Proof that index fragmentation affects backup size

CREATE DATABASE TestBackupSize ON (NAME='TestBackupSize_Data', FILENAME='C:\SQLDATA\MSSQL15.SQL2019\MSSQL\DATA\TestBackupSize_Data.mdf', SIZE=1000MB)
GO
USE TestBackupSize
GO

CREATE TABLE TestTable (
    ID INT PRIMARY KEY,
    Filler CHAR(100) NOT NULL DEFAULT ''
)

INSERT INTO dbo.TestTable (ID)
SELECT ROW_NUMBER() OVER (ORDER BY v1.low) FROM master.dbo.spt_values v1 CROSS JOIN master.dbo.spt_values v2

BACKUP DATABASE TestBackupSize TO DISK='TestBackupSize_1_NoCompression.bak' WITH NO_COMPRESSION -- 724MB
BACKUP DATABASE TestBackupSize TO DISK='TestBackupSize_1_Compressed.bak' WITH COMPRESSION -- 28MB

DELETE dbo.TestTable WHERE ID%10<>0

BACKUP DATABASE TestBackupSize TO DISK='TestBackupSize_2_NoCompression.bak' WITH NO_COMPRESSION -- 724MB
BACKUP DATABASE TestBackupSize TO DISK='TestBackupSize_2_Compressed.bak' WITH COMPRESSION -- 28MB

ALTER TABLE dbo.TestTable REBUILD

WAITFOR DELAY '0:0:10'

BACKUP DATABASE TestBackupSize TO DISK='TestBackupSize_3_NoCompression.bak' WITH NO_COMPRESSION -- 77MB
BACKUP DATABASE TestBackupSize TO DISK='TestBackupSize_3_Compressed.bak' WITH COMPRESSION -- 3MB

USE master
GO
DROP DATABASE TestBackupSize