1С ФИФО в запросе

ВЫБРАТЬ
	ВзаиморасчетыСПокупателями.Контрагент КАК Контрагент,
	ВзаиморасчетыСПокупателями.Регистратор КАК Регистратор,
	ВзаиморасчетыСПокупателями.МоментВремени КАК Период,
	СУММА(ВзаиморасчетыСПокупателями.Сумма) КАК Сумма
ПОМЕСТИТЬ Задолженность
ИЗ
	РегистрНакопления.ВзаиморасчетыСПокупателями КАК ВзаиморасчетыСПокупателями
ГДЕ
	ВзаиморасчетыСПокупателями.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Приход)

СГРУППИРОВАТЬ ПО
	ВзаиморасчетыСПокупателями.Контрагент,
	ВзаиморасчетыСПокупателями.Регистратор,
	ВзаиморасчетыСПокупателями.МоментВремени

ИНДЕКСИРОВАТЬ ПО
	Регистратор,
	Контрагент
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВзаиморасчетыСПокупателями.Контрагент КАК Контрагент,
	ВзаиморасчетыСПокупателями.Регистратор КАК Регистратор,
	ВзаиморасчетыСПокупателями.МоментВремени КАК Период,
	СУММА(ВзаиморасчетыСПокупателями.Сумма) КАК Сумма
ПОМЕСТИТЬ Оплата
ИЗ
	РегистрНакопления.ВзаиморасчетыСПокупателями КАК ВзаиморасчетыСПокупателями
ГДЕ
	ВзаиморасчетыСПокупателями.ВидДвижения = ЗНАЧЕНИЕ(ВидДвиженияНакопления.Расход)

СГРУППИРОВАТЬ ПО
	ВзаиморасчетыСПокупателями.Контрагент,
	ВзаиморасчетыСПокупателями.Регистратор,
	ВзаиморасчетыСПокупателями.МоментВремени

ИНДЕКСИРОВАТЬ ПО
	Регистратор,
	Контрагент
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ЗадолженностьПоКонтрагенту.Контрагент КАК Контрагент,
	СУММА(ЗадолженностьПоКонтрагенту.Сумма) КАК Сумма
ПОМЕСТИТЬ ЗадолженностьПоКонтрагенту
ИЗ
	(ВЫБРАТЬ
		Задолженность.Контрагент КАК Контрагент,
		Задолженность.Сумма КАК Сумма
	ИЗ
		Задолженность КАК Задолженность

	ОБЪЕДИНИТЬ ВСЕ

	ВЫБРАТЬ
		Оплата.Контрагент,
		-Оплата.Сумма
	ИЗ
		Оплата КАК Оплата) КАК ЗадолженностьПоКонтрагенту

СГРУППИРОВАТЬ ПО
	ЗадолженностьПоКонтрагенту.Контрагент

ИНДЕКСИРОВАТЬ ПО
	Контрагент
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ЗадолженностьПоДокументам.Период,
	ЗадолженностьПоДокументам.Контрагент,
	ЗадолженностьПоДокументам.Регистратор,
	ЗадолженностьПоДокументам.Сумма
ПОМЕСТИТЬ ЗадолженностьПоДокументам
ИЗ
	(ВЫБРАТЬ
		Задолженность.Период КАК Период,
		Задолженность.Контрагент КАК Контрагент,
		Задолженность.Регистратор КАК Регистратор,
		Задолженность.Сумма КАК Сумма
	ИЗ
		ЗадолженностьПоКонтрагенту КАК ОбщаяЗадолженность
			ВНУТРЕННЕЕ СОЕДИНЕНИЕ Задолженность КАК Задолженность
			ПО (ОбщаяЗадолженность.Сумма > 0)
				И ОбщаяЗадолженность.Контрагент = Задолженность.Контрагент) КАК ЗадолженностьПоДокументам
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ЗадолженностьПоДокументам.Регистратор КАК Документ,
	ЗадолженностьПоКонтрагенту.Контрагент КАК Контрагент,
	ВЫБОР
		КОГДА ЗадолженностьПоДокументам.Сумма ЕСТЬ NULL
			ТОГДА ЗадолженностьПоКонтрагенту.Сумма
		КОГДА ЗадолженностьПоКонтрагенту.Сумма >= ЗадолженностьПоДокументам.СуммаНакорленная
			ТОГДА ЗадолженностьПоДокументам.Сумма
		ИНАЧЕ ЗадолженностьПоКонтрагенту.Сумма - (ЗадолженностьПоДокументам.СуммаНакорленная - ЗадолженностьПоДокументам.Сумма)
	КОНЕЦ КАК Сумма
ИЗ
	ЗадолженностьПоКонтрагенту КАК ЗадолженностьПоКонтрагенту
		ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
			ДокументыОстатковЗадолженности.Период КАК Период,
			ДокументыОстатковЗадолженности.Контрагент КАК Контрагент,
			ДокументыОстатковЗадолженности.Регистратор КАК Регистратор,
			СУММА(ЕСТЬNULL(ДокументыОстатковЗадолженности1.Сумма, 0)) КАК СуммаНакорленная,
			ДокументыОстатковЗадолженности.Сумма КАК Сумма
		ИЗ
			ЗадолженностьПоДокументам КАК ДокументыОстатковЗадолженности
				ВНУТРЕННЕЕ СОЕДИНЕНИЕ ЗадолженностьПоДокументам КАК ДокументыОстатковЗадолженности1
				ПО ДокументыОстатковЗадолженности.Период <= ДокументыОстатковЗадолженности1.Период
					И ДокументыОстатковЗадолженности.Контрагент = ДокументыОстатковЗадолженности1.Контрагент

		СГРУППИРОВАТЬ ПО
			ДокументыОстатковЗадолженности.Период,
			ДокументыОстатковЗадолженности.Контрагент,
			ДокументыОстатковЗадолженности.Регистратор,
			ДокументыОстатковЗадолженности.Сумма) КАК ЗадолженностьПоДокументам
		ПО (ЗадолженностьПоКонтрагенту.Сумма > 0
					И ЗадолженностьПоКонтрагенту.Сумма >= ЗадолженностьПоДокументам.СуммаНакорленная
				ИЛИ ЗадолженностьПоКонтрагенту.Сумма >= ЗадолженностьПоДокументам.СуммаНакорленная - ЗадолженностьПоДокументам.Сумма)
			И ЗадолженностьПоКонтрагенту.Контрагент = ЗадолженностьПоДокументам.Контрагент
ГДЕ
	НЕ ВЫБОР
				КОГДА ЗадолженностьПоДокументам.Сумма ЕСТЬ NULL
					ТОГДА ЗадолженностьПоКонтрагенту.Сумма
				КОГДА ЗадолженностьПоКонтрагенту.Сумма >= ЗадолженностьПоДокументам.СуммаНакорленная
					ТОГДА ЗадолженностьПоДокументам.Сумма
				ИНАЧЕ ЗадолженностьПоКонтрагенту.Сумма - (ЗадолженностьПоДокументам.СуммаНакорленная - ЗадолженностьПоДокументам.Сумма)
			КОНЕЦ = 0

УПОРЯДОЧИТЬ ПО
	Контрагент,
	ЗадолженностьПоДокументам.Период