doGivePerk, GiveWeaponPaP, and GiveEquipment

//include these in main
#include maps\mp\zombies\_zm_perks;
#include maps\mp\zombies\_zm_weapons;
#include maps\mp\zombies\_zm_equipment;

doGivePerk(perk, giveBottle)
{
    self endon("disconnect");
    self endon("death");
    level endon("game_ended");
    self endon("perk_abort_drinking");

    if (!(self hasperk(perk) || (self maps/mp/zombies/_zm_perks::has_perk_paused(perk))))
    {
        self.perk_purchased = perk;

        if (isDefined(giveBottle))
        {
            if (giveBottle)
            {
                gun = self maps/mp/zombies/_zm_perks::perk_give_bottle_begin(perk);
                evt = self waittill_any_return( "fake_death", "death", "player_downed", "weapon_change_complete" );
                self thread maps/mp/zombies/_zm_perks::wait_give_perk(perk, 1);
                self maps/mp/zombies/_zm_perks::perk_give_bottle_end(gun, perk);
            }
            else
                self thread maps/mp/zombies/_zm_perks::give_perk(perk, 1);
        }
        else
            self thread maps/mp/zombies/_zm_perks::give_perk(perk, 1);

        self.perk_purchased = undefined;

        if (self maps/mp/zombies/_zm_laststand::player_is_in_laststand() || isDefined(self.intermission) && self.intermission)
            return;

        self notify("burp");
    }
}

GiveWeaponPaP(str)
{
    if (str == "upgrade")
    {
        str = self getcurrentweapon();
        upgraded_weapons = getarraykeys(level.zombie_weapons_upgraded);
        upgraded_weapon_exists = false;
        upgraded_weapon = "";

        foreach(weapon in upgraded_weapons)
        {
            //self iprintln(weapon + " | " + level.zombie_weapons_upgraded[weapon]);
            if (level.zombie_weapons_upgraded[weapon] == str)
            {
                upgraded_weapon = weapon;
                upgraded_weapon_exists = true;
                break;
            }
        }

        if (upgraded_weapon_exists)
        {
            //self giveWeapon(level.zombie_weapons_upgraded[str]);
            //self switchToWeapon(level.zombie_weapons_upgraded[str]);
            self weapon_give( upgraded_weapon );
            self iprintln("^2Weapon upgraded!");
        }
        else
        {
            self iprintln("^1Current weapon cannot be upgraded!");
        }
    }
    else
    {
        self weapon_give( str );
        self iprintln("^2" + str + " given!");
    }
}

GiveEquipment(str)
{
    self equipment_give(str);
}