# Maintainer: Alexander F. Rødseth <xyproto@archlinux.org>
# Contributor: Kaiting Chen <kaitocracy@gmail.com>
# Contributor: Gergely Imreh <imrehg@gmail.com>
# Contributor: champus, madeye, ranguvar and ninja_pt

pkgname=hwinfo
pkgver=21.58
pkgrel=1
pkgdesc='Hardware detection tool from openSUSE'
arch=('x86_64' 'armv7l')
url='https://github.com/openSUSE/hwinfo'
license=('GPL2')
depends=('perl')
makedepends=('flex' 'git' 'sysfsutils' 'patch')
options=('!emptydirs')
source=("https://github.com/openSUSE/$pkgname/archive/$pkgver.tar.gz"
        'custom_ioctl.patch')
sha256sums=('6708917d558e8768cfab65cd5a4fa0daa4326bd427b2455fac49c73137534ccf'
            '6e83b50aa34f31db5fe6de938402e7c4dda6ffa9ffe1346c076e4779018fcf1d')

prepare() {
  cd "$pkgname-$pkgver"
  patch -p0 -i ../custom_ioctl.patch
  echo 'touch changelog' > git2log
}

build() {
  make -C "$pkgname-$pkgver" -j1 \
    HWINFO_VERSION="$pkgver" \
    CFLAGS+="-fPIC -I$srcdir/$pkgname-$pkgver/src/hd" \
    LIBDIR=/usr/lib
}

package() {
  make -C "$pkgname-$pkgver" LIBDIR=/usr/lib DESTDIR="$pkgdir" install
  mv "$pkgdir/usr/sbin" "$pkgdir/usr/bin"
}

# getver: https://github.com/openSUSE/hwinfo/releases
# vim: ts=2 sw=2 et: