Dark Souls III Auto Char Creation

#SingleInstance Force
#MaxHotkeysPerInterval 99999
; #IfWinActive ahk_class FDPclass

IniRead, Name, ds3cc.ini, Settings, CharacterName, Name
IniRead, ChosenHotkey, ds3cc.ini, Settings, Hotkey, F4
IniRead, StartingClass, ds3cc.ini, Settings, StartingClass, 1
IniRead, BurialGift, ds3cc.ini, Settings, BurialGift, 1

Gui, Show, w260 h145, Test

Gui, Add, Text,   w120 x10, Character name:
Gui, Add, Edit,   w120 x+0 vName, %Name%

Gui, Add, Text,   w120 x10, Hotkey:
Gui, Add, Hotkey, w120 x+0 vChosenHotkey, %ChosenHotkey%

Gui, Add, Text,         w120 x10, Starting class:
Gui, Add, DropDownList, w120 x+0 vStartingClass AltSubmit Choose%StartingClass%, Knight|Mercenary|Warrior|Herald|Thief|Assassin|Sorcerer|Pyromancer|Cleric|Deprived

Gui, Add, Text,         w120 x10, Burial gift:
Gui, Add, DropDownList, w120 x+0 vBurialGift AltSubmit Choose%BurialGift%, Life Ring|Divine Blessing|Hidden Blessing|Black Firebomb|Fire Gem|Sovereignless Soul|Rusted Gold Coin|Cracked Red Eye Orb|Young White Branch

Gui, Add, Button, w240 x10 gSetup, OK

Return

; InputBox, Name, Enter your character's name, , , 300, 105

Sendl(key) {
  Send {%key% down}
  Sleep 10
  Send {%key% up}
  Sleep 5
}

SendE() {
  Sendl("e")
}

SendName(Name) {
  Loop, Parse, Name
  {
    Sendl(A_LoopField)
  }
}

Setup:
  Gui, Submit

  IniWrite, %Name%, ds3cc.ini, Settings, CharacterName
  IniWrite, %ChosenHotkey%, ds3cc.ini, Settings, Hotkey
  IniWrite, %StartingClass%, ds3cc.ini, Settings, StartingClass
  IniWrite, %BurialGift%, ds3cc.ini, Settings, BurialGift

  StartingClass -= 1

  Hotkey, %ChosenHotkey%, ApplyHotkey
  Return

ApplyHotkey:
  SendE()
  Sleep 250
  SendName(Name)
  Sendl("Enter")
  Sleep 500
  ; Gender
  Sendl("Down")
  SendE()
  Sleep 250
  Sendl("Left")
  SendE()
  Sleep 500
  Sendl("Down")
  SendE()
  ; Class
  Sendl("Down")
  Sendl("Down")
  SendE()
  Loop %StartingClass% {
    Sendl("Down")
  }
  SendE()
  ; Burial gift
  Sendl("Down")
  SendE()
  Loop %BurialGift% {
    Sendl("Down")
  }
  SendE()
  ; Finalize
  Loop 4 {
    Sendl("Down")
  }
  SendE()
  Sendl("Left")
  Return