scp_program -> product(*

	-> rrel_params: ... (*

		-> rrel_1: rrel_in: _graph1;;
		-> rrel_2: rrel_in: _graph2;;
		-> rrel_3: rrel_in: _test_number;;

	*);;

	-> rrel_operators: ... (*

	-> rrel_init: ..start (*
		<- print;;
		-> rrel_1: rrel_fixed: rrel_scp_const: [----------Тест ];;
		=> nrel_goto: ..print_test_numbers;;
	*);;

	-> ..print_test_numbers (*
		<- printEl;;
		-> rrel_1: rrel_fixed: rrel_scp_var: _test_number;;
		=> nrel_goto: ..generateProduct;;
	*);;

	-> ..generateProduct (*
		<- genEl;;
		-> rrel_1: rrel_assign: rrel_node: rrel_const: rrel_scp_var: _set;;
		=> nrel_goto: ..find_all_vertices1;;
	*);;

	//находим множество вершин первого графа и записываем его в сет
	->  ..find_all_vertices1(*
		 <- searchSetStr5;;
		-> rrel_1: rrel_fixed: rrel_scp_var: _graph1;;
		-> rrel_2: rrel_assign: rrel_pos_const_perm: rrel_scp_var: _arc1;;
		-> rrel_3: rrel_assign: rrel_scp_var: _vertices1;;
		-> rrel_4: rrel_assign: rrel_pos_const_perm: rrel_scp_var: _arc2;;
		-> rrel_5: rrel_fixed: rrel_scp_const: rrel_nodes;;

		=> nrel_then: ..find_all_vertices2;;
		=> nrel_else: ..return;;
	*);;
	//находим множество вершин второго графа и записываем его в сет
	->  ..find_all_vertices2(*
		 <- searchSetStr5;;
		-> rrel_1: rrel_fixed: rrel_scp_var: _graph2;;
		-> rrel_2: rrel_assign: rrel_pos_const_perm: rrel_scp_var: _arc1;;
		-> rrel_3: rrel_assign: rrel_scp_var: _vertices2;;
		-> rrel_4: rrel_assign: rrel_pos_const_perm: rrel_scp_var: _arc2;;
		-> rrel_5: rrel_fixed: rrel_scp_const: rrel_nodes;;

		=> nrel_then: ..find_vertex1;;
		=> nrel_else: ..return;;
	*);;

	-> ..find_vertex1 (*

		<- searchElStr3;;
		-> rrel_1: rrel_fixed: rrel_scp_var: _vertices1;;
		-> rrel_2: rrel_assign: rrel_pos: rrel_scp_var: _arc2;;
		-> rrel_3: rrel_assign: rrel_scp_var: _vertex1;;
		=> nrel_then: ..find_vertex2;;
		=> nrel_else: ..return;;

	*);;

	-> ..find_vertex2 (*

		<- searchElStr3;;
		-> rrel_1: rrel_fixed: rrel_scp_var: _vertices2;;
		-> rrel_2: rrel_assign: rrel_pos: rrel_scp_var: _arc3;;
		-> rrel_3: rrel_assign: rrel_scp_var: _vertex2;;
		=> nrel_then: ..generate_caretesian_product ;;
		=> nrel_else: ..erase_arc1;;

	*);;


	->..generate_caretesian_product (*
		<- genElStr5;;
		-> rrel_1: rrel_fixed: rrel_scp_var: _vertex1;;
		-> rrel_2: rrel_assign: rrel_common: rrel_scp_var: _arc10;;
		-> rrel_3: rrel_fixed: rrel_scp_var: _vertex2;;
		-> rrel_4: rrel_assign: rrel_pos_const_perm: rrel_scp_var: _arc11;;
		-> rrel_5: rrel_fixed: rrel_scp_const: nrel_pair;;


		=> nrel_goto: ..generate_caretesian_product2;;
	*);;

	->..generate_caretesian_product2 (*
		<- genElStr3;;
		-> rrel_1: rrel_fixed: rrel_scp_var: _set;;
		-> rrel_2: rrel_assign: rrel_common: rrel_scp_var: _arc;;
		-> rrel_3: rrel_fixed: rrel_scp_var: _arc10;;


		=> nrel_goto: ..print_element1;;
	*);;

	-> ..print_element1 (*
			<- printEl;;
			-> rrel_1: rrel_fixed: rrel_scp_var: _vertex1;;
			 => nrel_goto: ..print_element1_;;
	*);;

	-> ..print_element1_ (*
			<- print;;
			-> rrel_1: rrel_fixed: rrel_scp_const: [->];;
			 => nrel_goto: ..print_element2;;
	*);;

	->..print_element2(*
		<- printEl;;
		-> rrel_1: rrel_fixed: rrel_scp_var: _vertex2;;
		 => nrel_goto: ..erase_arc2;;
	*);;

	->..erase_arc2 (*
		<- eraseEl;;
		-> rrel_1: rrel_fixed: rrel_erase: rrel_scp_var: _arc3;;
		 => nrel_goto: ..find_vertex2;;
	*);;

	->..erase_arc1 (*
		<- eraseEl;;
		-> rrel_1: rrel_fixed: rrel_erase: rrel_scp_var: _arc2;;
		 => nrel_goto: ..find_vertex1;;
	*);;

	->..return(*
		<-return;;
	*);;
    *);;
*);;