pkgbuild-opengl-manpages

# Mainainer: Joskar
# Contributor: Pierre Neidhardt

pkgname=opengl-manpages-svn
pkgver=22276
pkgrel=1
pkgdesc="OpenGL Reference Pages converted to manpages"
provides=(opengl-manpages)
license=('custom')
arch=(any)
url="https://www.opengl.org/sdk/docs/man/"
makedepends=('subversion' 'libxslt' 'docbook-xsl' 'docbook-mathml' 'w3c-mathml2' 'sed')
source=(
    svn+https://cvs.khronos.org/svn/repos/ogl/trunk/ecosystem/public/sdk/docs/man2
    svn+https://cvs.khronos.org/svn/repos/ogl/trunk/ecosystem/public/sdk/docs/man3
    svn+https://cvs.khronos.org/svn/repos/ogl/trunk/ecosystem/public/sdk/docs/man4
    svn+https://cvs.khronos.org/svn/repos/ogl/trunk/ecosystem/public/sdk/docs/manglsl
    LICENSE SGI-FreeSoftwareLicenseB OpenPublicationLicense)
noextract=()
md5sums=(
    'SKIP' 'SKIP' 'SKIP' 'SKIP'
    '5fc9b93540b47782c64095176204c7e3'
    '1ac705a20a0b78c7c00512507bee5cec'
    'e2c59eccf33187f4605e116bdf3a8ffb')

pkgver() {
    cd 'man4'
    svnversion | tr -d [A-z]
}

prepare ()
{
    if [ -d "$srcdir/man2" ]; then
        sed -i 's/glDrawElementsInstanced.xml//' "$srcdir/man2/xhtml/Makefile"
    fi

    if [ -d "$srcdir/manglsl" ]; then
        cp -r "$srcdir/man4/usr" "$srcdir/manglsl/"
    fi
}

build() {
    for i in "2" "3" "4" "glsl"; do
        cd "man$i"
        msg "Starting build..."
        sed -i 's@xsl/current/xhtml@xsl/current/manpages@' xhtml/opengl-man.xsl
        make ROOT=.
        sed -i 's@\[FIXME: author\]@Khronos Group@g' xhtml/*
        sed -i 's@\[FIXME: source\]@Khronos Group@g' xhtml/*
        sed -i 's@\[FIXME: manual\]@OpenGL Reference Pages@g' xhtml/*
        cd ..
    done
}

package() {
    ## Note: we use the 'G' suffix for all OpenGL man pages except fr glsl.
    for i in "2" "3" "4" "glsl"; do
        cd "man$i"
        mkdir -p "$pkgdir/usr/share/man/man$i"
        cd xhtml
        SUFFIX="G"; [ "$i" = "glsl" ] && SUFFIX=""
        for j in *.3G; do
            mv "$j" "$pkgdir/usr/share/man/man$i/${j%3G}${i}$SUFFIX"
        done
        cd ../..
    done

    mkdir -p "$pkgdir/usr/share/licenses/$pkgname"
    cp "$srcdir/SGI-FreeSoftwareLicenseB" "$pkgdir/usr/share/licenses/$pkgname"
    cp "$srcdir/OpenPublicationLicense" "$pkgdir/usr/share/licenses/$pkgname"
    cp "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}