PrimeTime - Verification of ARM® CoreLink™ ADB-400

#=================================================
# File      : PrimeTime - Timing Verification of ARM CoreLink ADB-400, AMBA Domain Bridge IP
# Date      : 09-June-2015
# Author    : Ramnath Swamy
# Company   : ARM Ltd
#=================================================


proc rm_report_adb400_timing { \
                                destination_pld_regs_inpin_list \
                                destination_ptr_regs_inpin_list \
                                {slot_regs_list ""} \
                                {M      "2"} \
                                {R      "2"} \
                                {Pclkb      ""} \
                                {N      ""} \
                                {Pclka      ""} \
                             } {

  # Parameters definition
  # N       = FIFO Depth
  # M       = Total number of Synchronizer stages
  # R       = Number of Pointer-margin stages
  # Pclka   = Slave Clock period
  # Pclkb   = Master Clock period

  global        sh_product_version

  set ptr_strobe_derate     1

  #---------------------------------------------
  # Check Pre-requisites
  #---------------------------------------------

  if {$M < 2} {
    puts "\nError: rm_report_adb400_timing: M cannot be less than 2. Synchronizers must have atleast 2 stages\n"
    return -code 0
  }

  if {$R > $M} {
    puts "\nError: rm_report_adb400_timing: Total synchronizer stages of M=$M offers a maximum guaranteed pointer-margin of $M cycle(s)'"
    puts "         So \'R\' cannot be greater than $M\n"
    return -code 0
  }

  if {$R < 0} {
    puts "\nError: rm_report_adb400_timing: R cannot be less than 0\n"
    return -code 0
  }

  if {$R == 0} {
    puts "\nWarning: rm_report_adb400_timing: R is set to be 0. Hence no pointer-margin is used.\n"
  }


  #---------------------------------------------
  # Measurement
  #---------------------------------------------
  # Get Payload Paths
  if {$slot_regs_list == ""} {
    set pld_paths [get_timing_paths  -max_paths 10000 -to  [get_pins $destination_pld_regs_inpin_list] -slack_lesser_than inf]
  } else {
    set pld_paths [get_timing_paths  -max_paths 10000 -to  [get_pins $destination_pld_regs_inpin_list] -slack_lesser_than inf -from [get_cells $slot_regs_list]]
  }

  # Get Pointer Paths
  set ptr_paths [get_timing_paths  -max_paths 10000 -to  [get_pins $destination_ptr_regs_inpin_list] -slack_lesser_than inf]

  # Get Tpld and Tptr
  set max_Tpld  [lindex [lsort -decreasing -real [get_attribute $pld_paths arrival]] 0]
  set min_Tptr  [lindex [lsort -increasing -real [get_attribute $ptr_paths arrival]] 0]
  set max_Tptr  [lindex [lsort -decreasing -real [get_attribute $ptr_paths arrival]] 0]

  #---------------------------------------------
  # Slack Calculation
  #---------------------------------------------
  # SignOff Condition-1:
  #--------------------

  # Caluclate slack1
  #.................
  if {$R == $M} {
    set relaxation      ""
    set slack1          [expr ($min_Tptr*$ptr_strobe_derate)-$max_Tpld]
  } elseif {$R < $M} {
    if {$Pclkb == ""} {
      puts "\nError: rm_report_adb400_timing: Pclkb needs to be specified if R is less than M\n"
      return -code 0
    }

    set relaxation      " - ((M - R) x Pclkb)"
    set slack1          [expr ($min_Tptr*$ptr_strobe_derate)-($max_Tpld-(($M - $R) * $Pclkb))]
  }

  if {$slack1 < 0}      {set slack1_stat "(VIOLATED)"} else {set slack1_stat "(MET)"}

  # SignOff Condition-2:
  #--------------------

  # Caluclate slack1
  #.................
  if {$N != "" && $M != "" && $Pclka != "" && $Pclkb != ""} {

    set upperbound [expr ( ($N * $Pclka) - $M*($Pclka + $Pclkb) )/2]

    if {$upperbound <= 0} {
      set upperbound $Pclka
      puts "\nWarning: (rm_report_adb400_timing) upperbound is set to one sending clock period $Pclka\n"
      set upperbound_stat "(reset to 1 clock perriod)"
    } else {
      set upperbound_stat ""
    }

    set slack2   [expr $upperbound - ($max_Tptr/$ptr_strobe_derate)]

    if {$slack2 < 0} {set slack2_stat "(VIOLATED)"} else {set slack2_stat "(MET)"}
  } else {
    set upperbound  "-"
    set slack2      "Untested"
    set slack2_stat ""

  }


  # Reporting
  if {$M == ""}         {set M_value  "_"}  else {set M_value   $M}
  if {$R == ""}         {set R_value  "_"}  else {set R_value   $R}
  if {$Pclka == ""}     {set Pclka_value "_"}   else {set Pclka_value   $Pclka}
  if {$N == ""}         {set N_value  "_"}  else {set N_value   $N}
  if {$Pclkb == ""}     {set Pclkb_value "_"}   else {set Pclkb_value   $Pclkb}
  puts ""
  puts "***********************************************************************"
  puts " rm_report_adb400_timing"
  puts ""
  puts "    Design              - [get_attribute [get_design] full_name]"
  puts "    Version             - $sh_product_version"
  puts "    Date                - [date]"
  puts "-----------------------------------------------------------------------"
  puts " Input parameters   Value       Description"
  puts ""
  puts " SignOff Condition-1:"
  puts [format "%-3s %-19s %-15s %-42s" " " "M" "$M_value" "Total Synchronizer stages"]
  puts [format "%-3s %-19s %-15s %-42s" " " "R" "$R_value" "Pointer-margin stages"]
  puts [format "%-3s %-19s %-15s %-42s" " " "Pclkb" "$Pclkb_value" "Master Clock period"]
  puts ""
  puts " SignOff Condition-2:"
  puts [format "%-3s %-19s %-15s %-42s" " " "N" "$N_value" "Total number of slots(fifo depth)"]
  puts [format "%-3s %-19s %-15s %-42s" " " "Pclka" "$Pclka_value" "Slave Clock period"]
  puts "***********************************************************************"
  puts ""
  puts "SignOff Condition-1(Mandatory): Tptr >= Tpld $relaxation"
  puts "-----------------------------------------------------------------------"
  puts "Min Tptr        = $min_Tptr"
  puts "Max Tpld        = $max_Tpld"
  puts "Slack           = $slack1 $slack1_stat"
  puts "-----------------------------------------------------------------------"
  puts ""
  puts "SignOff Condition-2(Recommended): Tptr < Upperbound = ((N x Pclka) - M(Pclka + Pclkb)) / 2"
  puts "-----------------------------------------------------------------------"
  if {$N != "" && $M != "" && $Pclka != "" && $Pclkb != ""} {
  puts "Upperbound      = $upperbound $upperbound_stat"
  puts "Max Tptr        = $max_Tptr"
  puts "Slack           = $slack2 $slack2_stat"
  puts "-----------------------------------------------------------------------"
  } else {
  puts "Not Tested"
  }

  puts "\n1\n"

}