Tiler

Shader "Over2D/Tiler"
{
    Properties
    {
        _MainTex("Sprite Texture", 2D) = "white" {}
        _Tiling("Tiling", Vector) = (10,15,0,0)
        _Offset("Offset", Vector) = (0,0,0,0)
        _Color("Tint", Color) = (1,1,1,1)
        [MaterialToggle] PixelSnap("Pixel snap", Float) = 0
    }

        SubShader
    {
        Tags
    {
        "Queue" = "Transparent"
        "IgnoreProjector" = "True"
        "RenderType" = "Transparent"
        "PreviewType" = "Plane"
        "CanUseSpriteAtlas" = "True"
    }

        Cull Off
        Lighting Off
        ZWrite Off
        Blend One OneMinusSrcAlpha

        Fog{ Mode Off }

        Pass
        {
            CGPROGRAM
    #pragma vertex vert
    #pragma fragment frag
    #pragma multi_compile _ PIXELSNAP_ON
    #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex   : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex   : SV_POSITION;
                half2 uv  : TEXCOORD0;
            };

            fixed4 _Color;
            float2 _Tiling;
            float2 _Offset;
            sampler2D _MainTex;

            v2f vert(appdata IN)
            {
                v2f OUT;
                OUT.vertex = UnityObjectToClipPos(IN.vertex);
                //тайлим текстуру
                float xScale = length(float3(unity_ObjectToWorld[0][0], unity_ObjectToWorld[1][0], unity_ObjectToWorld[2][0])) / _Tiling.x;
                float yScale = length(float3(unity_ObjectToWorld[0][1], unity_ObjectToWorld[1][1], unity_ObjectToWorld[2][1])) / _Tiling.y;
                OUT.uv = IN.uv * half2(xScale, yScale);

        #ifdef PIXELSNAP_ON
                OUT.vertex = UnityPixelSnap(OUT.vertex);
        #endif

                return OUT;
            }

            fixed4 SampleSpriteTexture(float2 uv)
            {
                //сдвигаем Offset текстуры на заданную величину
                uv += _Offset;

                fixed4 color = tex2D(_MainTex, uv);

                return color;
            }

            fixed4 frag(v2f IN) : SV_Target
            {
                fixed4 c = SampleSpriteTexture(IN.uv);
                c.rgb *= _Color;
                c.rgb *= c.a;
                return c;
            }
            ENDCG
        }
    }
}