Lesson 4.4

//@version=5
strategy("Michaels Bands SL", overlay=true)

stopLossPercentage = input.float(3, "Stop Loss Percentage") * 0.01
takeProfitPercentage = input.float(3, "Take Profit Percentage") * 0.01

ema12 = ta.ema(close, 12)
ema21 = ta.ema(close, 21)

var line stopLossLine = na
var line takeProfitLine = na

if strategy.position_size == 0 // If we don't have a position we reset the lines to na
    stopLossLine := na
    takeProfitLine := na
else
    stopLossLine.set_x2(bar_index) // If we do have a position we extend the lines to the next bar
    takeProfitLine.set_x2(bar_index)

if ta.crossover(ema12, ema21) and strategy.position_size <= 0
    stopLoss = close * (1 - stopLossPercentage)

    takeProfit = close * (1 + takeProfitPercentage)

    stopLossLine := line.new(bar_index, stopLoss, bar_index, stopLoss, color=color.red)
    takeProfitLine := line.new(bar_index, takeProfit, bar_index, takeProfit, color=color.green)

    strategy.entry("Long", strategy.long)
    strategy.exit("SL / TP", "Long", stop=stopLoss, limit=takeProfit)

if ta.crossunder(ema12, ema21) and strategy.position_size >= 0
    stopLoss = close * (1 + stopLossPercentage)

    takeProfit = close * (1 - takeProfitPercentage)

    stopLossLine := line.new(bar_index, stopLoss, bar_index, stopLoss, color=color.red)
    takeProfitLine := line.new(bar_index, takeProfit, bar_index, takeProfit, color=color.green)

    strategy.entry("Short", strategy.short)
    strategy.exit("SL / TP", "Short", stop=stopLoss, limit=takeProfit)


bandColor = ema12 > ema21 ? color.green : color.red
plot(ema12, color=bandColor, linewidth=1)
plot(ema21, color=bandColor, linewidth=3)