vvvvvv PKGBUILD

# Contributor: gadget3000 <gadget3000 at msn dot com>
# Contributor: mikers <mikeonthecomputer at gmail dot com>
# Contributor: Xesxen <arch@xesxen.nl>
# Contributor: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Chris Billington <chrisjbillington@gmail.com>
# Maintainer: Eric Anderson <ejona86@gmail.com>

pkgname=vvvvvv
_pkgname=VVVVVV
pkgver=2.3.4
pkgrel=2
pkgdesc='A retro-styled 2D platformer'
arch=('i686' 'x86_64')
url='https://thelettervsixtim.es/'
groups=('humblebundle3' 'humblebundle4' 'humblebundles')
license=('custom')
depends=('sh' 'sdl2_mixer')
makedepends=('git' 'cmake')
provides=('vvvvvv')
conflicts=('vvvvvv')
source=(
    "${_pkgname}-${pkgver}.tar.gz::https://github.com/TerryCavanagh/${_pkgname}/archive/refs/tags/${pkgver}.tar.gz"
    "${pkgname}.desktop"
    "https://thelettervsixtim.es/makeandplay/data.zip"
    "LICENSE-data"
)
sha256sums=('514b85ee21a3a8d9bfb9af00bc0cd56766d69f84c817799781da93506f30dd9c'
            '8c704e92e6abc8172d7d9fe726f1a0bba4b8630682745d6daf1f34ce12e0e3e4'
            '6fae3cdec06062d05827d4181c438153f3ea3900437a44db73bcd29799fe57e0'
            'fdc9b91bfe9f220101c0fc59b12750ed8eae41870b7bfa966c4599c96df3801c')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}/desktop_version"
  mkdir -p build
  cd build
  cmake -DOFFICIAL_BUILD=ON ..
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  install -D -m755 "desktop_version/build/${_pkgname}" \
      "${pkgdir}/usr/lib/${pkgname}/${_pkgname}"
  install -D -m644 "LICENSE.md" \
      "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-bin"

  cd "${srcdir}"
  install -D -m644 "LICENSE-data" \
      "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-data"
  install -D -m644 "data.zip" "${pkgdir}/usr/lib/${pkgname}"
  install -D -m644 "VVVVVV.png" \
      "${pkgdir}/usr/share/pixmaps/${pkgname}.png"

  install -d "${pkgdir}/usr/bin"
  ln -s "../lib/${pkgname}/${_pkgname}" "${pkgdir}/usr/bin/${pkgname}"
  install -D -m644 "${srcdir}/${pkgname}.desktop" \
      "${pkgdir}/usr/share/applications/${pkgname}.desktop"
}