Execute Perform

alias curconserv {
  if ($status == connected) && ($network !isnum) {
    if ($network) { return $network }
    else { return $server }
  }
  else { return disconnected }
}
alias reperform {
  if ($1 == -a) { _do scon -at1 reperform }
  else {
    var %y = $_txtdir(perform.txt),%r $read(%y,tnw,[[ $+ $curconserv $+ ]])
    if ($status != connected) { errdialog You are not connected. }
    elseif (%r) {
      unset %rpfrm.done
      var %l $readn + 1,%n 1
      while (1) {
        var %r $read(%y,tn,%l)
        if (!$regex(%r,/^(\[[^\]\[]+\])$/)) && ($readn <= $lines(%y)) {
          if (%r != $null) {
            set %rpfrm.done 1
            perform_timer $cid $calc(%n * 2) $calc(%n * 1) %r
            inc %n
          }
          inc %l
        }
        else break
      }
      if (%rpfrm.done) {
        unset %rpfrm.done
        thmecho -a Executed perform list on $thmhl($curconserv) $+ .
      }
    }
    elseif ($exists(%y)) { thmerror -a Perform list for $thmhl($curconserv) is empty. }
    else { thmerror -a Perform.txt file not found. }
  }
}