/*
 *      rfid        node
 *      3.3v        3.3v
 *      rst         d2
 *      gnd         gnd
 *      miso        d6
 *      mosi        d7
 *      sck         d5
 *      sda         d4
 */

#include <SPI.h>
#include <MFRC522.h>
#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>

#define SS_PIN D4
#define RST_PIN D2

MFRC522 mfrc522(SS_PIN, RST_PIN);

const char* ssid = "WISP";
const char* password = "17215541";

#define ledbuzz 15

int count = 0;

void setup(){
  Serial.begin(9600);
  SPI.begin();
  mfrc522.PCD_Init();
  Serial.println("RFID reading UID");

  pinMode(ledbuzz,OUTPUT);
  digitalWrite(ledbuzz,HIGH);

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
  }

}

void loop(){
  String tmpValue = "";

  if(mfrc522.PICC_IsNewCardPresent()){
    if(mfrc522.PICC_ReadCardSerial()){
      Serial.print("Tag UID:");
      for (byte i = 0; i < mfrc522.uid.size; i++) {
        Serial.print(mfrc522.uid.uidByte[i], HEX);
        tmpValue += String(mfrc522.uid.uidByte[i], HEX);
      }

      digitalWrite(ledbuzz,LOW);
      delay(500);
      digitalWrite(ledbuzz,HIGH);

      String msg = "";
      msg += tmpValue;

      if(WiFi.status() == WL_CONNECTED){

        HTTPClient http;

        String url = "http://nv.labm2m.com/data.php?";
        url += "rfid=";
        url += msg;
        http.begin(url);
        int httpCode = http.GET();

        if(httpCode > 0){
          String payload = http.getString();
          Serial.print(" > ");
          Serial.println(payload);
        }

        http.end();

      }

      Serial.println();
      mfrc522.PICC_HaltA();
    }
  }

  if(WiFi.status() != WL_CONNECTED){
    recon();
  }

  delay(50);

}

void recon(){
  while(WiFi.status() != WL_CONNECTED){

    //wifi reload connection
    WiFi.begin(ssid, password);
    delay(1000);

  }
}