Detours, 11/11/15

"Detours" by Philemon

Use American dialect.

Book One- "Mechanics I Guess"
[Fix returning and you'll have a fully-functional COMP. Then start describing existing mapped places, filling in existing rooms with NPCs and objects, and build the first puzzle]
Chapter Zero- Naming values that rely on nothing to define them

snowflake1 is a truth state that varies. Snowflake1 is usually false. [this variable figures out whether or not the player read Law or Chaos or both before reading Neutral in the Sea of the Subconcious]

Starting is a number that varies. Starting is usually zero. [1 is law, 2 is chaos, 3 is neutral we will see this a lot. It stores the first path that the player took which can potentially affect ending dialogs-- eg if the person you played through the endgame as was or was not the same as the path you originally set out on]

eggs is an object.

[strife, discord, disharmony for chaos, ordinance, equity, covenant, legislation for law,]

Chapter One- Actually trying

[Loyalty mechanic]
Loyalty is a kind of value. The loyalties are disloyal, law, neutral, chaos, unlaw, unneutral, unchaos, llaw, lneutral, lchaos, fudge, and loyal. Every person has a loyalty. The loyalty of people is usually disloyal. The loyalty of the player is usually fudge. A loyalty can be lawful or unlawful. A loyalty is usually unlawful. Llaw and law are lawful. A loyalty can be chaotic or unchaotic. A loyalty is usually unchaotic. Lchaos and chaos are chaotic. A loyalty can be neutralish or unneutralish. A loyalty is usually unneutralish. Lneutral and neutral are neutralish. A loyalty can be forbidden or permitted. A loyalty is usually forbidden. Law, llaw, chaos, lchaos, neutral, and lneutral are permitted. A loyalty can be agreeable or rude. A loyalty is usually rude. llaw, lchaos, lneutral, and loyal are agreeable.

Extremeism is a number that varies. Extremeism is usually 0.

[copypaste this with verb changes or don't because I just did doing something. note that most code I know how to write regarding reactions doesn't cover other people doing it]
Persuasion rule for asking people to try doing something:
	if the loyalty of the player is fudge, persuasion succeeds;
	if the loyalty of the person asked is agreeable, persuasion succeeds;
	if the loyalty of the person asked is law and the loyalty of the player is lawful, persuasion succeeds;
	if the loyalty of the person asked is neutral and the loyalty of the player is neutralish, persuasion succeeds;
	if the loyalty of the person asked is chaos and the loyalty of the player is chaotic, persuasion succeeds;
	if the loyalty of the person asked is unlaw and the loyalty of the player is unlawful, persuasion succeeds;
	if the loyalty of the person asked is unneutral and the loyalty of the player is unneutralish, persuasion succeeds;
	if the loyalty of the person asked is unchaos and the loyalty of the player is unchaotic, persuasion succeeds;
	else say "[person asked] and you have some ideological differences.".

Playability is a kind of value. The playabilities are playable and unplayable. Every person has a playability. The playability of people is usually unplayable. [Karine, Henri, and Anatole have a playability of playable. ]

A demon is a kind of person. A boy is a kind of man. A girl is a kind of woman. A PC is a kind of person.

A COMP is a kind of container. A COMP is usually enterable. [The default COMP is a wearable, enterable container with the description "I guess we're mass producing these things now?".]

Before entering a COMP:
	if the actor is not a demon, say "Only demons can enter a COMP, [if the player is male]wise guy[otherwise]smart alec[end if]." instead.

Ownership is a kind of value. The ownerships are Calculator, Laptop, Cell Phone, free-willed, sundae, and none. Every person has an ownership. The ownership of a person is usually free-willed. The ownership of a demon is usually none.

The playability of a PC is usually playable.

People have a number called Strength. Strength is usually 0.

To possess (victim - a person):
	if the playability of victim is unplayable:
		say "They're not a hero of this story.";
	Otherwise:
		say "Now you are [the victim]";
		now the player is victim.

Possessing is an action applying to one visible thing. Understand "possess [someone]" as possessing.

Check possessing:
	if the playability of the noun is unplayable:
		say "They're not a hero of this story." instead.

Carry out possessing:
	possess the noun.

Report possessing: say "Now you are [the noun]"

Using is an action applying to one visible thing. Understand "use [something]" as using.

Report using:
	say "You use it. Hard. Usefully. [paragraph break] It occurs to you that this was not something that was meant to be USED."

Understand the command "press" as something new.
Understand the command "pull" as something new.

Understand "press [something]" or "pull [something]" or "activate [something]" or "engage [something]" as using.

Talking to is an action applying to one visible thing. Understand "talk to [something]" as talking.

Calling is an action applying to one visible thing. Understand "call [something]" as calling.

Check talking to:
	if the noun is not a person, say "You strike up a lively conversation with an inanimate object." instead.

Report talking to:
	say "They don't seem much for conversation.".

Summoning is an action applying to one thing. Understand "summon [someone]" as summoning.

Check summoning:
	if the ownership of the noun is Calculator and the player is not Anatole, say "That's Anatole's demon, not yours! Ask him for it." instead;
	if the ownership of the noun is Laptop and the player is not Karine, say "That's Karine's demon, not yours! Ask her for it." instead;
	if the ownership of the noun is Cell Phone and the player is not Henri, say "That's Henri's demon, not yours! Ask him for it." instead;
	if the ownership of the noun is none, say "A demon needs to be in your COMP to summon them. And you can't just pick up other people's COMPs!" instead;
	if the ownership of the noun is free-willed, say "Humans can't be summoned. Try calling them instead." instead.

Carry out summoning:
	now the noun is in the location of the player;
	now the ownership of the noun is none.

Report summoning:
	say "You summon [the noun] from your COMP in a flash of [if the loyalty of the player is lawful]heavenly[else if the loyalty of the player is chaotic]sinister[otherwise]bright[end if] light!"

To return (subject - some demon) to (armthing - some comp):
	if armthing is visible,
		say "[subject] vanishes in a flash of [if the loyalty of the player is lawful]heavenly[otherwise if the loyalty of the player is chaotic]sinister[otherwise]bright[end if] light!";
		now the subject is in armthing.
	[otherwise say "Return where, exactly?" instead.]

Book Two- "Describing The World"

The description of a room is usually "you shouldn't be seeing this"

The Sea of the Subconcious is a room. [It is south of the Computer Lab.]  "There are three placards-- one labled Law, one labled Chaos, and one with a lable that is too faded to read".[The player is in the Sea of the Subconcious. ]Law Placard is an object in the Sea of the Subconcious. The description of Law Placard is "Law: Order, above all else-- at the cost of free will and creativity, even. The alignment of God and His angels, of lawmakers and tyrants."  Chaos Placard is an object in the Sea of the Subconcious. The description of Chaos Placard is "Chaos: Freedom, above all else-- at the cost of safety and fairness, even. The alignment of Satan and his demons, of freedom-fighters and murderers." Neutral Placard is an object in the Sea of the Subconcious. The description of the Neutral Placard is "[if snowflake1 is true]Or perhaps[otherwise]Perhaps[end if] you will chose [if snowflake1 is true]a different[otherwise]your own[end if] path?" The printed name of the Neutral Placard is "a faded placard". The printed name of the Law Placard is "the Law placard". The printed name of the Chaos placard is "the Chaos placard".

Chaos Placard, Law Placard, and Neutral Placard are fixed in place.

Understand "faded" and "faded placard" and "the faded placard" as Neutral Placard.

Understand "read [something]" as examining.

After examining Law Placard:
	now snowflake1 is true;
	say "Is this your will? Y/N";
	if the player consents:
		now the player is Anatole;
		now starting is 1;
		try silently looking;
	otherwise:
		say "Very well.".


After examining Neutral Placard:
	now snowflake1 is false;
	say "Is this your will? Y/N";
	if the player consents:
		now the player is Karine;
		now starting is 3;
		try silently looking;
	otherwise:
		say "Very well.".


After examining Chaos placard:
	now snowflake1 is true;
	say "Is this your will? Y/N";
	if the player consents:
		now the player is Henri;
		now starting is 2;
		try silently looking;
	otherwise:
		say "Very well.".

The Computer Lab is a room. North of The Computer Lab is Lower Hallway. Up from Lower Hallway is Upper Hallway. South of Upper Hallway is History Room. Up from Upper Hallway is Roof.

There is a PC in the Computer Lab called Anatole. The description of Anatole is "Brun." Anatole is male. The loyalty of Anatole is llaw.

There is a PC in the History Room called Karine. The description of Karine is "Noire." Karine is female. Kairne is carrying a COMP called Karine's COMP. The description of Karine's COMP is "[if the player is Karine]Your [otherwise]Karine's [end if]COMP. A laptop computer running the latest in software, leeching Internet from the shrieking void you've found yourself in. [if the player is Karine]Sure, it's[otherwise]It's[end if] not [if the player is not Karine]nearly [end if]as portable as[if the player is Anatole] yours or Henri's,[otherwise if the player is Henri] yours or Anatole's,[otherwise] those of the boys, but at least it's not nearly as ridiculous.[end if][if the player is not Karine] and you can't figure out why Karine won't upgrade.[end if][if the player is Karine]You've got your friends['] USERNAMES here, and you can shoot them a quick MESSAGE if you'd like. No idea how Anatole gets his. [otherwise if the player is Anatole] You know Karine uses an instant messaging program but to be honest you can't figure out how this whole Graphical User Interface thing works. [otherwise] You know Karine uses an instant messaging program, but you can't find the icon for it amid all of her stuff.[end if]". The loyalty of Karine is lneutral.

There is a PC in the Roof called Henri.  The description of Henri is "Blond." Henri is male. The Strength of Henri is 1. Henri is wearing a wearable COMP called Henri's COMP.

Anatole is wearing a wearable COMP called Anatole's COMP. The description of Anatole's COMP is "[if the player is Anatole]Your trusty[otherwise]Anatole's[end if] COMP. It's made out of a few graphing calculators that display slowly rendered, low-res pentagrams and a tangle of leather straps that attach it to the user's arm.[if the player is Anatole] God you love it.[otherwise] Yours is so much better.[end if][if the player is Anatole] By INTONING your friends['] TRUE NAMES, you can transmit messages straight into their heads! Pretty neat, right?[otherwise] Anatole scratched some Nordic runes into the straps here but you have no clue what they might mean.[end if]".

Section 1- True Names

A true name is a kind of thing.

Henri's Username is a part of Karine's COMP. Henri's Username is a true name. The description of Henri's Username is "[if the player is Henri]You have a pretty killer username. [else if the player is Karine]How utterly juvenile.[Otherwise]Maybe it's about time Henri change his username.[end if]". Anatole's Username is a part of Karine's COMP. Anatole's Username is a true name. The description of Anatole's Username is "[if the player is Anatole]You've had the same username since you were small.[else if the player is Henri]Anatole's username could use a bit of a facelift, in your opinion.[otherwise]Anatole's username is about as cute and nonthreatening as he is.[end if]".

Henri's True Name is part of Anatole's COMP. Henri's True Name is a true name. Karine's True Name is part of Anatole's COMP. Karine's True Name is a true name. The description of Henri's True Name is "[if the player is Anatole]Henri's True Name would be too embarassing to say in public. [otherwise]Some weird symbols. Is there a heart there?[end if]". The description of Karine's True Name is "[if the player is Anatole]Karine's True Name is pretty unassuming if you're being honest with yourself.[otherwise] This could be Demonic Alphabet Soup for all you know.[end if][If the player is Henri] Or care.[end if]".

Understand "laptop" as Karine's COMP.
Understand "calculator" or "calculators" as Anatole's COMP.
Understand "phone" or "mobile" or "cell phone" or "cell" as Henri's COMP.

Understand "runes" as Henri's True Name.

Understand "use [some true name]" as calling.
Understand "intone [some true name]" as calling.
Understand "message [some true name]" as calling.


Section 1.1-- Calling people by their names is hard

After reading a command:
	if the player's command matches "call Henri" or the player's command matches "intone Henri" or the player's command matches "message Henri":
		if the player is Henri:
			say "Very funny.";
			stop the action;
		if the player is not carrying Karine's COMP or wearing Anatole's COMP or wearing Henri's COMP:
			say "Laptops should be carried, and post-appocalyptic demonic computing solutions worn, before a call is placed. This is elementary.";
			stop the action;
		otherwise:
			possess Henri;
			stop the action;
	otherwise:
		do nothing.

After reading a command:
	if the player's command matches "call Karine" or the player's command matches "intone Karine" or the player's command matches "message Karine":
		if the player is Karine:
			say "Very funny.";
			stop the action;
		if the player is not carrying Karine's COMP or wearing Anatole's COMP or wearing Henri's COMP:
			say "Laptops should be carried, and post-appocalyptic demonic computing solutions worn, before a call is placed. This is elementary.";
			stop the action;
		otherwise:
			possess Karine;
			stop the action;
	otherwise:
		do nothing.

After reading a command:
	if the player's command matches "call Anatole" or the player's command matches "intone Anatole" or the player's command matches "message Anatole":
		if the player is Anatole:
			say "Very funny.";
			stop the action;
		if the player is not carrying Karine's COMP or wearing Anatole's COMP or wearing Henri's COMP:
			say "Laptops should be carried, and post-appocalyptic demonic computing solutions worn, before a call is placed. This is elementary.";
			stop the action;
		otherwise:
			possess Anatole;
			stop the action;
	otherwise:
		do nothing.


Instead of calling Henri's True Name:
	possess Henri.

Instead of calling Karine's True Name:
	possess Karine.

Instead of calling Henri's Username:
	possess Henri.

Instead of calling Anatole's Username:
	possess Anatole.

[If a demon is contained by Anatole's COMP, now the ownership of Pixie is Calculator.]

Book Three- Stuff Now Happens

Lord Of The Goddamn Flies is a scene. Lord Of The Goddamn Flies begins when Extremeism is 10.

Book Zero - Junk code - Not for release

Testing Room is a room.  The player is in the testing room. Pixie is a demon in the testing room. The loyalty of Pixie is loyal. Angel is a demon in the testing room. The loyalty of Angel is law. Imp is a man in the testing room. The loyalty of Imp is chaos. Robot is a demon in the testing room. The loyalty of Robot is neutral. Asshole is a man in the testing room. The loyalty of Asshole is unneutral. Jesus is a man in the testing room. The loyalty of jesus is unchaos. Fawkes is a man in the testing room. The loyalty of Fawkes is unlaw. Blondie is a man in the testing room. The loyalty of Blondie is lchaos. Bruno is a man in the testing room. The loyalty of Bruno is llaw.  Dark Hair is a woman in the testing room. The loyalty of Dark Hair is lneutral. North of the Testing Room is Destination. The playability of Pixie is playable. The ownership of Pixie is Calculator. The ownership of Robot is sundae.

The Developer's Tool is a wearable, enterable COMP worn by the player. The description of the Developer's Tool is "Buttons and widgets and stuff. The white, black, and gray buttons set your morality to Law, Chaos, and Neutral, respectively. The Return Widget sends you between the Computer Lab and the Testing Room. The flower button returns your helpful friend Pixie from anywhere into the tool. The butterfly button puts you in the Sea of the Subconcious. There's also more complicated machinery: an intention dial, and a doodad.". The White button is a part of the Developer's Tool. The Black button is a part of the Developer's Tool. The Gray Button is a part of the Developer's Tool. The Return Widget is a part of the Developer's tool. The flower button is a part of the Developer's Tool. Anatole's Widget is a part of the developer's tool. Anatole's Widget is a true name. The butterfly button is a part of the Developer's Tool. The intention dial is a part of the Developer's Tool. The description of the intention dial is "This dial records the path the player first intended to follow. Currently, it [if starting is zero]is spinning around aimlessly.[else if starting is one]reads Law.[else if starting is two]reads Chaos.[else if starting is three]reads Neutral.[otherwise]is accusing you of cheating.[end if]". The doodad is a part of the Developer's Tool. The description of the doodad is "You're not sure what the fuck this is measuring. It tends to change. [if snowflake1 is true]True.[otherwise]False.[end if]".

Instead of calling Anatole's widget:
	possess Anatole.

Instead of using the white button:
	now the loyalty of the player is law.

Instead of using the flower button:
	return Pixie to Developer's Tool.

Instead of using the butterfly button:
	now the player is in the Sea of the Subconcious.

instead of using the black button:
	now the loyalty of the player is chaos.

instead of using the gray button:
	now the loyalty of the player is neutral.

instead of using the Return Widget:
	if the player is in the Computer Lab, now the player is in the Testing Room;
	else now the player is in the Computer lab.