#include <fix_fft.h> //dolaczenie biblioteki z algorytmem fix_fft
const float pi = 3.14159; //deklaracja stałej PI do obliczen
const int N = 8; // określenie rozmiaru okna potęgą liczby 2
const int rozmiar_okna = 1 << N; //deklaracja parametru rozmiaru okna 1 << N = 2^N - przesun bit o N w prawo
float fHann[rozmiar_okna]; //inicjalizacja funkcji okna
char sample[rozmiar_okna]; //inicjalizacja buforu próbek - czesc rzeczywista
char sample_im[rozmiar_okna]; //inicjalizacja buforu próbek - czesc urojona

//const int wysokosc_kolumny[8] = {251 , 247 , 254 , 253 , 191 , 127 , 239 , 223}; // tabela wartosci uzywanych do wyswietlenia wysokosci kolumny LED (tylko szczyt)
const int wys_kol[8] = {251 , 243 , 242 , 240 , 176 , 48 , 32 , 0}; // tabela wartosci uzywanych do wyswietlenia wysokosci kolumny LED (kolumna wypelniona)
// tylko do odczytu (const int)

int wartosc_kolumny[8]; //tablica uzywana do obslugi wysokosci kolumny
int k; //globalna zmienna do czytania wartosc_kolumny w obsludze przerwan

void setup() {

  //konfiguracja portów ARDUINO

  DDRA |= B11111111; //ustaw caly port A jako OUTPUT, ukladowo sluzy jako sterowanie wysokoscia kolumny zerem 22 -> 29
  DDRC |= B11111111; //ustaw caly port C jako OUTPUT, ukladowo sluzy jako sterowanie zasilaniem kolumny jedynka 37 -> 30

  // ustaw przerwania timer1 co 400 Hz
  TCCR1A = 0; // set entire TCCR1A register to 0
  TCCR1B = 0; // same for TCCR1B
  TCNT1  = 0; //initialize counter value to 0

  //  ustaw rejestr timer1 na zliczanie 400 Hz
  OCR1A = 39;// = (16*10^6) / (391*1024) - 1 ; 391*1024 ~ 400000
  TCCR1B |= (1 << WGM12); // wlacz tryb CTC - Clear Timer on Compare
  TCCR1B |= (1 << CS12) | (1 << CS10);  // Ustaw bity CS10 i CS12 dla preskalera 1024
  TIMSK1 |= (1 << OCIE1A); // wlacz tryb timer compare interrupt

  sei(); //zezwól na przerwania
  PORTC = 1; //zainicjuj stan portu C

  for (int z = 0; z < rozmiar_okna; z++) { //generacja funkcji Hanna dla wybranego rozmiaru okna

    fHann[z] = (sin((pi * z) / rozmiar_okna)) * (sin((pi * z) / rozmiar_okna));

  }

}

void loop() {

  //spróbkuj sygnał audio + naloz funkcje okna
  for (int c = 0; c < rozmiar_okna ; c++) {
    sample[c] = analogRead(A0) * fHann[c]; //okolo 30 ms
    sample_im[c] = 0;
  }
  //próbka gotowa do FFT

  //wykonaj algorytm FFT z biblioteki fix_fft.h - nieznany czas trwania
  fix_fft(sample, sample_im, N, 0);
  //fix_fft(a , b , c , d)
  //a - tabela wartosci rzeczywistych [char]
  //b - tabela wartosci zespolonych [char]
  //c - rozmiar okna = 2^c [int]
  //d - kierunek FFT 0 - obliczanie widma , 1 - obliczanie sygnalu  int

  for (int d = 0; d < rozmiar_okna; d++) {
    sample[d] = sqrt(sample[d] * sample[d] + sample_im[d] * sample_im[d]); //oblicz wartosci skuteczne |z| = sqrt(Re*Re + Im*Im)
  }  // sample[0 -> rozmiar_okna / 2] zawiera teraz wartosci skuteczne widma
  //przypisanie poszczegolnych wartosci sample[] jako wys_kol[0 - 7] do wartosc_kolumny :
  for (int e = 0; e < N; e++) {
    wartosc_kolumny[e] = wys_kol[(sample[1 << e]) / 128];
  }
}

ISR(TIMER1_COMPA_vect) { //obsługa przerwania timer1 - timer1 compare interrupt service routine. Jedno przerwanie - jedno przesuniecie bitu sterowania kolumna

  if (PORTC != B10000000) // jezeli PORTC jest rozny od 0 to :
  {
    PORTC = PORTC << 1; //przesun bit o jeden w lewo
    k++; //k = k + 1, przesun odczyt z wartosc_kolumny
    PORTA = wartosc_kolumny[k]; //wybierz wysokosc kolumny z tablicy
  }
  else {
    PORTC = B00000001; // jezeli PORTC jest rowny zero ustaw jedynke na osmy bit
    k = 0; //ustaw odczyt z wartosc_kolumny dla kolumny 1
    PORTA = wartosc_kolumny[k]; //wybierz wysokosc kolumny z tablicy
  }

}