Callum's Fast BardKeys 2.0

;==================================
; Script Name:  Callum's Fast Bard Keys
; Author: Callum O'Lyre
; ICQ: 625-658-845
; Version: 1.0
; Shard: Pangaea
; Public Release: 15.10.2012
; Purpose: To speed up the casting of bard songs on Pangaea
; Originally Posted: http://pastebin.com/u/DavidJSGardner
;=============Song ID==============
;Illumination - 1
;Sounds of Injury - 2
;Fertility - 3
;Lightheadedness - 4
;Shielding - 5
;Transportation - 6
;Bane - 7
;Sounds of Damage - 8
;True Seeing - 9
;Boosting - 10
;Recovery - 11
;Cleansing - 12
;Transparency - 13
;Revival - 14
;Sounds of Demolition - 15
;Stunning - 16
;Dispelling - 17
;Feedback - 18
;==================================
;Let's Break it down:
;onhotkey F1
; {
;  GoSub PlaySong 5
; }
;
;The onHotKey command performs the following line of code (brackets do NOT work) when a certain key is pressed.
;The key-specifier can either be A-Z, 0-9, F1-F12 and ESC, BACK, TAB, ENTER, PAUSE, CAPSLOCK, SPACE, PGDN, PGUP,
;END, HOME, LEFT, RIGHT, UP, DOWN, PRNSCR, INSERT, DELETE, NUMLOCK or SCROLLLOCK.
;
;onHotKey {key-specifier} {[alt] | [ctrl] | [shift]}
;
;Ex: onhotkey t alt
;==================================
;As always if you need any help with setup, please do not hesitate to contact me via icq or a PM, I am more then
;happy to help out anyway I can.
;==================================
;Instrument Lists
set %Harp QRF
set %StandingHarp NRF
set %Flute MNL
set %Tambo LQF
set %RibTambo OQF
set %Drum MQF
set %Lute1 KRF
set %Lute2 PRF

While #true
{
;Shielding
 onhotkey F1
  {
   GoSub PlaySong 5
  }
;Feedback
 onhotkey F1 SHIFT
  {
   GoSub PlaySong 17
  }
;Boosting
 onhotkey F1 ALT
 {
  GoSub PlaySong 10
 }
;Demo
 onhotkey F3
 {
  GoSub PlaySong 15
 }
;Lightheaded
 onhotkey F3 SHIFT
 {
  GoSub PlaySong 4
 }
 onhotkey F4
 {
  GoSub PlaySong 11
 }
 onhotkey F4 SHIFT
 {
  GoSub PlaySong 12
 }
 onhotkey F12
 {
  GoSub PlaySong 14
 }
;------

;------
}

;==================================
; Script Name: PlaySong
; Author: Callum O'Lyre
; Version: 2.0
; Shard: Pangaea
; Public Release: 12.06.2013
; Purpose: Uses an instrument and plays the specified song it has been passed.
; Usage: GoSub PlaySong SongID
; SongID <the position of the song in the gump, range of numbers 1-18>
;=============Song ID==============
;Illumination - 1
;Sounds of Injury - 2
;Fertility - 3
;Lightheadedness - 4
;Shielding - 5
;Transportation - 6
;Bane - 7
;Sounds of Damage - 8
;True Seeing - 9
;Boosting - 10
;Recovery - 11
;Cleansing - 12
;Transparency - 13
;Revival - 14
;Sounds of Demolition - 15
;Stunning - 16
;Dispelling - 17
;Feedback - 18
;==================================
Sub PlaySong
set %lpc #lpc
set #lpc 60

set %Song %1 - 1
if %Song < 0 || %Song > 17
 {
  set #lpc %lpc
  return #False
 }

;Modifier songs
;Fertility, Lightheadedness, Shielding, Bane, True Seeing, Boosting, Transparency, Feedback
If %Song = 2 || %Song = 3 || %Song = 4 || %Song = 6 || %Song = 8 || %Song = 9 || %Song = 12 || %Song = 17
 {
  GoSub ItemFind %RibTambo %Tambo %Lute1 %Lute2 %StandingHarp %Harp %Drum %Flute
 }
;Helpful songs
;Illumination, Transportation, Recovery, Cleansing, Revival
If %Song = 0 || %Song = 5 || %Song = 10 || %Song = 11 || %Song = 13
 {
  GoSub ItemFind %StandingHarp %Harp %Lute1 %Lute2 %RibTambo %Tambo %Flute %Drum
 }
;Aggressive Songs
;Sounds of Injury, Sounds of Damage, Sounds of Demolition, Stunning, Dispelling
If %Song = 1 || %Song = 7 || %Song = 14 || %Song = 15 || %Song = 16
 {
  GoSub ItemFind %Drum %Flute %Lute1 %Lute2 %Tambo %Harp %StandingHarp %RibTambo
 }

if #Result = NoInstrumentToPlay
 {
  Event Sysmessage You have no instruments fool!
  set #lpc %lpc
  return
 }

set #LOBJECTID #Result
Event Macro 17 0

set %TimeToWait #SCNT + 5
while ( #contname <> generic_gump && #contPosX <> 0 )
{
 if %TimeToWait < #SCNT
  {
   Event Sysmessage Couldn't Find Bard Gump!
   set #lpc %lpc
   return
  }
}

set %PS_X #ContPosX + 48
set %PS_Y #ContPosY + 75 + ( 20 * ( %Song % 18 ) )

click %PS_X %PS_Y f
set #lpc %lpc
return

;==================================
; Script Name: Find Item In Specific Order
; Author: Callum O'Lyre
; Version: 2.0
; Shard: Pangaea
; Purpose: To search for and use the first instrument it finds, if the user wishes to
;          use a sepcific instrument for a song list it first and it will use it assuming
;          of course it is available to use. It is advisable to list all instrument types
;          so that if one is not available it will move down the list and use the next
;          available instrument.
; Usage: GoSub ItemFind firstitem seconditem thirditem ...
;==================================
Sub ItemFind
for %i 1 %0
{
  FindItem % . %i CA
  Event Property #FindID
  if #FindID <> X
   {
    if Consonance in #Property
     {
      Set %InstrumentType #FindType
      return #findid
     }
    if Harmony in #Property
     {
      Set %InstrumentType #FindType
      return #findid
     }
    if Melody in #Property
     {
      Set %InstrumentType #FindType
      return #findid
     }
    if Accord in #Property
     {
      Set %InstrumentType #FindType
      return #findid
     }
    if Sonority in #Property
     {
      Set %InstrumentType #FindType
      return #findid
     }
    Set %InstrumentType #FindType
    return #findid
   }
}
return NoInstrumentToPlay