Moderation CMD

$nomention
$defer

$enabled[yes;Command is disabled...for now.]


$var[user;$findUser[$message[user];yes]]

$title[**/// Attempting**]
$description[Attempting to *$message[type]* $username[$var[user]]#$discriminator[$var[user]] for $message[reason]...]
$color[#2f3135]


$var[title;a]
$var[description;a]
$var[dms;no]
$var[errCode;0]
$var[timestamp;0]

$if[$authorID!=$serverOwner]
$if[$rolePosition[$highestRole[$var[user]]]<=$rolePosition[$highestRole[$authorID]]]

  $title[**/// Insufficient Permissions**]
  $description[The user, <@$var[user]> has a higher rank than you and therefore can't receive Moderation.
> $rolePosition[$highestRole[$var[user]]] < **$rolePosition[$highestRole[$authorID]]**]
  $stop
$endif
$endif

$if[$isAdmin[$authorID]==false]
  $title[**/// Insufficient Permissions**]
  $description[You are not allowed to use the Moderation command because you are not an Administrator.
> $rolePosition[$highestRole[$var[user]]] < **$rolePosition[$highestRole[$authorID]]**]
$endif


$if[$var[user]==$authorID]
  $title[**/// Bruh**]
  $description[If you don't like being here, you know you can just leave the server, *right?*]
  $stop
$endif

$async[time]

$try

  $if[$message[unit]==m]
    $var[timestamp;$calculate[$message[duration]*60+$getTimestamp]]
  $elseif[$message[unit]==h]
    $var[timestamp;$calculate[$message[duration]*3600+$getTimestamp]]
  $elseif[$message[unit]==d]
    $var[timestamp;$calculate[$message[duration]*86400+$getTimestamp]]
  $elseif[$message[unit]==w]
    $var[timestamp;$calculate[$message[duration]*604800+$getTimestamp]]
  $endif

$endtry

$endasync

$await[time]

$try

$c[yep, error checking this whole thing aaaaaaaaa]

$if[$message[type]==warn]
  $c[warned]
$if[$isUserDMEnabled[$var[user]]==true]

$sendEmbedMessage[$dmChannelID[$var[user]];$c[content];
**/// WARNING**;$c[url];
You were warned in **$serverName[$guildID]**.
> Moderator: <@$authorID>
> Reason: $message[reason];#2f3135;$c[author];$c[author icon];$c[footer];$c[footer icon];$c[thumbnail];$c[image];yes;no]

$var[dms;yes]

$else

$title[**/// ERROR**]
  $description[The User, <@$var[user]> doesn't have DMs enabled. Therefore, the warn will have no effect.
> You can define a channel to send the Moderation Logs to as a fallback solution. soonᵗᵐ]
  $stop

$endif

$elseif[$message[type]==timeout]

$timeout[$message[duration]$message[unit];$var[user]]

$if[$isUserDMEnabled[$var[user]]==true]
  $c[timeout]
$sendEmbedMessage[$dmChannelID[$var[user]];$c[content];
**/// TIMED OUT**;$c[url];
You were timed out in **$serverName[$guildID]**.
> Moderator: <@$authorID>
> Reason: $message[reason]
> Length: $message[duration]$message[unit]
> Expires: <t:$var[timestamp]:R>
;#2f3135;$c[author];$c[author icon];$c[footer];$c[footer icon];$c[thumbnail];$c[image];yes;no]

$var[dms;yes]

$endif

$elseif[$message[type]==kick]

$kick[$var[user]]

  $c[kick]
$if[$isUserDMEnabled[$var[user]]==true]
$sendEmbedMessage[$dmChannelID[$var[user]];$c[content];
**/// KICKED**;$c[url];
You were kicked from **$serverName[$guildID]**.
> Moderator: <@$authorID>
> Reason: $message[reason]
;#2f3135;$c[author];$c[author icon];$c[footer];$c[footer icon];$c[thumbnail];$c[image];yes;no]

$var[dms;yes]

$endif

$elseif[$message[type]==ban]

$banID[$message[reason];$var[user]]

  $c[ban]
$if[$isUserDMEnabled[$var[user]]==true]
$sendEmbedMessage[$dmChannelID[$var[user]];$c[content];
**/// BANNED**;$c[url];
You were banned from **$serverName[$guildID]**.
> Moderator: <@$authorID>
> Reason: $message[reason]
;#2f3135;$c[author];$c[author icon];$c[footer];$c[footer icon];$c[thumbnail];$c[image];yes;no]

$var[dms;yes]
$endif


$elseif[$message[type]==untimeout]

  $c[untimeout]

  $if[$isUserDMEnabled[$var[user]]==true]
  $sendEmbedMessage[$dmChannelID[$var[user]];$c[content];
**/// TIMEOUT REMOVED**;$c[url];
You were removed from timeout in **$serverName[$guildID]**.
> Moderator: <@$authorID>
> Reason: $message[reason]
;#2f3135;$c[author];$c[author icon];$c[footer];$c[footer icon];$c[thumbnail];$c[image];yes;no]

  $var[dms;yes]
$endif

$endif



$catch

$title[**/// ERROR**]
$description[A fatal error occurred while $message[type]ing $username[$var[user]]#$discriminator[$var[user]].

**Function** `$error[command]` **returned an error at** `$error[row]:$error[column]` **with the following:**
```css
$error[message]
```]



$stop

$endtry


$title[**/// Success**]

$if[$message[type]==warn]
  $c[warned]
  $description[Successfully *warned* $username[$var[user]]#$discriminator[$var[user]] for the following:
> $message[reason]]
$elseif[$message[type]==timeout]
  $c[timeout]
  $description[Successfully *timed out* $username[$var[user]]#$discriminator[$var[user]] for the following:
> $message[reason]
> Time Issued: $message[duration]$message[unit]
> Expires <t:$var[timestamp]:R>]
$elseif[$message[type]==kick]
  $c[kick]
  $description[Successfully *kicked* $username[$var[user]]#$discriminator[$var[user]] for the following:
> $message[reason]]
$elseif[$message[type]==ban]
  $c[ban]
  $description[Successfully *banned* $username[$var[user]]#$discriminator[$var[user]] for the following:
> $message[reason]]
$elseif[$message[type]==untimeout]
  $c[untimeout]
  $description[Successfully removed the *timeout* for $username[$var[user]]#$discriminator[$var[user]] for the following:
> $message[reason]]
$endif

$thumbnail[$userAvatar[$var[user]]]

$if[$var[dms]==no]

$footer[The DM to $username[$var[user]] failed. This may be due to the user being a bot or the user turning off their DMs.]

$endif