!Born for justin.tv

;Born script for justin.tv by Ford_Lawnmower irc.geekshed.net #Script-Help
menu Channel,Status {
  .$iif($group(#born_on_date) == On,$style(1)) born_on_date Trigger
  ..$iif($group(#born_on_date) == On,$style(2)) On: .enable #born_on_date
  ..$iif($group(#born_on_date) == Off,$style(2)) Off: .disable #born_on_date
}
#born_on_date on
On $*:Text:/^!born\s(.+)/gi:#: {
  var %user $strip($regml(1))
  if (!$timer($+(born_on_date,$network,$nick))) {
    .timer $+ $+(born_on_date,$network,$nick) 1 6 noop
    Getborn_on_date .msg # %user
  }
}
#born_on_date end
alias born { Getborn_on_date echo -a $1- }
alias -l Getborn_on_date {
  $1-2 Searching........
  var %sockname $+(born_on_date,$network,$2,$ticks)
  sockopen %sockname www.justin.tv 80
  svar %sockname output $1-2
  svar %sockname url $+(/meta/,$3,.xml)
  svar %sockname user $3
}
On *:sockopen:born_on_date*: {
  if (!$sockerr) {
    sockwrite -nt $sockname GET $svar($sockname,url) HTTP/1.0
    sockwrite -n $sockname Host: $sock($sockname).addr
    sockwrite -n $sockname $crlf
  }
  else { echo -st Socket Error $nopath($script) | sockclose $sockname | return }
}
On *:sockread:born_on_date*: {
  if ($sockerr) { echo -st Socket Error $nopath($script) | sockclose $sockname | return }
  else {
    var %born_on_date | sockread %born_on_date
    if ($regex(born,%born_on_date,/<created_on>(.*)</created_on>/i)) {
      $svar($sockname,output) $svar($sockname,user) was born on $asctime($regml(born,1))
      sockclose $sockname
    }
  }
}
On *:sockclose:born_on_date*: {
  $svar($sockname,output) No such user: $svar($sockname,user)
}
alias -l Svar {
  var %sockname $1, %item $2
  if ($isid) {
    if ($regex($sock(%sockname).mark,/ $+ %item $+ \x01([^\x01]*)/i)) return $regml(1)
  }
  elseif ($3)  {
    var %value $3-
    if (!$regex($sock(%sockname).mark,/ $+ %item $+ \x01/i)) { sockmark %sockname $+($sock(%sockname).mark,$chr(1),%item,$chr(1),%value) }
    else { sockmark %sockname $regsubex($sock(%sockname).mark,/( $+ %item $+ \x01[^\x01]*)/i,$+(%item,$chr(1),%value)) }
  }
}