adventure 2

Start:
x = 3: y = 3: HP = 10: FF = 1
mob = -1
DO

  CLS
  COLOR 15
  PRINT "The Chaos Mystery"
  PRINT "-----------------"
  r = x + y * 4
  IF FF = 0 AND mob >= 0 THEN mob = r
  IF r = 0 AND mob = -1 THEN mob = 0
  SELECT CASE r
    CASE 0: Ex = 1
      PRINT "You are in the creature cage."
      PRINT "The cage is solidly constructed with thick concrete walls."

    CASE 1: Ex = 7
      PRINT "You are in the observation room."
      PRINT "To the west is the creature cage, which is protected by a forcefield."
      PRINT "The forcefield is currently ";
      IF FF = 0 THEN PRINT "OFF." ELSE PRINT "ON."
      PRINT "To the east is a high wall, up to the control room."
      PRINT "You will need something to climb up here."

    CASE 2: Ex = 4
      PRINT "You climb up into the control room."
      PRINT "Inside here are many computer panels."
      PRINT "A giant switch marked 'FORCEFIELD' captures your attention."
      PRINT "The switch is currently marked ";
      IF FF = 0 THEN PRINT "OFF." ELSE PRINT "ON."
      INPUT "Would you like to switch the switch? [y/n]", m$
      IF LCASE$(m$) = "y" THEN FF = 1 - FF

    CASE 3: Ex = 2
      PRINT "You are in the vault."
      PRINT "The vault is full of gold. You declare this gold to be your reward."
      PRINT "\o/"
      gameover = 1

    CASE 4: Ex = 3
      PRINT "You enter the test chamber in the science lab."
      PRINT "The chamber is filled with a toxic acid gas."
      IF mask = 0 THEN
        PRINT "You feel the gas burning your eyes. You cannot bare them open."
        PRINT "An intense burning sensation in your lungs and head overwhelms you."
        PRINT "You feel yourself passing out before you can even turn around."
        gameover = 2
      ELSE
        PRINT "You can feel the gas penetrating your clothing and stinging your body parts."
        PRINT "Fortunately, it doesn't seem to cause you are lasting harm."
        IF mob = r THEN
          PRINT "The CHAOS BEAST chokes on the toxic gas."
          PRINT "It's flesh covers in blisters, which then rupture."
          PRINT "Writhing in pain with it's limbs flailing and smoking."
          PRINT "It's body slowly dissolves into a pool of slime."
          PRINT "All that remains is it's CHAOS HEART. You take it!"
          chaos = 1
          mob = -2
        END IF
      END IF

    CASE 5: Ex = 13
      PRINT "You are in the containment area."
      PRINT "The door to the north is marked 'creature observation area'"
      PRINT "This door is voice activated."
      PRINT "The door to the west is marked 'test chamber'. It has warning signs all over it."

    CASE 6: Ex = 7
      PRINT "You are in the north corridor."
      PRINT "The door to the north has a hand scanner. You cannot go that way."

    CASE 7: Ex = 12
      PRINT "You are in the manager's office. A big desk dominates the room."
      PRINT "A vault door is seen to the north of the room."
      IF keys = 0 THEN COLOR 11: PRINT "On the desk, you find a STORE ROOM KEY": COLOR 15: keys = 1

    CASE 8: Ex = 9
      PRINT "You are in the chemistry wing of the science lab."
      PRINT "The benches here are piled with complicated looking glassware."
      PRINT "Lots of bottle line the walls."
      PRINT "The door to the north is marked 'test chamber'. It has warning signs all over it."
      IF acid = 0 THEN COLOR 11: PRINT "You found a ACID FLASK": COLOR 15: acid = 1

    CASE 9: Ex = 5
      PRINT "You are in the biology wing of the science lab."
      PRINT "Most of the benches here have microscopes on them."
      IF balloon = 0 THEN
        PRINT "You find a BALLOON stuck against the ceiling. It reads HAPPY 40th."
        PRINT "It must have been the technician's birthday. You take it!"
        balloon = 1
      END IF
      IF chaos = 1 THEN
        PRINT "You find a microscope and look closely at the CHAOS HEART."
        PRINT "Inside the heart, you see yourself in the future."
        PRINT "You see yourself typing 472 somewhere, and feeling a sense of victory."
      END IF
    CASE 10: Ex = 14
      PRINT "You are in the central corridor."
      PRINT "The corridor runs north-south."
      PRINT "To the west is a door, marked 'science labs'."

    CASE 11: Ex = 2
      PRINT "You are in a small store room."
      IF mask = 0 THEN COLOR 11: PRINT "You find a GAS MASK.": COLOR 15: mask = 1

    CASE 12: Ex = 1
      PRINT "You are in the security office."
      IF card = 0 THEN COLOR 11: PRINT "You found a PASS CARD": COLOR 15: card = 1

    CASE 13: Ex = 5
      PRINT "You are at the security desk."
      PRINT "To the west is the security office."
      PRINT "To the east is the main corridor."

    CASE 14: Ex = 13
      PRINT "You are in the south corridor."
      PRINT "There is a tall closet here, secured with a padlock."
      IF acid = 1 AND steps = 0 THEN
        PRINT "You pour some of the ACID over the padlock."
        PRINT "It fizzes and smokes a bit, before breaking apart."
        PRINT "Inside the closet you find some STEP LADDERS"
        steps = 1
      END IF

    CASE 15: Ex = 12
      PRINT "You are in the lobby of GreyCorp Industrial Complex."
      PRINT "To the north is a store room."
      PRINT "To the west is the main corridor."
      PRINT ""

  END SELECT

  IF r = mob THEN
    PRINT "In this room is also a CHAOS BEAST."
    PRINT "The CHAOS BEAST attacks you. You lose 1 HP."
    HP = HP - 1
  END IF
  IF HP <= 0 THEN gameover = 2

  PRINT "------------------------------------"
  IF gameover = 1 THEN
    COLOR 10
    PRINT
    PRINT "YOU HAVE WON!"
    PRINT "... Or was it all just a toxic gas induced hallucination?"
    PRINT
    PRINT "Find out in our next adventure!"
    SLEEP
    END
  END IF
  IF gameover = 2 THEN
    COLOR 12
    PRINT
    PRINT "YOU HAVE DIED!"
    PRINT
    PRINT "THAT MEANS GAME OVER"
    SLEEP
    END
  END IF

  COLOR 11
  PRINT
  PRINT "You are carrying:"
  IF keys > 0 THEN PRINT "STORE ROOM KEY"
  IF card > 0 THEN PRINT "PASS CARD"
  IF acid > 0 THEN PRINT "ACID FLASK"
  IF mask > 0 THEN PRINT "GAS MASK"
  IF balloon > 0 THEN PRINT "HELIUM BALLOON"
  IF chaos > 0 THEN PRINT "CHAOS HEART"
  IF steps > 0 THEN PRINT "STEP LADDERS"

  COLOR 10
  PRINT
  PRINT "Health: "; HP; "/10"

  COLOR 14
  PRINT

  a$ = ""
  IF (Ex AND 8) > 0 THEN a$ = a$ + " [N]ORTH"
  IF (Ex AND 4) > 0 THEN a$ = a$ + " [W]EST"
  IF (Ex AND 2) > 0 THEN a$ = a$ + " [S]OUTH"
  IF (Ex AND 1) > 0 THEN a$ = a$ + " [E]AST"
  PRINT "Exits are: " + a$
  INPUT a$: a$ = LCASE$(a$): a$ = LEFT$(a$, 1)

  COLOR 15

  'voice door
  IF a$ = "n" AND r = 5 THEN
    IF balloon = 1 THEN
      PRINT "You suck a little of the helium out of the ballon, and speak."
      PRINT "The voice activated door opens."
      INPUT q$
    ELSE
      PRINT "You speak to the door, but it refuses access."
      PRINT "If only you could find something to change the tone of your voice..."
      INPUT q$
      a$ = ""
    END IF
  END IF
  'card
  IF a$ = "w" AND (r = 10 OR r = 6) THEN
    IF card = 1 THEN
      PRINT "You insert the pass card into the slot."
      PRINT "The mechanism buzzes while the door springs open."
      INPUT q$
    ELSE
      PRINT "It looks like you need a pass card to open this door."
      PRINT "You try to push it, but it refuses to open."
      INPUT q$
      a$ = ""
    END IF
  END IF
  'store room
  IF a$ = "n" AND r = 15 THEN
    IF keys = 1 THEN
      PRINT "You insert your key into the lock and turn. It fits!"
      INPUT q$
    ELSE
      PRINT "The door appears to be locked."
      INPUT q$
      a$ = ""
    END IF
  END IF
  'vault
  IF a$ = "n" AND r = 7 THEN
    PRINT "The door to the vault has a three digit combination lock."
    INPUT "Please enter combination", m$
    IF m$ = "472" THEN
      PRINT "Eureka! The code worked."
      INPUT q$
    ELSE
      PRINT "That didn't seem to work."
      INPUT q$
      a$ = ""
    END IF
  END IF
  'steps
  IF a$ = "e" AND r = 1 THEN
    IF steps = 1 THEN
      PRINT "You prop the step ladders against the east wall."
      PRINT "They are just long enough to reach the control room platform."
      INPUT q$
    ELSE
      PRINT "The control room platform is too high to reach."
      a$ = ""
      INPUT q$
    END IF
  END IF
  IF a$ = "w" AND r = 1 AND FF = 1 THEN
    PRINT "The forcefield is ON. You cannot walk through it!"
  END IF

  IF a$ = "n" AND (Ex AND 8) > 0 THEN y = y - 1
  IF a$ = "w" AND (Ex AND 4) > 0 THEN x = x - 1
  IF a$ = "s" AND (Ex AND 2) > 0 THEN y = y + 1
  IF a$ = "e" AND (Ex AND 1) > 0 THEN x = x + 1


LOOP