jupe_ele,44,56,5	script	Bomber Pontuação	858,{
mes "[Bomber Pontuação]";
mes "==========================";
.@count = query_sql("SELECT char_id,value from char_reg_num where `key`='Bomberpoints' order by value DESC", .@ranks, .@points);
mes "Colocação # - Nome - Pontos";
if ( .@count <= 0){
	mes "Nenhum ainda.";
} else {
	for (set .@x, 0; .@x < .@count; set.@x, .@x + 1){
		query_sql("SELECT `name` from `char` where char_id='"+.@ranks[.@x]+"'", .@name$);
		mes "#"+(.@x+1)+": "+.@name$+" - "+.@points[.@x];
	}
}

close;
end;
}

-	script	Bomber	-1,{
OnInit:
	set .eventstarted, 0;
	set $Bomber_reward,12256;
	bindatcmd "enableBomber","Bomber::OnGMStart";
	bindatcmd "disableBomber","Bomber::OnGMStop";
	hideonnpc "Bomber#2";
	//hideonnpc "Bomber#1";
	end;

OnGMStart:
	if (getgroupid() < 99){
		dispbottom "Você não está qualificado para este comando.", RED;
		end;
	}
	set .eventstarted, 0;
OnEventStart:
	initnpctimer;
	hideoffnpc "Bomber#1";
	set .x, 3;
OnTimer0000:
	if (.eventstarted == 1)
		end;
	announce "Bomber: O evento vai começar em breve!",bc_all;
	announce "Bomber: Venha para sala de eventos em Elfic e fale comigo para participar!",bc_all;
	announce "Bomber: "+.x+" minutos restantes antes de começar!",bc_all;
	set .x, .x - 1;
	end;
OnTimer60000:
OnTimer120000:
	if (.eventstarted == 1)
		end;
	announce "Bomber: "+.x+" minutos restantes antes do início do evento Bomber!",bc_all;
	set .x, .x - 1;
	end;
OnTimer170000:
	if (.eventstarted == 1)
		end;
	announce "Bomber: 10 segundos antes do início do evento Bomber!",bc_all;
	end;
OnTimer180000:
	if (.eventstarted == 1)
		end;
	set .totalplayers, getmapusers ("quiz_02");
	announce "Bomber: "+.totalplayers+" jogadores se juntaram!",bc_all;
	announce "Bomber: O Bombardeiro vai começar! Tchau!",bc_all;
	//hideonnpc "Bomber#1";
	stopnpctimer;
	callsub OnEventStart1;
	end;

OnEventStart1:
	set .totalplayers, getmapusers ("quiz_02");
	mapannounce "quiz_02","Bomber: Ok, ouça, é assim que funciona.",bc_all;
	sleep 2000;
	mapannounce "quiz_02","Bomber: Bombardeiros correrão desenfreados nesta área.",bc_all;
	sleep 2000;
	mapannounce "quiz_02","Bomber: e todos eles vão booooooom!",bc_all;
	sleep 2000;
	mapannounce "quiz_02","Bomber: tudo que você tem a fazer é evitá-los.",bc_all;
	sleep 2000;
	mapannounce "quiz_02","Bomber: Isso será executado por 30 segundos por 5 rodadas no total.",bc_all;
	sleep 2000;
	mapannounce "quiz_02","Bomber: AAAAAH!, pronto ou não aqui eles vêm!!!", bc_all;

	for (set .round,1;.round <= 5;set .round, .round + 1) {
		set .totalplayers, getmapusers ("quiz_02");
		callsub OnBomberSummon;
		sleep 10000;
	}

	if (.round > 5 && getmapusers("quiz_02") > 0){
		hideoffnpc "Bomber#2";
		mapannounce "quiz_02","Bomber: Wooooow! Isso é raro! Pessoas ganharam! :D",bc_all;
	}
	end;

OnBomberSummon:
	mapannounce "quiz_02","Bomber: Round "+.round+"!!",bc_all;
	set .eventstarted, 1;
	initnpctimer;
	while (.eventstarted == 1) {
		if ( (3 * .totalplayers) <= 60)
			areamonster "quiz_02",48,334,71,357,"Corra por sua vida!",1904,3 * .totalplayers;
		else
			areamonster "quiz_02",48,334,71,357,"Corra por sua vida!",1904,60;

		if(.round == 1) {
			sleep 4000;
		} else if (.round == 2) {
			sleep 3000;
		} else if (.round == 3) {
			sleep 2000;
		} else if (.round == 4) {
			sleep 1500;
		} else if (.round == 5) {
			sleep 1000;
		}
	}
	if (.eventstarted == 1)
		mapannounce "quiz_02","Bomber: Round "+.round+" terminou!!",bc_all;
	if (.round < 5)
		mapannounce "quiz_02","Bomber: Próxima rodada em 10 segundos.",bc_all;
	return;

OnTimer31000:
	if (.eventstarted == 0)
		end;
	else
		set .eventstarted, 0;
		killmonsterall "quiz_02";
		cleanmap "quiz_02";
	stopnpctimer;
	end;

OnPCDieEvent:
	if (strcharinfo(3) == "quiz_02") {
		mapannounce "quiz_02","Bomber: "+strcharinfo(0)+" foi explodid"+(Sex? "o":"a")+"!!",bc_all;
		dispbottom "Você recebeu 100 CASHPOINTS por participar neste evento.";
		set #CASHPOINTS, #CASHPOINTS + 100;
		sleep2 3000;
		set @Bomberpoints, @Bomberpoints + 1;
		warp "jupe_ele",37,54;
		if (getmapusers("quiz_02") <= 1) {
			stopnpctimer;
			set .eventstarted, 0;
			set .round, 6;
			killmonsterall "quiz_02";
			cleanmap "quiz_02";
			hideoffnpc "Bomber#2";
			mapannounce "quiz_02","Bomber: Tudo bem! Nós temos u"+(Sex? "m":"ma")+" vencedo"+(Sex? "r":"ra")+"!!",bc_all;
		}
	}
	end;

OnPCLogoutEvent:
	set Bomberpoints, Bomberpoints + @Bomberpoints;
	end;
OnGMStop:
	set .eventstarted, 0;
	set .round, 6;
	killmonsterall "quiz_02";
	cleanmap "quiz_02";
	hideoffnpc "Bomber#2";
	end;
}

quiz_02,59,345,5	script	Bomber#2	2_F_SIGN1,{
mes "[Bomber]";
mes "Ha! Você foi muito bom lá atrás!";
mes "Aqui está um token para me entreter.";
next;
mes "^00FF00Você recebeu 250 CASHPOINTS!";
mes "Você recebeu ^00FF00"+getitemname($Bomber_reward)+"^000000!";
set #CASHPOINTS, #CASHPOINTS + 250;
getitem $Bomber_reward,1;
next;
mes "[Bomber]";
mes "Agora saia daqui antes que eu faça você explodir!";
next;
set @Bomberpoints, @Bomberpoints + 2;
warp "jupe_ele",37,54;
end;
}

jupe_ele,46,56,5	script	Bomber#1	4_DR_STELO,{
mes "[Bomber]";
mes "Oi! Quer participar do evento Bomber?";
Switch(Select("Sim!:Sobre o que é isso?:Não, não estou interessad"+(Sex? "o":"a")+".")) {
	case 1:
		mes "[Bomber]";
		mes "Tudo bem! Prepare-se!";
		next;
		set @Bomberpoints,0;
		warp "quiz_02",59,345;
		break;
	case 2:
		mes "[Bomber]";
		mes "Bem, tudo que você tem a fazer é ficar vivo.";
		mes "Isso é, esquivando-se, pois teremos bombers explodindo com ^00FF00Bombardeiros^000000!";
		next;
		mes "[Bomber]";
		mes "Se você ganhar, você receberá:";
		mes "1x ^00FF00250 CASHPOINTS^000000!";
		mes "1x ^00FF00"+getitemname($Bomber_reward)+"^000000!";
		close;
		break;
	case 3:
		mes "[Bomber]";
		mes "Tudo bem, vejo você por aí!";
		close;
		break;
	}
end;

OnInit:
	waitingroom "@enableBomber",0;
	//hideonnpc "Bomber#1";
}