Solve[(47^(u + 1) + 3^(u + 1))/(u + 1) ==(50^1.5)/1.5,u]

Plot[(47^(u + 1) + 3^(u + 1))/(u + 1), {u, -50, 50},
 PlotRange -> {-1, 236}]

Solve[(47^(u+1)+3^(u+1))/(u+1)==(50^(3/2))/(3/2) && Abs[u]<1,u, Reals]

(* {{u->Root[{500 Sqrt[2]-3^(2+#1)-3 47^(1+#1)+500 Sqrt[2] #1&,-0.99133010386676537502}]},{u->Root[{500 Sqrt[2]-3^(2+#1)-3 47^(1+#1)+500 Sqrt[2] #1&,0.52441226301643480967}]}} *)

N[%]

(* {{u->-0.99133},{u->0.524412}} *)

Clear[f]
f[u_] := (47^(u + 1) + 3^(u + 1))/(u + 1) - (50^1.5)/1.5

sol =
  Reap@
   NDSolve[{
      D[y[u], u] == D[f[u], u], y[0] == f[0],
      WhenEvent[y[u] == 0, Sow[u]]},
     y, {u, -2, 2}
   ];

sol[[2, 1]]
(* Out: {-0.99133, 0.524412} *)

Show[
  Plot[f[u], {u, -2, 2}, PlotRange -> 1000],
  ListPlot[
    Callout[
      {#, 0}, Round[#, 0.001],
      LabelStyle -> Directive[Red, Medium]
    ] & /@ sol[[2, 1]],
    PlotStyle -> {Red, PointSize[0.015]}
  ]
]

With[
 {
  lhseqn = (47^(u + 1) + 3^(u + 1))/(u + 1),
  rhseqn = (50^1.5)/1.5
  },
 {u, lhseqn} /. Solve@Reduce[
    lhseqn == rhseqn
    , u
    , Reals
    ]
 ]

(* {{-0.99133, 235.702}, {0.524412, 235.702}} *)

Plot[
 {(3^(1 + u) + 47^(1 + u))/(1 + u), 235.70226039551585`}
 , {u, -2, 1}
 , Epilog -> {
   Red,
   PointSize[Large],
   Point[
    {
     {-0.9913301038667653`, 235.702260395515`},
     {0.5244122630164348`, 235.7022603955158`}
     }
    ]
   }]