Pickup Hunt System

// Pickup Hunt by AiRaLoKa
// Credits
// - AiRaLoKa                   : For making this whole filterscript
// - Zeex                       : For zcmd
// - Y_Less                     : For y_ini
// - Davee (owner of nextgenstunting.net)   : For the idea

#define FILTERSCRIPT

#include <a_samp>
#include <zcmd>
#include <YSI\y_ini>

#define PATH "/Users/%s.ini"
#define ROSU 0x00CC00FF

#if defined FILTERSCRIPT

public OnFilterScriptInit()
{
    print("\n--------------------------------------");
    print(" Pickup Hunt by AiRaLoKa");
    print("--------------------------------------\n");
    SetTimer("PickUpHunt", 1500, true);
    return 1;
}

public OnFilterScriptExit()
{
    return 1;
}

#else
main(){}
#endif

enum pInfo
{
    pPickuphunt
}

new PlayerInfo[MAX_PLAYERS][pInfo];
new bool:PUHIsStarted = false, PUHTimerTicker = 0, PUHSpawned, PUHCommand;
new TestPUH;
//////////////////////// PICKUP HUNT POSITION INFO
new pickuphuntpos[][]=
{
    "Verdant Bluffs","Verona Beach","Los Santos Airport","East Beach","Las Colinas","Flint County",
    "Angel Pine","Leaffy Hollow","Back O Beyond","Fallen Tree","Red County","Blueberry Acress",
    "Montgomery","Montgomery Inserction","Randolph Industrial Estates","Rockshore West","Queens",
    "Doherty","El Castilo Del Diablo","Tierra Robada","Tierra Robada","Tierra Robada","Downtown",
    "City Hall","Ocean Flats","Avispa Country Club","Palisades","Battery Point"
};
//////////////////////// PICKUP HUNT POSITION
new Float:pickuphunt[][]=
{
    {1196.8407, -2344.1743, 15.1022},//VERDANT BLUFFS
    {835.8299, -2061.5854, 12.6303},//VERONA BEACH
    {1682.2606, -2286.2442, -1.7188},//LOS SANTOS AIRPORT
    {2660.7590, -1433.2063, 30.9913},//EAST BEACH
    {2553.1987, -1126.8297, 63.5787},//LAS COLINAS
    {-26.4870, -2508.4851, 36.6555},//FLINT COUNTY
    {-2100.7266, -2239.4922, 29.9488},//ANGEL PINE
    {-1110.9795, -1637.1415, 75.9780},//LEAFFY HOLLOW
    {-602.0828, -1853.4364, 22.9738},//BACK O BEYOND
    {-490.2611, -522.5457, 24.8097},//FALLEN TREE
    {-49.9205, -370.6295, 4.7845},//RED COUNTY
    {-208.9162, -1.8698, 3.1094},//BLUEBERRY ACRESS
    {1302.0482, 169.7543, 19.8932},//MONTGOMERY
    {1589.3712, 313.0976, 23.4200},//MONTGOMERY INSERCTION
    {1665.1302, 719.9824, 10.8203},//RANDOLPH INDUSTRIAL ESTATES
    {2404.9160, 648.6808, 10.5726},//ROCKSHORE WEST
    {-2505.9390, 356.2068,35.1172},//QUEENS
    {-1835.3127,-88.9142,15.1094},//DOHERTY
    {-167.3171,2363.7449,53.2441},//EL CASTILO DEL DIABLO
    {-637.4780,2588.3975,89.9215},//TIERRA ROBADA 1
    {-1300.2871,2509.9211,87.0096},//TIERRA ROBADA 2
    {-2090.6196,2313.4001,25.9141},//TIERRA ROBADA 3
    {-1584.5339,812.0679,6.8203},//DOWNTOWN
    {-2706.1826,376.1722,4.9685},//CITY HALL
    {-2679.4722,-5.4511,6.1328},//OCEAN FLATS
    {-2752.6086,-252.1124,7.1875},//AVISPA COUNTRY CLUB
    {-2753.2566,1257.4037,11.4213},//PALISADES
    {-2681.7788,1283.1487,56.4844}//BATTERY POINT
};

forward LoadUser_PlayerData(playerid,name[],value[]);
public LoadUser_PlayerData(playerid,name[],value[])
{
    INI_Int("Pickuphunt",PlayerInfo[playerid][pPickuphunt]);
    return 1;
}
//////////////////////////// COMMAND TO VIEW THE CLUE OF THE PICKUP'S POSITION
CMD:pickuphunt(playerid,params[])
{
    if(PUHIsStarted == true)
    {
        new string[50],str[256];
        format(string,sizeof string,"%s",pickuphuntpos[PUHCommand]);
        format(str,sizeof str,"[PICKUPHUNT]: Pickup has been spawned near:{FFCC00} %s",string);
        SendClientMessage(playerid,ROSU,str);
        SendClientMessage(playerid,ROSU,"[PICKUPHUNT]: Find it and get {FFCC00}5 {00CC00}score and ${FFCC00}50000{00CC00}!");
    } else return SendClientMessage(playerid,0xFF0000FF,"[PICKUPHUNT]: Pickuphunt isn't spawned yet!");
    return 1;
}
CMD:gopickuphunt(playerid, params[])
{
    if(PUHIsStarted == true)
    {
        SetPlayerPos(playerid,pickuphunt[TestPUH][0]+1,pickuphunt[TestPUH][1]+1,pickuphunt[TestPUH][2]);
    } else return SendClientMessage(playerid,0xFF0000FF,"[PICKUPHUNT]: Pickuphunt isn't spawned yet!");
    return 1;
}

public OnPlayerConnect(playerid)
{
    INI_ParseFile(UserPath(playerid), "LoadUser_%s", .bExtra = true, .extra = playerid);
    return 1;
}

public OnPlayerDisconnect(playerid, reason)
{
    new INI:File = INI_Open(UserPath(playerid));
    INI_SetTag(File,"PlayerData");
    INI_WriteInt(File,"Pickuphunt",PlayerInfo[playerid][pPickuphunt]);
    INI_Close(File);
    return 1;
}

forward PickUpHunt();
public PickUpHunt()
{

    if(PUHIsStarted == false)
    {
        new Random = random(sizeof(pickuphunt));
        new string[256];
        PUHTimerTicker ++;
        switch (PUHTimerTicker)
        {
            case 25:
            {
                PUHSpawned = CreatePickup(1239,2,pickuphunt[Random][0],pickuphunt[Random][1],pickuphunt[Random][2]);
                PUHCommand = Random;
                format(string,sizeof string,"[PICKUPHUNT]: Pickup has been spawned near:{FFCC00} %s",pickuphuntpos[Random]);
                SendClientMessageToAll(ROSU,string);
                SendClientMessageToAll(ROSU,"[PICKUPHUNT]: Find it and get {FFCC00}5 {00CC00}score and ${FFCC00}50000{00CC00}!");
                TestPUH = Random;
                PUHIsStarted = true;
                PUHTimerTicker = 0;
            }
        }
    }
    return 1;
}
public OnPlayerPickUpPickup(playerid, pickupid)
{
    if(pickupid == PUHSpawned)
    {
        new pName[MAX_PLAYER_NAME],string[512];
        GetPlayerName(playerid, pName, MAX_PLAYER_NAME);
        format(string,sizeof(string),"[PICKUPHUNT]: %s (%d) has found the pickup and get {FFCC00}5 {00CC00}score and ${FFCC00}50000{00CC00}",pName,playerid);
        SendClientMessageToAll(ROSU,string);
        GivePlayerMoney(playerid,50000);
        PlayerInfo[playerid][pPickuphunt]=PlayerInfo[playerid][pPickuphunt]+1;
        SetPlayerScore(playerid, GetPlayerScore(playerid) + 5);
        DestroyPickup(PUHSpawned);
        PUHIsStarted = false;
    }
    return 1;
}

stock UserPath(playerid)
{
    new string[128],playername[MAX_PLAYER_NAME];
    GetPlayerName(playerid,playername,sizeof(playername));
    format(string,sizeof(string),PATH,playername);
    return string;
}