buildscript {
    repositories {
        jcenter()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = 'sponge'
            url = 'https://repo.spongepowered.org/maven'
        }
        maven {
            name = "Modmuss50"
            url = "http://maven.modmuss50.me/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.2-SNAPSHOT'
        classpath 'org.spongepowered:mixingradle:0.5-SNAPSHOT'
        classpath 'ModsIOUpload:ModsIOUpload:+'
    }
}

plugins {
    id "com.matthewprenger.cursegradle" version "1.0.9"
    id 'org.spongepowered.plugin' version '0.8.1'
}
apply plugin: 'net.minecraftforge.gradle.forge'
apply plugin: 'org.spongepowered.mixin'
apply plugin: 'net.cazzar.gradle.modsio'
apply plugin: 'maven'
apply plugin: 'maven-publish'

def signJar(archivePath) {
    if (project.hasProperty("ksAlias") && project.hasProperty("ks") && project.hasProperty("ksPass")) {
        ant.signjar(
            jar:                  archivePath,
            alias:                project.ksAlias,
            keystore:             project.ks,
            storepass:            project.ksPass,
            preservelastmodified: true
        )
    } else {
        println "WARNING!!!\tCannot sign jar!"
    }
}

version = "1.1.0"
group= "com.wildex999.tickdynamic"
archivesBaseName = "TickDynamic-SpongeForge-1.11.2"

allprojects {
    sourceCompatibility = 1.8
    targetCompatibility = 1.8
}


minecraft {
    version = "1.11.2-13.20.0.2315"
    runDir = "run"
    replace '${version}', project.version
    mappings = "stable_32"

	clientJvmArgs += "-Dfml.coreMods.load=com.wildex999.tickdynamic.LoadingPlugin"
	serverJvmArgs += "-Dfml.coreMods.load=com.wildex999.tickdynamic.LoadingPlugin"
	clientRunArgs += "--uuid=0b1ec5ad-cb2a-43b7-995d-889320eb2e5b --username=The_Fireplace"
}

dependencies {
	//compile 'org.spongepowered:spongeapi:5.0.0'
    compile 'org.spongepowered:mixin:0.5.17-SNAPSHOT'
    compile 'org.spongepowered:spongeforge:1.11.2-2393-6.1.0-BETA-2572:dev'
}

processResources
{
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

task showVersion {
    description "Displays the current version"
    group "help"

    compileJava.dependsOn showVersion
    deobfCompileDummyTask.dependsOn showVersion
    extractMcpMappings.dependsOn showVersion

    doLast {
        def versionFile = new File(buildDir, '.version')

        versionFile.getParentFile().mkdirs()
        versionFile.text = version
    }

    outputs.upToDateWhen { false }
}

sourceSets {
    main {
        refMap = "mixins.pluginmixintest.refmap.json"
    }
}

jar {
     manifest {
             attributes 'TweakClass': 'org.spongepowered.asm.launch.MixinTweaker',
                        'MixinConfigs': 'mixins.pluginmixintest.json',
                        'FMLCorePlugin': 'com.wildex999.tickdynamic.LoadingPlugin',
                        'FMLCorePluginContainsFMLMod': 'true'
         }

     doLast {
         if (!gradle.taskGraph.hasTask(reobfJar)) {
             signJar(jar)
         }
     }
 }

 reobfJar {
     doLast {
         signJar(jar)
     }
 }

 task deobfJar(type: Jar) {
     classifier = "deobf"
     manifest {
                 attributes 'FMLCorePlugin': 'com.wildex999.tickdynamic.LoadingPlugin',
                             'FMLCorePluginContainsFMLMod': 'true'
             }

     doLast {
         signJar(deobfJar.archivePath)
     }
 }

 sourceJar {

     doLast {
         signJar(sourceJar.archivePath)
     }
 }


artifacts {
    archives jar
    archives deobfJar
    archives sourceJar
}

curseforge {
  apiKey = project.hasProperty("curseForgeApiKey")? project.curseForgeApiKey : "empty"
  project {
    id = '269359'
    changelog = file('changelog.txt')
    releaseType = 'release'
    addGameVersion '1.11.2'
	addGameVersion 'Java 8'
    mainArtifact(jar) {
        displayName = jar.archiveName.replace(".jar", "")
    }
    addArtifact(sourceJar) {
        displayName = sourceJar.archiveName.replace(".jar", "")
        changelog = "*This is a file for mod developers. If you don't know what to do with it, don't use it!*"
    }
    addArtifact(deobfJar) {
        displayName = deobfJar.archiveName.replace(".jar", "")
        changelog = "*This is a file for mod developers. If you don't know what to do with it, don't use it!*"
    }
  }
}

modsIO {
    key = project.hasProperty("modsioApiKey")? project.modsioApiKey : "empty"
    project{
		artifact = new File(jar.destinationDir, archivesBaseName+"-"+version+".jar")
		modid = "1265"
		minecraft = "1.11.2"
		try{changelog = file('changelog.txt').text}catch(Exception e){changelog=""}
		tag = ""
		current = true
    }
}

uploadArchives {
    repositories {
        mavenDeployer {
            if (project.hasProperty("local_maven")) {
                repository(url: "file://${local_maven}")
                pom {
                    groupId = project.group
                    version = project.version
                    artifactId = project.archivesBaseName
                    project {
                        name project.archivesBaseName
                        packaging "jar"
                        description "TickDynamic"
                        url "https://github.com/The-Fireplace/TickDynamic"
                        issueManagement {
                            system "github"
                            url "https://github.com/The-Fireplace/TickDynamic/issues"
                        }
                        licenses {
                            license {
                                name "License"
                                url "https://github.com/The-Fireplace/TickDynamic/blob/master/LICENSE"
                                distribution "repo"
                            }
                        }
                        developers {
                            developer {
                                id "fireplace"
                                name "The_Fireplace"
                                roles {
                                    role "owner"
                                    role "developer"
                                }
                            }
							developer {
                                id "wildex999"
                                name "wildex999"
                                roles {
                                    role "former developer"
                                }
                            }
                        }
                    }
                }
            }
        }
    }
}