Double Axe - Whirlwind

////******************************************************////
//Title: Double Axe Whirlwind
//Author: Maelune
//Version: 1.0
//Purpose: Automatically equip your axe, select the closest target, and
//         begin whirlwinding!
//
//Requirements: A Double Axe
//
//Instructions: Copy this entire text into a UOSteam Macro! Replace the serial
//              ID of the axe at the beginning of the macro with that of your own.
//
//Notes: This macro will constantly be trying to switch to the nearest target
//       in order to keep your character whirlwinding as much as possible.
//       Several of the buffs are turned off by default due to long cast
//       times. They can be useful though depending on what you fight.
//       Uncomment the ones you'd like to use!
////******************************************************////
if not @findobject 'axe'
  @setalias 'axe' 0x4296e090 //Replace me with your axe's serial!
endif
////******************************************************////
clearignorelist
while @getenemy 'murderer' 'enemy' 'gray' 'criminal' 'closest'
  while @findobject 'axe' 'any' 'backpack'
    clearhands right //Uncomment this one if 1handed axe
    //clearhands both //Uncomment this one if 2handed axe
    pause 300
    equipitem 'axe' 1
  endwhile
  attack! 'enemy'
  if mana >= 10
    @setability 'secondary' 'on'
  endif
  //***Self Buffs. Comment or uncomment to your liking!***//
  if not timerexists 'ConsecrateWeaponTimer'
    createtimer 'ConsecrateWeaponTimer'
    settimer 'ConsecrateWeaponTimer' 9000
  elseif timer 'ConsecrateWeaponTimer' > 9000
    cast 'Consecrate Weapon'
    pause 1000
    settimer 'ConsecrateWeaponTimer' 0
  endif
  if buffexists 'Polymorph'
    cast 'Polymorph'
    pause 1000
  endif
  //**************auto-cast Vamp Embrace*****************//
  //*****Causes strangeness if you were in Wraith Form*****
  //if @findtype 0x25e 'any' 'self'
  //  if color < 33918 or color > 33918
  //    cast 'vampiric embrace'
  //    pause 2500
  //  endif
  //endif
  //////*******************************************////////
  attack! 'enemy'
endwhile