@echo off
SET VPPATH=C:\Visual Pinball
SET POVS=
SET VBSS=

if [%1] == [] (SET /P FOLDER=Enter Folder Name: ) ELSE (SET FOLDER=%1%)

CHOICE /T 5 /D Y /M "Extract POV Files? "
IF "%ERRORLEVEL%"=="1" (SET POVS=y)

CHOICE /T 5 /D Y /M "Extract VBS Files? "
IF "%ERRORLEVEL%"=="1" (SET VBSS=y)

if /I "%POVS%"=="" (if /I "%VBSS%"=="" (Echo Nothing Selected to Extract & goto END))

for /f "tokens=* delims=" %%f in ('dir "%FOLDER%"\*.vpx /s /b') do (
    ECHO Processing %%f
    if /I "%POVS%"=="y" (
        if exist "%%~df%%~pf%%~nf.pov" (
          ECHO   Skipping POV as %%~nf.pov already exists
        ) ELSE (
          ECHO   Extracting POV from "%%f"
          start "VPX" /D "%VPPATH%" /min /wait VPinballX.exe -pov "%%f"
        )
    )

    if /I "%VBSS%"=="y" (
        if exist "%%~df%%~pf%%~nf.vbs" (
          ECHO   Skipping VBS as %%~nf.vbs already exists
        ) ELSE (
          ECHO   Extracting VBS from "%%f"
          start "VPX" /D "%VPPATH%" /min /wait VPinballX.exe -extractvbs "%%f"
        )
    )
)

:END
pause