<stdin>

actor "Combat Shotgun": Weapon
{
    Weapon.AmmoType  "CombatShell"
    Weapon.AmmoType2 "Shell"
    Weapon.AmmoUse1 1
    Weapon.AmmoUse2 0
    Weapon.AmmoGive1 8
    Weapon.AmmoGive2 8

    Weapon.SlotNumber 3
    Weapon.Kickback 100

    +AMMO_OPTIONAL
    +NOALERT

    Inventory.PickupMessage "You got the combat shotgun!"
    Obituary "%o ate a few loads of %k's combat shotgun."

    States
    {
      Ready:
        SHTG A 1 A_WeaponReady
        Loop

      Deselect:
        SHTG A 1 A_Lower
        Loop

      Select:
        SHTG A 1 A_Raise
        Loop

      Fire:
        SHTG A 0 A_JumpIfNoAmmo("AltFire")
        SHTG A 0 A_AlertMonsters

        SHTG A 0 A_FireBullets(ACS_ExecuteWithResult($DOOMRL_ACCURACY, 4,00,2)/100.0, ACS_ExecuteWithResult($DOOMRL_ACCURACY, 2,30,2)/100.0, 7, ACS_ExecuteWithResult($DOOMRL_DAMAGE, 5,2,0) )
        SHTG A 0 A_PlaySound ("weapons/shotgf", CHAN_WEAPON)
        SHTG A 2 bright offset(0, 36) A_GunFlash
        SHTG A 2 bright offset(0, 35)
        SHTG A 2 bright offset(0, 33)

        SHTG A 0 A_JumpIfNoAmmo(1)
        goto NoPump
        SHTG A 0 A_JumpIfInventory("Shell", 1, "AltFire")
        goto NoPump

      AltFire:
        SHTG A 0 A_JumpIfInventory("CombatShell", 0, "NoAltFire")
        SHTG A 0 A_JumpIfInventory("Shell", 1, 1)
        goto NoAltFire

        SHTG A 0 A_JumpIf(ACS_ExecuteWithResult($DOOMRL_GETSTAT, $STAT_SHOTTYMAN,0,0) >= 3, "Pump.SM3")
        SHTG A 2
        SHTG A 0 A_JumpIf(ACS_ExecuteWithResult($DOOMRL_GETSTAT, $STAT_SHOTTYMAN,0,0) == 2, "Pump.SM2")
        SHTG A 2
        SHTG A 0 A_JumpIf(ACS_ExecuteWithResult($DOOMRL_GETSTAT, $STAT_SHOTTYMAN,0,0) == 1, "Pump.SM1")
        SHTG A 2
        goto Pump.SM0

      NoAltFire:
        SHTG A 1 A_WeaponReady(12)
        SHTG A 0 A_WeaponReady
        goto Ready

      NoPump:
        SHTG A 4
        SHTG A 0 A_Refire
        goto Ready

      Pump.SM0:
        SHTG BC 5
        SHTG A 0 A_TakeInventory("Shell", 1)
        SHTG A 0 A_GiveInventory("CombatShell", 1)
        SHTG D  6
        SHTG CB 5
        SHTG A 4
        SHTG A 0 A_ReFire
        Goto Ready

      Pump.SM1:
        SHTG BC 4
        SHTG A 0 A_TakeInventory("Shell", 1)
        SHTG A 0 A_GiveInventory("CombatShell", 1)
        SHTG D  5
        SHTG CB 4
        SHTG A 4
        SHTG A 0 A_ReFire
        goto Ready

      Pump.SM2:
        SHTG BC 3
        SHTG A 0 A_TakeInventory("Shell", 1)
        SHTG A 0 A_GiveInventory("CombatShell", 1)
        SHTG D  3
        SHTG CB 3
        SHTG A 3
        SHTG A 0 A_ReFire
        goto Ready

      Pump.SM3:
        SHTG BC 3
        SHTG A 0 A_TakeInventory("Shell", 1)
        SHTG A 0 A_GiveInventory("CombatShell", 1)
        SHTG D  3
        SHTG CB 2
        SHTG A 2
        SHTG A 0 A_ReFire
        goto Ready

      Flash:
        SHTF B 3 Bright A_Light1
        SHTF A 2 Bright A_Light2
        Goto LightDone

      Spawn:
        SHOT A -1
        Stop
    }
}

actor CombatShell: Ammo
{
    Inventory.Amount 1
    Inventory.MaxAmount 5
    Ammo.BackpackAmount 0
    Ammo.BackpackMaxAmount 5

    Inventory.Icon "SHOTA0"

    +UNDROPPABLE
    +IGNORESKILL
}