Evento Sobrevivente

//By x Twilight
//Version 1.0

prontera,156,224,5	script	Evento Sobrevivente	734,{
disablenpc "sobreviventepremiador";

set @npc$,"[^ff1111 Sobrevivente ^000000]";

mes @npc$;
mes ""+strcharinfo(0)+", bem-vind"+(Sex?"o":"a")+" ao evento sobrevivente.";
mes "O que deseja fazer hoje?";
next;
if(getgmlevel() >= 80) set .@a$,"Manipular o evento";
switch(select("Entrar no evento","Informações",.@a$,"Sair"))
{
	next;
	mes @npc$;
	case 1:
		if(!$event_sobre)
		{
			mes "Desculpe, mas você não pode entrar no evento enquanto ele estiver fechado.";
			close;
		}
		mes "Boa sorte!";
		warp "guild_vs2",0,0;
		close;

	case 2:
		mes "Sobre o que você deseja se informar?";
		switch(select("Como funciona:Horários:Prêmiações:Nada"))
		{
			next;
			mes @npc$;

			case 1:
				mes "Quando o evento abrir, você deverá falar comigo para ser levado para um mapa especial.";
				next;
				mes @npc$;
				mes "Dentro desse mapa, você deverá aguardar 3 minutos para o início do evento.";
				next;
				mes @npc$;
				mes "Quando ele se iniciar, os jogadores dentro do mapa deverão se enfrentar.";
				next;
				mes @npc$;
				mes "A utilização de Fruto de Yggsrail e Semente de Yggdrasil são proibidas, caso você tentar usá-las, você não será curado.";
				next;
				mes @npc$;
				mes "O último jogador que sobreviver, ganha o evento e leva os prêmios.";
				mes "Boa sorte!";
				close;

			case 2:
				mes "O evento acontece todos os dias às 10 horas e às 20:15.";
				close;

			case 3:
				mes "Os prêmios são os seguintes:";
				for(set @i, 0; @i < getarraysize($id_premios); set @i, @i + 1)
					mes ""+$quantity_premios[@i]+" - "+getitemname($id_premios[@i])+"";
				close;

			case 4:
				mes "Volte quando quiser.";
				close;
		}

	case 3:
		mes "O que o senhor deseja fazer?";
		switch(select("Iniciar o evento:Mudar prêmiação:Sair"))
		{
			next;
			mes @npc$;

			case 1:
				if(!$event_sobre)
				{
					mes "O evento foi iniciado com sucesso.";
					close2;
					callsub start_event;
					end;
				}
				mes "O evento já foi iniciado.";
				close;

			case 2:
				mes "Você deseja mudar as prêmiações?";
				if(select("Não:Sim") == 1 ) close;
				next;
				mes @npc$;
				mes "Digite o ID do 1º item."; input @id_one;
				next;
				mes @npc$;
				mes "Digite a quantidade do 1º item."; input @quantity_one;
				next;
				mes @npc$;
				mes "Digite o ID do 2º item."; input @id_two;
				next;
				mes @npc$;
				mes "Digite a quantidade do 2º item."; input @quantity_two;
				next;
				mes @npc$;
				mes "Digite o ID do 3º item."; input @id_three;
				next;
				mes @npc$;
				mes "Digite a quantidade do 3º item."; input @quantity_three;
				next;
				mes @npc$;
				mes "1º prêmio: ^777777"+@quantity_one+" - "+getitemname(@id_one)+"^000000";
				mes "2º prêmio: ^777777"+@quantity_two+" - "+getitemname(@id_two)+"^000000";
				mes "3º prêmio: ^777777"+@quantity_three+" - "+getitemname(@id_three)+"^000000";
				next;
				if(select("Confirmar:Cancelar") == 2 ) close;
				next;
				mes @npc$;
				mes "Prêmiações editadas com sucesso.";
				close2;
				setarray $id_premios,@id_one,@id_two,@id_three;
				setarray $quantity_premios,@quantity_one,@quantity_two,@quantity_three;
				end;
			case 3:
				mes "Volte quando quiser.";
				close;
		}

	case 4:
		mes "Volte quando quiser.";
		close;
}
OnClock2015:
OnClock1000:
start_event:

	set $event_sobre,1;
	pvpoff "guild_vs2";
	announce "Evento Sobrevivente : O evento está aberto! Vocês tem apenas 3 minutos para entrar.",8;
	sleep 60000;
	announce "Evento Sobrevivente : O evento irá se iniciar, vocês tem de 2 minutos!",8;
	sleep 60000;
	announce "Evento Sobrevivente : O evento irá se iniciar, vocês tem 1 minuto! Corram, irá se fechar!",8;
	sleep 60000;

	set $event_sobre,0;

	mapannounce "guild_vs2","A batalha vai começar em 30 segundos.",bc_blue;
	sleep 25000;
	mapannounce "guild_vs2","05.",bc_blue;
	sleep 1000;
	mapannounce "guild_vs2","04.",bc_blue;
	sleep 1000;
	mapannounce "guild_vs2","03.",bc_blue;
	sleep 1000;
	mapannounce "guild_vs2","02.",bc_blue;
	sleep 1000;
	mapannounce "guild_vs2","01.",bc_blue;
	sleep 1000;

	if(getmapusers("guild_vs2") <= 1)
	{
			announce "Evento Sobrevivente : O evento foi cancelado por falta de jogadores.",8;
			end;
	}
	pvpon "guild_vs2";
	announce "Evento Sobrevivente : O evento começou!",8;
	end;

OnPCDieEvent:
	if(strcharinfo(3) == "guild_vs2")
	{
		warp "prontera",150,150;
		dispbottom "Você perdeu.";
	}
	sleep 1000;
	if(getmapusers("guild_vs2") == 1)
	{
		mapannounce "guild_vs2","Evento Sobrevivente : Você é vencedor(a)! Vá ao centro do mapa e retire seu prêmio.",bc_blue;
		enablenpc "sobreviventepremiador";
		end;
	}
	end;


OnInit:
set $event_sobre,0;
disablenpc "sobreviventepremiador";
end;
}

guild_vs2,49,49,4	script	Premiador#1::sobreviventepremiador	734,{

	announce "Evento Sobrevivente : "+(Sex?"O vencedor":"A vencedora")+" do evento sobrevivente foi [ "+strcharinfo(0)+" ]",bc_blue;
    for(set @i, 0; @i < getarraysize($id_premios); set @i, @i + 1)
		getitem $id_premios[@i],$quantity_premios[@i];
	warp "prontera",150,150;
	disablenpc "sobreviventepremiador";
	end;
    }

guild_vs2	mapflag	gvg	off
guild_vs2	mapflag	pvp	off
guild_vs2	mapflag	nowarp
guild_vs2	mapflag	nowarpto
guild_vs2	mapflag	nobranch
guild_vs2	mapflag	novending
guild_vs2	mapflag	nomemo
guild_vs2	mapflag	noteleport
guild_vs2	mapflag	zone	Mapa sem Ygg