Hexagon .cmd generator for GIMP (import paths)

@echo off
set vakio=3000
set width=10
set height=10

set /a height*=2
set /a height+=1
set first=true

echo ^<?xml version="1.0" encoding="UTF-8" standalone="no"?^>
echo ^<^!DOCTYPE svg PUBLIC "-//W3C//DTD SVG 20010904//EN"
echo              "http://www.w3.org/TR/2001/REC-SVG-20010904/DTD/svg10.dtd"^>
echo.
echo ^<svg xmlns="http://www.w3.org/2000/svg"
echo     width="1.66667in" height="1.66667in"
echo     viewBox="0 0 500 500"^>
set X=0
:xloop
set Y=0
set /A mx=%X% %% 2
set /A my=%Y% %% 2
set /A point1x= ( %mx% ^^ %my% ) * ( %vakio% / 2 ) + ( %X% * %vakio% * 3 / 2 )
set /A point1y= %Y% * 866 * %vakio% / 1000
set ptmp=%point1x:~0,-2%.%point1x:~-2%,%point1y:~0,-2%.%point1y:~-2%
if NOT "%first%"=="true" echo " />
set first=
echo ^<path id="%X%" fill="none" stroke="black" stroke-width="1" d="M %ptmp%
set Y=1
set beg=C
:yloop
set /A mx=%X% %% 2
set /A my=%Y% %% 2
set /A point1x= ( %mx% ^^ %my% ) * ( %vakio% / 2 ) + ( %X% * %vakio% * 3 / 2 )
set /A point1y= %Y% * 866 * %vakio% / 1000
if NOT "%Y%"=="1" set ptmp=%atmp%
set atmp=%point1x:~0,-2%.%point1x:~-2%,%point1y:~0,-2%.%point1y:~-2%
echo %beg%%ptmp% %atmp% %atmp%
set beg=
set /A Y+=1
if %Y% LEQ %height% goto yloop
set /A X+=1
if %X% GTR %width% goto part2
goto xloop

:part2
echo " />
echo ^<^!-- PART TWO --^>
set /a width-=1
set /a height-=1
set /a height/=2
set X=0
set count=0
:xlaap
set Y=0
:ylaap
set /A mx=(%X% + 1) %% 2
set /A my=%Y% %% 2
set /A point1x= %vakio% * 3 / 2 * ( %X% + 1 )
set /A point2x= %vakio% / 2 + ( %vakio% * 3 / 2 ) * %X%
set /A point1y= %Y% * 1732 * %vakio% / 1000 + %mx% * 866 * %vakio% / 1000
set ptmp=%point1x:~0,-2%.%point1x:~-2%,%point1y:~0,-2%.%point1y:~-2%
set atmp=%point2x:~0,-2%.%point2x:~-2%,%point1y:~0,-2%.%point1y:~-2%
echo ^<path id="b%count%" fill="none" stroke="black" stroke-width="1" d="M %ptmp% C %ptmp% %atmp% %atmp%" /^>
set /A Y+=1
set /A count+=1
if %Y% LEQ %height% goto ylaap
set /A X+=1
if %X% GTR %width% goto end
goto xlaap

:end
echo ^</svg^>