LDLS - convert line break format

' This program converts file line break format
' from CR+LF (13, 10 - DOS/Windows format)
' to LF (10 - Unix format)
new src dst rem 32 ' stream descriptors, length variable
new byte 8 ' byte to be read from stream
!stream.create src dst ' create streams
!stream.load src ' get stream from user
!stream.seek src 0 ' reset i/o position in it
_loop
  !stream.available src rem ' get number of remaining bytes
  if rem <= 0 goto _endloop ' in stream and exit if <= 0
  !stream.read src byte ' get next byte
  if rem <= 1 goto _not13 ' don't do check if it's last one
  if byte <> 13 goto _not13 ' not CR symbol
    !stream.read src byte ' read next byte
    if byte <> 10 !stream.write dst 13 ' if not LF,
  _not13                               ' write CR to dst
  !stream.write dst byte ' write current byte to dst
  goto _loop ' go to loop on top
_endloop
' display contents of stream:
!stream.seek dst 0
_out
  !stream.read dst byte
  !out.char byte
  !stream.available dst rem
  if rem > 0 goto _out
!stream.save dst ' let user save the file
!stream.delete src dst ' free used resources