screen preferences:
##This is my preference screen code for the images below
    tag menu
##The imagemap is still the same old thing
    imagemap:
        ground "Pref_idle.png"
        idle "Pref_idle.png"
        hover "Pref_hover.png"
        selected_idle "Pref_selected_idle.png"
        selected_hover "Pref_selected_hover.png"
##This is where things get tricky. When changing this, don't erase any of the "actions Preference" from the original preference screen (Unless you're not planning to use some of them)
##The first two define the window size (Full and Windowed). Haven't tested yet if you can change resolution like this as well. Well, food for thought.
        hotspot (684, 327, 62, 32) action Preference("display", "fullscreen")
        hotspot (798, 327, 327, 32) action Preference("display", "window")
##The Skip Text preference
        hotspot (205, 328, 62, 32) action Preference("skip", "seen")
        hotspot (92, 329, 62, 32) action Preference("skip", "all")
##After Choices preference that decides whether to stop skipping after a choice or to continue
        hotspot (205, 395 , 62, 32) action Preference("after choices", "stop")
        hotspot (92, 395 , 62, 32) action Preference("after choices", "skip")
##This one is the Transition setting. Best to keep this if your game is using graphic-heavy transitions or you want to add support for very low-end computers
        hotspot (684, 393 , 62, 32) action Preference("transitions", "all")
        hotspot (798, 393 , 62, 32) action Preference("transitions", "none")
##Notice how this says "bar pos" instead of "bar" That's because in my pref screens, I always keep the bar seperate. All you have to define is it's position on the menu like this and deal with it's size below.
        bar pos (46, 189) value Preference("text speed") style "pref_slider"
        bar pos (641, 244) value Preference("sound volume") style "pref_slider"
        bar pos (641, 181) value Preference("music volume") style "pref_slider"
        bar pos (46, 256) value Preference("auto-forward time") style "pref_slider"
##This is the navigation menu (Since imagemaps have the nasty habit of covering them) It also allows me to have different types of navigation menus. All can share the same ground image, but I can change what the navigation text says per screen.
    imagemap:
        ground "guide_ground.png"
        idle "guide_idle.png"
        hover "guide_hover.png"
        selected_idle "guide_hover.png"
        selected_hover "guide_hover.png"

        hotspot (4,522,91,78) action Return()
        hotspot (929,522,91,78) action ShowMenu("save")
        hotspot (822,522,91,78) action ShowMenu("load")
        hotspot (113,522,91,78) action ShowMenu("preferences")
        hotspot (873,0,151,47) action Quit()
init -2 python:
    style.pref_slider.left_bar = "bar_empty.png" #full
    style.pref_slider.right_bar = "bar_full.png" #empty

    style.pref_slider.xmaximum = 275    # width of your left_bar image.
    style.pref_slider.ymaximum = 20    # height of your left_bar image.

    style.pref_slider.thumb = "thumb.png"
    style.pref_slider.thumb_offset = 15    # Half of your thumb's width in pixels
    style.pref_slider.thumb_shadow = None