//

002-1.gat,15,67,0   script  Samuel  132,{
    mes "[Samuel the Nomad]";
    mes "\"This is really a nice place.\"";

    mes "Don't you think so?\"";
    close;
}

002-1.gat,18,68,0   script  Elijah  128,{

    if(BaseLevel < 60) goto L_Nolvl;
    if(TMW_Quest == 53) goto L_Done;
    if(TMW_Quest == 52) goto L_SleepingBag;
    if(TMW_Quest == 51) goto L_Rise;
    if(TMW_Quest == 50) goto L_Bag;
    if(TMW_Quest == 49) goto L_Patchs;
    if(TMW_Quest == 48) goto L_Ingridients;
    if(TMW_Quest == 47) goto L_Tent;
    if(TMW_Quest == 45) goto L_Results;
    if(TMW_Quest == 44) goto L_Weather;
    if(TMW_Quest == 43) goto L_Answer;
    if(TMW_Quest == 42) goto L_Message;
    if(TMW_Quest == 41) goto L_Stones;

    mes "[Elijah the Nomad]";
    mes "\"Hm, young traveler. As I see you're good in running, can you help me?\"";
    menu
        "I can", -,
        "Nope", L_No;

    mes "[Elijah the Nomad]";
    mes "\"Some days ago I have arrived from a trek and got a lot of interesting types of stones.\"";
    next;
    mes "[Elijah the Nomad]";
    mes "\"My friend is scientist, and I wanted to give him my stones, but I'm to tired. Can you help me with it?\"";
    menu
        "Yes", L_Yes,
        "No", L_No;

L_Yes:
    mes "[Elijah the Nomad]";
    set TMW_Quest, 41;
    mes "\"He's living near Hurnscland. His name is Rasker, I hope you'll meet him. Good luck.\"";
    close;

L_Nolvl:
    mes "[Elijah the Nomad]";
    mes "\"If I only had a tent...\"";
    close;

L_Stones:
    mes "[Elijah the Nomad]";
    mes "\"Please, bring this stones to Rasker. He's near Hurnscland.\"";
    close;

L_No:
    close;

L_Message:
    mes "[Elijah the Nomad]";
    set TMW_Quest, 43;
    mes "\"Hello! As I see you gave stones to Rasker, good.\"";
    menu
        "Wait, he asked me to bring you a message.", -;

    mes "[Elijah the Nomad]";
    mes "\"Message? Can you show it to me?\"";
    next;
    mes "[Elijah the Nomad]";
    mes "He reads the message and his eyes became very big.";
    next;
    mes "[Elijah the Nomad]";
    mes "\"Hm, good. Can you bring him my answer?\"";
    menu
        "Sure!", -;

    mes "[Elijah the Nomad]";
    mes "\"Thanks.\"";
    close;

L_Answer:
    mes "[Elijah the Nomad]";
    mes "\"Please, bring my answer to Rasker. He's waiting near Hurnscland.\"";
    close;

L_Weather:
    mes "[Elijah the Nomad]";
    mes "\"Interesting, why it's so cold in hot desert...\"";
    close;

L_Results:
    mes "[Elijah the Nomad]";
    set TMW_Quest, 47;
    mes "\"Great, you made it! You brought results!\"";
    next;
    mes "[Elijah the Nomad]";
    mes "\"Hm, I have some problem with living in this desert. Can you ask one of my friends, how I can make a tent?\"";
    next;
    goto L_Tent;

L_Tent:
    mes "[Elijah the Nomad]";
    mes "\"He's living in one of the houses on the east of Tulimsar. His name is Swet.\"";
    close;

L_Ingridients:
    mes "[Elijah the Nomad]";
    set TMW_Quest, 49;
    mes "\"Did you ask him?\"";
    menu
        "Yes, hi asked me to give you this list", -;

    mes "[Elijah the Nomad]";
    mes "\"Good. And now, can you help me with getting this ingredients?\"";
    menu
        "Sure", -;

    mes "[Elijah the Nomad]";
    mes "\"I need 12 [Leather Patch]s for the tent. Please, get it.\"";
    close;

L_Patchs:
    if (countitem("leatherpatch") < 12) goto L_NotEnough;
    mes "[Elijah the Nomad]";
    set TMW_Quest, 50;
    mes "\"Wow, thanks you! Now I'll need to have sleeping bag, because of it's to cold in desert.\"";
    delitem "leatherpatch", 12;
    next;
    mes "[Elijah the Nomad]";
    mes "\"Please, ask Swet, how can I make a sleeping bag.\"";
    close;

L_Bag:
    mes "[Elijah the Nomad]";
    mes "\"Please, ask Swet, how can I make a sleeping bag.\"";
    close;

L_NotEnough:
    mes "[Elijah the Nomad]";
    mes "\"I need 12 [Leather Patch]s for the tent. Please, get it.\"";
    close;

L_Rise:
    mes "[Elijah the Nomad]";
    mes "\"Always when I'm sitting on this place, I always remember mountains and sun.\"";
    close;

L_SleepingBag:
    mes "[Elijah the Nomad]";
    set TMW_Quest, 53;
    mes "\"Looks good. Thanks you traveler. For all your honor I want to make a small present. Thanks for all again!\"";
    getitem "blackboots", 12;
    getexp 50000, 0;
    close;
}

//

008-1.gat,121,18,0  script  Rasker  107,{

    if(TMW_Quest >= 46) goto L_Rest;
    if(TMW_Quest == 45) goto L_Results;
    if(TMW_Quest == 44) goto L_Scorpions;
    if(TMW_Quest == 43) goto L_Answer;
    if(TMW_Quest == 42) goto L_Message;
    if(TMW_Quest == 41) goto L_Stones;

    mes "[Rasker]";
    mes "\"It's so sunny and good day.\"";
    close;

L_Stones:
    mes "[Rasker]";
    set TMW_Quest, 42;
    mes "\"It's so sunny and good day.\"";
    menu
        "Hey, aren't you Rasker, the scientist?", -,
        "Maybe", L_No;

    mes "[Rasker]";
    mes "\"Who are you and why you know me? You are right, but you are to strange.\"";
    menu
        "Elijah asked me to give you some stones", -;

    mes "[Rasker]";
    mes "\"Ah, Elijah. Yes, he told me that you'll come. Sorry me, I forgot.\"";
    next;
    mes "[Rasker]";
    mes "\"I have a small message for him. Please, give it to him.\"";
    menu
        "I will", -;

    mes "[Rasker]";
    mes "\"Good luck!\"";
    close;

L_No:
    close;

L_Message:
    mes "[Rasker]";
    mes "\"Please, bring this list of paper to Elijah.\"";
    close;

L_Answer:
    mes "[Rasker]";
    set TMW_Quest, 44;
    mes "\"Hi! Did Elijah received my letter?\"";
    menu
        "Yes. He asked me to give you an answer.", -;

    mes "[Rasker]";
    mes "\"Please, give it to me.\"";
    next;
    mes "[Rasker]";
    mes "\"Hm, he's asking me to look on lava ingredients. I need 5 [Scorpion Stinger]s for it.\"";
    next;
    mes "[Rasker]";
    mes "\"Please, get 5 [Scorpion Stinger]s for me.\"";
    close;

L_Scorpions:
    if (countitem("scorpionstinger") < 5) goto L_NotEnough;
    mes "[Rasker]";
    set TMW_Quest, 45;
    mes "\"Good, you brought it. Now, can you give this letter back to Elijah?\"";
    delitem "scorpionstinger", 5;
    menu
        "Sure!", -;

    mes "[Rasker]";
    mes "\"Thanks you!\"";
    close;

L_Results:
    mes "[Rasker]";
    mes "\"Hey, I was working under this results. Bring them to Elijah!\"";
    close;

L_Rest:
    mes "[Rasker]";
    mes "\"Science s so interesting!\"";
    close;

L_NotEnough:
    mes "[Rasker]";
    mes "\"Please, get 5 [Scorpion Stinger]s for me.\"";
    close;

L_Done:
    mes "[Rasker]";
    mes "\"Tent and sleeping bag are so good, thanks a lot!\"";
    close;
}

//

021-1.gat,148,68,0  script  Swet    142,{

    if(TMW_Quest >= 52) goto L_Sun;
    if(TMW_Quest == 51) goto L_Sleeping;
    if(TMW_Quest == 50) goto L_Bag;
    if(TMW_Quest == 49) goto L_Day;
    if(TMW_Quest == 48) goto L_Ing;
    if(TMW_Quest == 47) goto L_Tent;

    mes "[Swet]";
    mes "\"Tulimsar is so big and beautiful!\"";
    close;

L_Tent:
    mes "[Swet]";
    mes "\"Hello, what do you want?\"";
    menu
        "Elijah asked me to ask you, how he can make a tent.", L_Ingridients,
        "Nothing", L_No;

L_No:
    close;

L_Ingridients:
    mes "[Swet]";
    set TMW_Quest, 48;
    mes "\"Ok, here you are instructions for him. Give it to him.\"";
    close;

L_Ing:
    mes "[Swet]";
    mes "\"Please, give all instructions to Elijah.\"";
    close;

L_Day:
    mes "[Swet]";
    mes "\"I hope it will help Elijah.\"";
    close;

L_Bag:
    mes "[Swet]";
    mes "\"Hi, what do you want to know?\"";
    menu
        "How can Elijah get a sleeping bag?", L_Sleep,
        "Nothing", L_No;

L_Sleep:
    mes "[Swet]";
    set TMW_Quest, 51;
    mes "\"Ah, this one. For that he need a lot of experience of tailing. I'll make it for him.\"";
    next;
    mes "[Swet]";
    mes "\"But for it I need 20 [Cotton Cloth]s and 40 [White Fur]s. Please, get it.\"";
    close;

L_Sleeping:
    if (countitem("CottonCloth") < 20) goto L_NotEnough;
    if (countitem("WhiteFur") < 40) goto L_NotEnough;
    mes "[Swet]";
    set TMW_Quest, 52;
    mes "\"Great, you made it. Now, give this sleeping bag to Elijah.\"";
    delitem "CottonCloth", 20;
    delitem "WhiteFur", 40;
    close;

L_Sun:
    mes "[Swet]";
    mes "\"It's such a good day today, isn't it?\"";
    close;
}