[Include] SA:MP GetLastDriver

/*  SA-MP GetLastDriver
 *
 *  (c) Copyright 2020, Kaliber
 *
 */
/******************************************************************************/
/*
    native GetLastDriver(vehicleid);
*/
/******************************************************************************/
#if defined _last_driver_included
    #endinput
#endif
#define _last_driver_included
/******************************************************************************/
#if !defined _samp_included
    #include <a_samp>
#endif
/******************************************************************************/
public OnPlayerStateChange(playerid, newstate, oldstate)
{
    if(newstate == PLAYER_STATE_DRIVER)
    {
        new n[MAX_PLAYER_NAME];
        GetPlayerName(playerid,n,MAX_PLAYER_NAME);
        setproperty(.value = GetPlayerVehicleID(playerid)+1000, .string = n);
    }
    #if defined Veh_Driver_OnPlayerStateChange
        return Veh_Driver_OnPlayerStateChange(playerid, newstate, oldstate);
    #else
        return 1;
    #endif
}
#if defined Veh_Driver_OnPlayerStateChange
    forward Veh_Driver_OnPlayerStateChange(playerid, newstate, oldstate);
#endif
#if defined _ALS_OnPlayerStateChange
    #undef OnPlayerStateChange
#else
    #define _ALS_OnPlayerStateChange
#endif
#define OnPlayerStateChange Veh_Driver_OnPlayerStateChange
/******************************************************************************/
stock GetLastDriver(vehicleid)
{
    new bool:f,str[MAX_PLAYER_NAME];
    if(existproperty(.value=vehicleid+1000))
    {
        getproperty(.value=vehicleid+1000, .string=str),strunpack(str, str, sizeof(str));
        for(new i=GetPlayerPoolSize(),n[MAX_PLAYER_NAME]; i!=-1; i--)
        {
            if(GetPlayerName(i,n,MAX_PLAYER_NAME) && !strcmp(n,str))
            {
                f = true;
                break;
            }
        }
        if(!f) deleteproperty(.value=vehicleid+1000);
    }
    if(!f) str = "Niemand";
    return str;
}