#include <mbf21>
#include <friendly>

/////////////
// STRINGS //
/////////////

Strings
{
	GOTCHAINGUN "You got the 9mm Subgun!"
	GOTSHOTGUN "You got the Winchester shotgun!"
	GOTSHOTGUN2 "You got The Bonecrusher! Bust some heads!"
	GOTCLIP "Picked up a loaded pistol."
	GOTCLIPBOX "Picked up a drum of bullets."
}

/////////////
// WEAPONS //
/////////////

weapon WP_PISTOL
{
	States
	{
		Fire:
			PISG A 1
			TNT1 A 0 A_GunFlash
			TNT1 A 0 A_ConsumeAmmo
			TNT1 A 0 A_WeaponSound(sound "fre045")
			PISG B 1 Bright A_WeaponBulletAttack(0, 0)
			PISG C 1 Bright
			PISG D 1
			PISG E 1
			PISG F 1
			PISG G 1
			PISG A 7
			PISG A 1 A_ReFireTo(fire2)
			Goto Ready
		Fire2:
			PISG A 1
			TNT1 A 0 A_GunFlash
			TNT1 A 0 A_ConsumeAmmo
			TNT1 A 0 A_WeaponSound(sound "fre045")
			PISG B 1 Bright A_WeaponBulletAttack(5.6, 0)
			PISG C 1 Bright
			PISG D 1
			PISG E 1
			PISG F 1
			PISG G 1
			PISG A 7
			PISG A 1 A_ReFireTo(fire2)
			Goto Ready
		Flash:
			TNT1 A 4 A_Light1
			Goto LightDone
	}
}

weapon WP_CHAINGUN
{
	States
	{
		Fire:
			TNT1 A 0 A_GunFlash
			TNT1 A 0 A_ConsumeAmmo
			TNT1 A 0 A_WeaponSound(sound "fre048")
			CHGF A 1 Bright A_WeaponBulletAttack(0, 0)
			CHGF B 1 Bright
			CHGG B 1
			CHGG A 1
			TNT1 A 0 A_GunFlashTo("flash2")
			TNT1 A 0 A_ConsumeAmmo
			TNT1 A 0 A_WeaponSound(sound "fre048")
			CHGF A 1 Bright A_WeaponBulletAttack(0, 0)
			CHGF B 1 Bright
			CHGG B 1
			CHGG A 1
			TNT1 A 0 A_Refireto("fire2")
			Goto Ready
		Fire2:
			TNT1 A 0 A_GunFlash
			TNT1 A 0 A_ConsumeAmmo
			TNT1 A 0 A_WeaponSound(sound "fre048")
			CHGF A 1 Bright A_WeaponBulletAttack(5.6, 0)
			CHGF B 1 Bright
			CHGG B 1
			CHGG A 1
			TNT1 A 0 A_GunFlashTo("flash2")
			TNT1 A 0 A_ConsumeAmmo
			TNT1 A 0 A_WeaponSound(sound "fre048")
			CHGF A 1 Bright A_WeaponBulletAttack(5.6, 0)
			CHGF B 1 Bright
			CHGG B 1
			CHGG A 1
			TNT1 A 0 A_Refireto("fire2")
			Goto Ready
		Flash:
			TNT1 A 5 A_Light1
			Goto LightDone
		Flash2:
			TNT1 A 5 A_Light2
			Goto LightDone
	}
}

weapon WP_SHOTGUN
{
	States
	{
		Fire:
			SHTG X 1
			TNT1 A 0 A_GunFlash
			TNT1 A 0 A_ConsumeAmmo
			TNT1 A 0 A_WeaponSound(sound "fre049")
			SHTG B 1 A_WeaponBulletAttack(5.6, 0, 7)
			SHTG C 1 BRIGHT
			SHTG D 1
			SHTG E 1
			SHTG O 1
			SHTG Z 5
			SHTG F 1
			SHTG G 1
			SHTG H 1
			SHTG I 1
			SHTG J 4
			SHTG K 1
			SHTG L 1
			SHTG M 2
			SHTG N 3
			SHTG W 2
			SHTG L 2
			SHTG J 1
			SHTG I 1
			SHTG H 1
			SHTG Q 1
			SHTG R 1
			SHTG S 1
			Goto Ready
		Flash:
			TNT1 A 2 A_Light1
			TNT1 A 2 A_Light2
			Goto LightDone
	}
}

weapon WP_SUPERSHOTGUN
{
	States
	{
		Fire:
			SP35 A 1 Bright A_FireShotgun2
			SP35 B 1 Bright
			SP35 E 1
			SP35 F 1
			SP35 G 1
			SP36 A 1
			SP36 B 1
			SP37 A 1
			SP37 B 1
			SP37 C 1
			SP37 D 1
			SP37 E 1
			SP37 F 1
			SP37 G 3
			SP37 H 1
			SP37 I 1
			SP37 J 1
			SP37 K 1
			SP37 L 1
			SP37 M 3
			SP37 N 1
			SP37 O 1
			SP37 P 1
			SP37 Q 2
			SP37 R 3
			SP37 S 1
			SP37 T 1
			SP37 U 1
			SP37 V 1
			SP37 W 1
			SP37 X 1
			SP37 Y 1
			TNT1 A 2
			SP38 A 1
			SP38 B 1
			SP38 C 1
			SP38 D 1
			SP38 E 1
			TNT1 A 1
			SP38 G 1
			SP38 H 1
			SP38 J 1
			Goto Ready
		Flash:
			TNT1 A 2 A_Light1
			TNT1 A 2 A_Light2
			Goto LightDone
	}
}

//////////////
// MONSTERS //
//////////////

thing MTF_EXTRA00 "Pumpkin Marine"
{
	EdNum 1000
	Health 250
	Speed 16
	PainChance 30
	Radius 20
	Height 56
	ReactionTime 8
	Mass 100
	Projectilegroup 5

	+SOLID
	+SHOOTABLE
	+COUNTKILL

	SeeSound "fre013"
	AttackSound ""
	PainSound "popain"
	DeathSound "podth2"
	ActiveSound "posact"

	states
	{
		Spawn:
			SP00 AB 10 A_Look
			Loop
		See:
			SP00 AABBCCDD 1 A_Chase
			Loop
		Missile:
			SP00 E 2 A_FaceTarget
			SP00 F 1 Bright A_BspiAttack
			SP00 E 2 A_FaceTarget
			SP00 F 1 Bright A_BspiAttack
			SP00 E 2 A_FaceTarget
			SP00 F 1 Bright A_BspiAttack
			Goto See
		Pain:
			SP00 G 3
			SP00 G 3 A_Pain
			Goto See
		Death:
			SP00 H 5
			SP00 I 5 A_Scream
			SP00 J 5 A_Fall
			SP00 KLM 5
			SP00 N -1
			Stop
		XDeath:
			SP00 O 5
			SP00 P 5 A_XScream
			SP00 Q 5 A_Fall
			SP00 RSTUV 5
			SP00 W -1
			Stop
		Raise:
			SP00 MLKJIH 5
			Goto See
	}
}

thing MTF_EXTRA01 "Gargoyle"
{
	EdNum 1001
	Radius 19
	Height 40
	Mass 50
	Speed 10
	Health 25
	PainChance 256
	ReactionTime 8
	ProjectileGroup 1

	+SHOOTABLE
	+NOGRAVITY
	+SPAWNCEILING
	+FLOAT
	+COUNTKILL
	+SOLID

	SeeSound "fre002"
	AttackSound ""
	PainSound "fre003"
	DeathSound "fre004"
	ActiveSound "fre044"

	States
	{
		Spawn:
			SP01 BA 10 A_Look
			Loop
		See:
			SP01 AABBCCBB 2 A_Chase
			Loop
		Melee:
		Missile:
			SP01 D 6 A_FaceTarget
			SP01 E 4 A_FaceTarget
			SP01 E 0 A_JumpIfTargetCloser("ComboAttack", 60.0)
			SP01 F 4 Bright A_MonsterProjectile(MTF_EXTRA05, 0, 0, 0, -8.0)
			Goto See
		ComboAttack:
			SP01 F 4 A_MonsterMeleeAttack(3, 8, sound "claw")
			Goto See
		Pain:
			SP01 G 4
			SP01 G 4 A_Pain
			Goto See
		Death:
			SP01 H 11
			SP01 I 8 A_Scream
			SP01 J 4
			SP01 K 4 A_Fall
			SP01 L -1
			Stop
		XDeath:
			SP01 T 5 A_XScream
			SP01 U 5 A_Fall
			SP01 VWXY 5
			SP01 Z -1
			Stop
		Raise:
			SP01 KJIH 5
			Goto See
	}
}

thing MTF_EXTRA05 : thing MTF_IMP_FIREBALL "Garg Fireball"
{
	Speed 12
	FastSpeed 20

	States
	{
		Spawn:
			SP05 AB 4 Bright
			Loop
		Death:
			SP05 CDE 6 Bright
			Stop
	}
}

thing MTF_EXTRA59 : thing MTF_EXTRA01 "Gargoyle (spawn on floor)"
{
	-SPAWNCEILING

	Ednum 1054
}

thing MTF_EXTRA02 "Satyr"
{
	EdNum 1002
	Radius 24
	Height 64
	Mass 500
	Speed 12
	Health 300
	PainChance 200
	ReactionTime 8
	ProjectileGroup 2

	+SOLID
	+SHOOTABLE
	+COUNTKILL

	SeeSound "fre008"
	AttackSound ""
	PainSound "dmpain"
	DeathSound "fre009"
	ActiveSound "dmact"

	states
	{
		Spawn:
			SP02 AB 10 A_Look
			Loop
		See:
			SP02 AABBCCDD 2 A_Chase
			Loop
		Melee:
		Missile:
			SP02 EF 5 A_FaceTarget
			SP02 G 0 A_JumpIfTargetCloser("ComboAttack1", 60.0)
		Missile1:
			SP02 G 5 Bright A_MonsterProjectile(MTF_EXTRA04)
			Goto Missile2
		ComboAttack1:
			SP02 G 5 A_MonsterMeleeAttack(6, 8, sound "claw")
		Missile2:
			SP02 PQ 5 A_FaceTarget
			SP02 R 0 A_JumpIfTargetCloser("ComboAttack2", 60.0)
		Missile3:
			SP02 R 6 Bright A_MonsterProjectile(MTF_EXTRA04)
			Goto See
		ComboAttack2:
			SP02 R 6 A_MonsterMeleeAttack(6, 8, sound "claw")
			Goto See
		Pain:
			SP02 H 2
			SP02 H 2 A_Pain
			Goto See
		Death:
			SP02 I 5
			SP02 J 5 A_Scream
			SP02 K 5
			SP02 L 5 A_Fall
			SP02 MN 5
			SP02 O -1
			Stop
		Raise:
			SP02 NMLKJI 8
			Goto See
	}
}

thing MTF_EXTRA04 : thing MTF_BARON_FIREBALL "Satyr Fireball"
{
	Damage 5
	Speed 20
	FastSpeed 25

	States
	{
		Spawn:
			SP06 AB 4 Bright
			Loop
		Death:
			SP06 CDEFGHI 4 Bright
			Stop
	}
}

thing MTF_EXTRA03 "Rocket With Legs"
{
	EdNum 1003
	Health 20
	PainChance 0
	Speed 10
	Radius 30
	Height 56
	Mass 400
	MeleeRange 96

	+SOLID
	+SHOOTABLE
	+NOBLOOD
	+COUNTKILL

	States
	{
		Spawn:
			SP03 AB 10 A_Look
			Loop
		See:
			TNT1 A 0 A_Playsound(sound "fre043")
			SP03 AABBCCDDEEFF 1 A_Chase
			Loop
		Melee:
			TNT1 A 0 A_Die
		Death:
			TNT1 A 0 A_Playsound(sound "barexp")
			SP04 A 8 Bright A_Explode
			SP04 B 6 Bright A_Fall
			SP04 C 4 Bright
			Stop
  }
}

thing MTF_EXTRA06 "Skellington"
{
	EdNum 1004

	Health 150
	Speed 14
	Radius 20
	Height 56
	Damage 0
	ReactionTime 8
	PainChance 180
	Mass 400
	Projectilegroup 3

	+SOLID
	+SHOOTABLE
	+COUNTKILL
	+NOBLOOD
	+LONGMELEE

	SeeSound "fre012"
	AttackSound ""
	PainSound "popain"
	DeathSound "fre011"
	ActiveSound "fre010"

	states
	{
		Spawn:
			SP07 AB 10 A_Look
			Loop
		See:
			SP07 AABBCCDDEEFF 2 A_Chase
			Loop
		Melee:
			SP07 G 0 A_FaceTarget
			SP07 G 6 A_SkelWhoosh
			SP07 H 6 A_FaceTarget
			SP07 I 6 A_SkelFist
			Goto See
		Missile:
			SP07 G 4 A_FaceTarget
			SP07 H 4 A_FaceTarget
			SP07 I 6 A_MonsterProjectile(MTF_EXTRA07)
			Goto See
		Pain:
			SP07 L 5
			SP07 L 5 A_Pain
			Goto See
		Death:
			SP07 L 0 A_JumpIfHealthBelow("xdeath", -70)
			SP07 LM 7
			SP07 N 7 A_Scream
			SP07 O 7 A_Fall
			SP07 P 7
			SP07 Q -1
			Stop
		XDeath:
			SP07 LM 7
			TNT1 A 0 {
				A_Playsound(sound "fre024")
				A_SpawnObject(MTF_EXTRA42, 0, 0, 0, 0, 0, 0, 15.0)
				A_SpawnObject(MTF_EXTRA42, 0, 0, 0, 0, 5.0, 0, 15.0)
				A_SpawnObject(MTF_EXTRA42, 0, 0, 0, 0, 5.0, 5.0, 15.0)
				A_SpawnObject(MTF_EXTRA42, 0, 0, 0, 0, 0, 5.0, 15.0)
				A_SpawnObject(MTF_EXTRA42, 0, 0, 0, 0, -5.0, -5.0, 15.0)
				A_SpawnObject(MTF_EXTRA42, 0, 0, 0, 0, -5.0, 0, 15.0)
				A_SpawnObject(MTF_EXTRA42, 0, 0, 0, 0, 0, -5.0, 15.0)
			}
			SP07 N 7
			SP07 O 7 A_Fall
			SP07 P 7
			SP07 Q -1
			Stop
		Raise:
			SP07 P 5
			SP07 ONM 8
			Goto See
	}
}

thing MTF_EXTRA07 : thing MTF_IMP_FIREBALL "Bone to Pick"
{
	Damage 4
	Speed 18
	FastSpeed 20

	SeeSound "fre015"
	DeathSound "fre014"

	States
	{
		Spawn:
			SP08 ABCD 4
			Loop
		Death:
			PUFF CD 6
			Stop
	}
}

thing MTF_EXTRA42 "Skelly Gib Bones"
{
	Radius 10
	Height 8
	Mass 200

	+BOUNCES

	States
	{
		Spawn:
			SP08 ABCDABCDABCD 4
			SP08 E -1
			Stop
	}
}

thing MTF_EXTRA08 "King Boner the Stiff"
{
	EdNum 1005

	Health 600
	Speed 12
	Radius 20
	Height 56
	Damage 0
	ReactionTime 8
	PainChance 50
	Mass 500
	Splashgroup 1
	Projectilegroup 4

	Flags 0
	+SOLID
	+SHOOTABLE
	+COUNTKILL
	+RANGEHALF

	SeeSound "fre017"
	AttackSound ""
	PainSound "fre021"
	DeathSound "fre022"
	ActiveSound "fre018"

	states
	{
		Spawn:
			SP09 AB 10 A_Look
			Loop
		See:
			SP09 AABBCCDD 3 A_Chase
			Loop
		Missile:
			SP09 E 10 A_FaceTarget
			SP09 F 10 Bright A_MonsterProjectile(MTF_EXTRA09)
			SP09 E 10 A_FaceTarget
			Goto See
		Pain:
			SP09 I 5
			SP09 I 5 A_Pain
			Goto See
		Death:
			SP09 J 7 A_Scream
			SP09 K 7
			SP09 L 7 A_Fall
			SP09 M 7
			SP09 N -1
			Stop
		Raise:
			SP09 MLKJI 6
			Goto See
	}
}

thing MTF_EXTRA09 : thing MTF_REVENANT_ROCKET "Super Rev Rocket"
{
	Splashgroup 1
	Damage 0
	+FORCERADIUSDMG

	SeeSound "fre019"
	DeathSound "fre020"

	States
	{
		Spawn:
			TNT1 A 0 A_Spawn(38,0)
			SP10 A 4 Bright A_SeekTracer(0, 30.0)
			Loop
		Death:
			MISL B 8 Bright A_RadiusDamage(100, 128)
			MISL C 6 Bright
			MISL D 4 Bright
			TNT1 A 20
			Stop
	}
}

/////////////////////
//   DECORATIONS   //
/////////////////////

thing MTF_EXTRA10 "Pile of Bones"
{
	Ednum 1006
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP11 A -1
			Stop
	}
}

thing MTF_EXTRA11 "Skeleton on Floor"
{
	Ednum 1007
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP12 A -1
			Stop
	}
}

thing MTF_EXTRA12 "Fountain Red"
{
	Ednum 1008
	Radius 64
	Height 16

	States
	{
		Spawn:
			SP13 A 4 A_PlaySound(sound "fre025")
			SP13 BCDABCDABCD 4
			Loop
	}
}

thing MTF_EXTRA13 "Fountain Green"
{
	Ednum 1009
	Radius 64
	Height 16

	States
	{
		Spawn:
			SP14 A 4 A_PlaySound(sound "fre025")
			SP14 BCDABCDABCD 4
			Loop
	}
}

thing MTF_EXTRA14 "Fountain Blue"
{
	Ednum 1010
	Radius 64
	Height 16

	States
	{
		Spawn:
			SP15 A 4 A_PlaySound(sound "fre025")
			SP15 BCDABCDABCD 4
			Loop
	}
}

thing MTF_EXTRA15 "Fountain Brown"
{
	Ednum 1011
	Radius 64
	Height 16

	States
	{
		Spawn:
			SP16 A 4 A_PlaySound(sound "fre025")
			SP16 BCDABCDABCD 4
			Loop
	}
}

thing MTF_EXTRA16 "Fountain Black"
{
	Ednum 1012
	Radius 64
	Height 16

	States
	{
		Spawn:
			SP17 A 4 A_PlaySound(sound "fre025")
			SP17 BCDABCDABCD 4
			Loop
	}
}

thing MTF_EXTRA17 "Skeleton Statue Black"
{
	+SOLID

	Ednum 1013
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP18 A -1
			Stop
	}
}

thing MTF_EXTRA18 "Skeleton Statue Black Lit"
{
	+SOLID

	Ednum 1014
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP18 BC 8 Bright
			Loop
	}
}

thing MTF_EXTRA19 "Skeleton Statue White"
{
	+SOLID

	Ednum 1015
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP18 D -1
			Stop
	}
}

thing MTF_EXTRA20 "Skeleton Statue White Lit"
{
	+SOLID

	Ednum 1016
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP18 EF 8 Bright
			Loop
	}
}

thing MTF_EXTRA21 "Skeleton Statue Green"
{
	+SOLID

	Ednum 1017
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP18 G -1
			Stop
	}
}

thing MTF_EXTRA22 "Skeleton Statue Green Lit"
{
	+SOLID

	Ednum 1018
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP18 HI 8 Bright
			Loop
	}
}

thing MTF_EXTRA23 "Skeleton Statue Brown"
{
	+SOLID

	Ednum 1019
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP18 J -1
			Stop
	}
}

thing MTF_EXTRA24 "Skeleton Statue Brown Lit"
{
	+SOLID

	Ednum 1020
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP18 KL 8 Bright
			Loop
	}
}

thing MTF_EXTRA25 "Skeleton Statue Black Spooky"
{
	+SOLID

	Ednum 1021
	Radius 20
	Height 16

	States
	{
		Repeat:
			SP18 CB 8 Bright
			Loop
		Activate:
			SP18 B 8 Bright A_PlaySound(sound "fre023")
			Goto Repeat
		See:
			SP18 A 1 A_JumpIfTargetCloser("activate", 128.0)
			Loop
		Spawn:
			SP18 A 10 A_Look
			Loop
	}
}

thing MTF_EXTRA26 "Skeleton Statue White Spooky"
{
	+SOLID

	Ednum 1022
	Radius 20
	Height 16

	States
	{
		Repeat:
			SP18 FE 8 Bright
			Loop
		Activate:
			SP18 E 8 Bright A_PlaySound(sound "fre023")
			Goto Repeat
		See:
			SP18 D 1 A_JumpIfTargetCloser("activate", 128.0)
			Loop
		Spawn:
			SP18 D 10 A_Look
			Loop
	}
}

thing MTF_EXTRA27 "Skeleton Statue Green Spooky"
{
	+SOLID

	Ednum 1023
	Radius 20
	Height 16

	States
	{
		Repeat:
			SP18 IH 8 Bright
			Loop
		Activate:
			SP18 H 8 Bright A_PlaySound(sound "fre023")
			Goto Repeat
		See:
			SP18 G 1 A_JumpIfTargetCloser("activate", 128.0)
			Loop
		Spawn:
			SP18 G 10 A_Look
			Loop
	}
}

thing MTF_EXTRA28 "Skeleton Statue Brown Spooky"
{
	+SOLID

	Ednum 1024
	Radius 20
	Height 16

	States
	{
		Repeat:
			SP18 LK 8 Bright
			Loop
		Activate:
			SP18 K 8 Bright A_PlaySound(sound "fre023")
			Goto Repeat
		See:
			SP18 J 1 A_JumpIfTargetCloser("activate", 128.0)
			Loop
		Spawn:
			SP18 J 10 A_Look
			Loop
	}
}

thing MTF_EXTRA29 "Black Column"
{
	+SOLID

	Ednum 1025
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP19 A -1
			Stop
	}
}

thing MTF_EXTRA30 "Skull Pedestal"
{
	+SOLID

	Ednum 1026
	Radius 10
	Height 16

	States
	{
		Spawn:
			SP20 A -1
			Stop
	}
}

thing MTF_EXTRA31 "Serpent Statue"
{
	+SOLID

	Ednum 1027
	Radius 12
	Height 16

	States
	{
		Spawn:
			SP21 A -1
			Stop
	}
}

thing MTF_EXTRA32 "Wooden Barrel"
{
	+SOLID

	Ednum 1028
	Radius 10
	Height 16

	States
	{
		Spawn:
			SP22 A -1
			Stop
	}
}

thing MTF_EXTRA33 "Knight Statue"
{
	+SOLID

	Ednum 1029
	Radius 16
	Height 16

	States
	{
		Spawn:
			SP23 A -1
			Stop
	}
}

thing MTF_EXTRA34 "Demon Statue"
{
	+SOLID

	Ednum 1030
	Radius 16
	Height 16

	States
	{
		Spawn:
			SP24 A -1
			Stop
	}
}

thing MTF_EXTRA35 "Black Pine Tree"
{
	+SOLID

	Ednum 1031
	Radius 16
	Height 16

	States
	{
		Spawn:
			SP25 A -1
			Stop
	}
}

thing MTF_EXTRA36 "Brown Pile of Bones"
{
	Ednum 1032
	Radius 24
	Height 16

	States
	{
		Spawn:
			SP26 A -1
			Stop
	}
}

thing MTF_EXTRA37 "Tombstone 1"
{
	+SOLID

	Ednum 1033
	Radius 12
	Height 16

	States
	{
		Spawn:
			SP27 A -1
			Stop
	}
}

thing MTF_EXTRA38 "Tombstone 2"
{
	+SOLID

	Ednum 1034
	Radius 12
	Height 16

	States
	{
		Spawn:
			SP27 B -1
			Stop
	}
}

thing MTF_EXTRA39 "Tombstone 3"
{
	+SOLID

	Ednum 1035
	Radius 12
	Height 16

	States
	{
		Spawn:
			SP27 C -1
			Stop
	}
}

thing MTF_EXTRA40 "Tombstone 4"
{
	+SOLID

	Ednum 1036
	Radius 12
	Height 16

	States
	{
		Spawn:
			SP27 D -1
			Stop
	}
}

thing MTF_EXTRA41 "Tombstone 5"
{
	+SOLID

	Ednum 1037
	Radius 12
	Height 16

	States
	{
		Spawn:
			SP27 E -1
			Stop
	}
}

thing MTF_EXTRA43 "Ambience Creaking"
{
	+NOBLOCKMAP

	Ednum 1038

	States
	{
		Spawn:
			TNT1 A 245 A_PlaySound(sound "fre026")
			Loop
	}
}

thing MTF_EXTRA44 "Ambience Thunder"
{
	+NOBLOCKMAP

	Ednum 1039

	States
	{
		Spawn:
			TNT1 A 245 A_PlaySound(sound "fre027")
			Loop
	}
}

thing MTF_EXTRA45 "Ambience Wind"
{
	+NOBLOCKMAP

	Ednum 1040

	States
	{
		Spawn:
			TNT1 A 70 A_PlaySound(sound "fre028")
			Loop
	}
}

thing MTF_EXTRA46 "Ambience Swamp/Forest"
{
	+NOBLOCKMAP

	Ednum 1041

	States
	{
		Spawn:
			TNT1 A 87 A_PlaySound(sound "fre029")
			Loop
	}
}

thing MTF_EXTRA47 "Ambience Screaming/Crying"
{
	+NOBLOCKMAP

	Ednum 1042

	States
	{
		Spawn:
			TNT1 A 105 A_PlaySound(sound "fre030")
			TNT1 A 120 A_PlaySound(sound "fre038")
			TNT1 A 160 A_PlaySound(sound "fre031")
			TNT1 A 140 A_PlaySound(sound "fre037")
			TNT1 A 105 A_PlaySound(sound "fre032")
			TNT1 A 120 A_PlaySound(sound "fre036")
			TNT1 A 160 A_PlaySound(sound "fre033")
			TNT1 A 140 A_PlaySound(sound "fre034")
			TNT1 A 140 A_PlaySound(sound "fre035")
			Loop
	}
}

thing MTF_EXTRA48 "Ambience Fire"
{
	+NOBLOCKMAP

	Ednum 1043

	States
	{
		Spawn:
			TNT1 A 70 A_PlaySound(sound "fre039")
			Loop
	}
}

thing MTF_EXTRA49 "Ambience Dripping"
{
	+NOBLOCKMAP

	Ednum 1044

	States
	{
		Spawn:
			TNT1 A 157 A_PlaySound(sound "fre040")
			Loop
	}
}

thing MTF_EXTRA50 "Ambience Whispers"
{
	+NOBLOCKMAP

	Ednum 1045

	States
	{
		Spawn:
			TNT1 A 210 A_PlaySound(sound "fre041")
			Loop
	}
}

thing MTF_EXTRA51 "Demon Statue 2"
{
	+SOLID

	Ednum 1046
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP28 A -1
			Stop
	}
}

thing MTF_EXTRA52 "Angel Statue"
{
	+SOLID

	Ednum 1047
	Radius 24
	Height 16

	States
	{
		Spawn:
			SP28 B -1
			Stop
	}
}

thing MTF_EXTRA53 "Cauldron Still"
{
	+SOLID

	Ednum 1048
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP29 A -1
			Stop
	}
}

thing MTF_EXTRA54 "Cauldron Bubbling"
{
	+SOLID

	Ednum 1049
	Radius 20
	Height 16

	States
	{
		Spawn:
			SP29 BCDEFGH 4 Bright
			Loop
	}
}

thing MTF_EXTRA55 "Crystal Ball"
{
	+SOLID

	Ednum 1050
	Radius 10
	Height 16

	States
	{
		Spawn:
			SP30 A -1
			Stop
	}
}

thing MTF_EXTRA56 "Bloody Cleaver"
{
	Ednum 1051
	Radius 30
	Height 16

	States
	{
		Spawn:
			SP31 A -1
			Stop
	}
}

thing MTF_EXTRA57 "Pot 1"
{
	+SOLID

	Ednum 1052
	Radius 10
	Height 16

	States
	{
		Spawn:
			SP32 A -1
			Stop
	}
}

thing MTF_EXTRA58 "Pot 2"
{
	+SOLID

	Ednum 1053
	Radius 10
	Height 16

	States
	{
		Spawn:
			SP32 B -1
			Stop
	}
}

thing MTF_EXTRA60 "Hanging Man"
{
	Ednum 1055

	Health 100
	Radius 16
	Height 72
	Mass 10000000
	PainChance 256
	+SOLID
	+SPAWNCEILING
	+NOGRAVITY
	+SHOOTABLE
	+COUNTKILL

	PainSound "fre046"
	DeathSound "fre047"

	States
	{
		Spawn:
			SP33 A -1
			Loop
		Death:
			TNT1 A 0 A_AddFlags(nogravity)
			SP33 BC 6
			SP33 E 6 A_Scream
			SP33 F 6 A_KeenDie
			SP33 G 0 A_SpawnObject(MTF_EXTRA61)
			SP33 G -1
			Stop
		Pain:
			SP33 H 4
			SP33 H 8 A_Pain
			Goto Spawn
	}
}

thing MTF_EXTRA61 "Hanging Man's legs"
{
	States
	{
		Spawn:
			SP34 ABCD 4
			SP34 E -1
			Stop
	}
}

each thing from 135 to 137
{
	-NOBLOCKMAP
}