PKGBUILD (deadbeef-git)

# Maintainer: ToadKing <toadking at toadking dot com>
# Contributor: Soukyuu <chrno-sphered at hotmail dot com>
# Contributor: archtux <antonio dot arias99999 at gmail dot com>

pkgname=deadbeef-git
pkgver=r12098.c4140b137
pkgrel=1
pkgdesc="A GTK+ audio player for GNU/Linux (devel branch)"
url="https://deadbeef.sourceforge.io/"
arch=('i686' 'x86_64')
license=('GPL-2.0-or-later' 'LGPL-2.1-or-later' 'Zlib')
depends=('gtk3' 'alsa-lib' 'jansson' 'libdispatch' 'libFLAC.so')
makedepends=('libvorbis' 'libmad' 'flac' 'curl' 'imlib2' 'wavpack' 'libsndfile' 'libcdio'
             'libcddb' 'libx11' 'faad2' 'zlib' 'intltool' 'libpipewire' 'libpulse' 'libzip'
             'libsamplerate' 'yasm' 'ffmpeg' 'clang' 'opusfile' 'mpg123' 'git' 'gtk2')
optdepends=('gtk2: for the GTK2 interface'
            'alsa-oss: for OSS output plugin'
            'cdparanoia: for cd audio plugin'
            'curl: for last.fm, vfs_curl (shoutcast/icecast), artwork plugins'
            'dbus: for notification daemon support (OSD current song notifications)'
            'faad2: for AAC plugin'
            'ffmpeg: for ffmpeg plugin'
            'flac: for flac plugin'
            'imlib2: for artwork plugin'
            'libcddb: for cd audio plugin'
            'libcdio: for cd audio plugin'
            'libice: optional dependency for gtkui session client support'
            'libmad: for mp3 plugin (mpeg1,2 layers1,2,3)'
            'libogg: for ogg vorbis plugin'
            'libpipewire: for pipewire plugin'
            'libsamplerate: for dsp_libsrc plugin (resampler)'
            'libsm: optional dependency for gtkui session client support'
            'libsndfile: for sndfile plugin'
            'libvorbis: for ogg vorbis plugin'
            'libx11: for global hotkeys plugin'
            'libzip: for vfs_zip plugin'
            'mpg123: for MP1/MP2/MP3 playback'
            'opusfile: for opus plugin'
            'pulseaudio: for PulseAudio output plugin'
            'wavpack: for wavpack plugin'
            'yasm: required to build assembly portions of ffap plugin'
            'zlib: for Audio Overload plugin (psf, psf2, etc), GME (for vgz)')
conflicts=('deadbeef')
provides=('deadbeef=1.10.3')
source=('git+https://github.com/DeaDBeeF-Player/deadbeef.git')
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/${pkgname%-*}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/${pkgname%-*}"
  # skip osx/deps and external/apbuild submodules
  git -c submodule."osx/deps".update=none -c submodule."external/apbuild".update=none submodule update --init --recursive
}

build () {
  cd "$srcdir/${pkgname%-*}"
  export CC=clang CXX=clang++
  ./autogen.sh
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/${pkgname%-*}"
  make DESTDIR="${pkgdir}" install
  install -D COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}