; Script generated by the Inno Script Studio Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define MyAppName "Hybrid"
#define MyAppVersion "0.2.6"
#define MyAppPublisher "Selurs Software"
#define MyAppURL "https://www.selur.de"
#define MyAppExeName "Hybrid.exe"
#define Revision GetDateTimeString('yyyy.mm.dd','','');
#define Build GetDateTimeString('yyyy.mm.dd-hms','','');
#define CopyRight "Hybrid (C) Selurs Software"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{111111-F700-4B35-A58C-99429D7E3240}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
;AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultDirName={commonpf}\{#MyAppName}
DefaultGroupName={#MyAppName}
LicenseFile=F:\InnoInstaller\License files\hybrid.rtf
OutputBaseFilename=Hybrid_dev_{#Build}
SetupIconFile=F:\InnoInstaller\hybrid-install-icon3.ico
Compression=lzma2/ultra64
InternalCompressLevel=ultra64
SolidCompression=yes
LZMANumBlockThreads=16
VersionInfoVersion={#Revision}
AppCopyright={#CopyRight}
ArchitecturesInstallIn64BitMode=x64
LZMAUseSeparateProcess=yes
LZMADictionarySize=1048576
;LZMADictionarySize=524288

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"
Name: "brazilianportuguese"; MessagesFile: "compiler:Languages\BrazilianPortuguese.isl"
Name: "catalan"; MessagesFile: "compiler:Languages\Catalan.isl"
Name: "corsican"; MessagesFile: "compiler:Languages\Corsican.isl"
Name: "czech"; MessagesFile: "compiler:Languages\Czech.isl"
Name: "danish"; MessagesFile: "compiler:Languages\Danish.isl"
Name: "dutch"; MessagesFile: "compiler:Languages\Dutch.isl"
Name: "finnish"; MessagesFile: "compiler:Languages\Finnish.isl"
Name: "french"; MessagesFile: "compiler:Languages\French.isl"
Name: "german"; MessagesFile: "compiler:Languages\German.isl"
Name: "hebrew"; MessagesFile: "compiler:Languages\Hebrew.isl"
Name: "italian"; MessagesFile: "compiler:Languages\Italian.isl"
Name: "japanese"; MessagesFile: "compiler:Languages\Japanese.isl"
Name: "norwegian"; MessagesFile: "compiler:Languages\Norwegian.isl"
Name: "polish"; MessagesFile: "compiler:Languages\Polish.isl"
Name: "portuguese"; MessagesFile: "compiler:Languages\Portuguese.isl"
Name: "russian"; MessagesFile: "compiler:Languages\Russian.isl"
Name: "slovenian"; MessagesFile: "compiler:Languages\Slovenian.isl"
Name: "spanish"; MessagesFile: "compiler:Languages\Spanish.isl"
Name: "turkish"; MessagesFile: "compiler:Languages\Turkish.isl"
Name: "ukrainian"; MessagesFile: "compiler:Languages\Ukrainian.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Files]
Source: "F:\InnoInstaller\Hybrid.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:\InnoInstaller\32bit\*"; DestDir: "{app}\32bit"; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: "enc_fhgaac.dll, neroAacEnc.exe, libmp4v2.dll, nsutil.dll, DGDecNV.ini, DGIndex.ini"
Source: "F:\InnoInstaller\64bit\*"; DestDir: "{app}\64bit"; Flags: ignoreversion recursesubdirs createallsubdirs; Excludes: "__pycache__, nvcuvenc.dll"
Source: "F:\InnoInstaller\License files\*"; DestDir: "{app}\License files"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "F:\InnoInstaller\CustomSynthScripts\*"; DestDir: "{app}\CustomSynthScripts"; Flags: ignoreversion recursesubdirs createallsubdirs;
; QT files
Source: "F:\InnoInstaller\Qt6*.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:\InnoInstaller\platforms\*"; DestDir: "{app}\platforms"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "F:\InnoInstaller\styles\*"; DestDir: "{app}\styles"; Flags: ignoreversion recursesubdirs createallsubdirs
; runtime files
Source: "F:\InnoInstaller\vcruntime140*.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:\InnoInstaller\msvcp140*.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "F:\InnoInstaller\lib*.dll"; DestDir: "{app}"; Flags: ignoreversion
; NOTE: Don't use "Flags: ignoreversion" on any shared system files

[Icons]
Name: "{group}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"
Name: "{group}\{cm:UninstallProgram,{#MyAppName}}"; Filename: "{uninstallexe}"
Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon

[Code]
procedure CurUninstallStepChanged(CurUninstallStep: TUninstallStep);
var
  mres: integer;
begin
  case CurUninstallStep of
    usPostUninstall:
    begin
      mres := MsgBox('Do you want to delete all settings?', mbConfirmation, MB_YESNO or MB_DEFBUTTON2);
      if mres = IDYES then
        DelTree(ExpandConstant('{userappdata}\hybrid'), True, True, True);
    end;
  end;
end;