deadbeef-plugin-waveform-git PKGBUILD

# Maintainer:  Raphaël Doursenaud <[email protected]>
# Contributor: dreieck (https://aur.archlinux.org/account/dreieck)
# Contributor: Raphaël Doursenaud <[email protected]>

_gitname=ddb_waveform_seekbar
# _gituser=cboxdoerfer
_gituser=Jbsco
_githost=github.com

_pkgbase="deadbeef-plugin-waveform"
pkgbase="${_pkgbase}-git"
pkgname=(
  "${_pkgbase}-doc-git"
  "${_pkgbase}-gtk2-git"
  "${_pkgbase}-gtk3-git"
)
epoch=0
pkgver=0.5.r204.20240912.2e5ea86
pkgrel=1
_pkgdesc="Waveform Seekbar plugin for DeaDBeeF audio player, latest git checkout."
pkgdesc="${_pkgdesc}"
url="https://github.com/Jbsco/ddb_waveform_seekbar"
arch=(
  'i686'
  'x86_64'
)
license=(
  'GPL-2.0-or-later'
)
_common_depends=(
  'cairo'
  'deadbeef'
  'glib2'
  'glibc'
  'sqlite'
)
_gtk2_depends=(
  'gtk2'
)
_gtk3_depends=(
  'gtk3'
)
makedepends=(
  'git'
  "${_common_depends}"
  "${_gtk2_depends}"
  "${_gtk3_depends}"
)

_gitroot="${url}.git"
source=("${_pkgbase}::git+${_gitroot}")
sha256sums=('SKIP')

prepare() {
  cd "${srcdir}/${_pkgbase}"

  git log > git.log
}

pkgver() {
  cd "${srcdir}/${_pkgbase}"

  _ver_major="$(grep -E '^[[:space:]]*\.plugin\.version_major[[:space:]]*=' waveform.c | sed -E 's|^[[:space:]]*\.plugin\.version_major[[:space:]]*=[[:space:]]*([-\.0-9a-zA-Z_]*).*$|\1|')"
  _ver_minor="$(grep -E '^[[:space:]]*\.plugin\.version_minor[[:space:]]*=' waveform.c | sed -E 's|^[[:space:]]*\.plugin\.version_minor[[:space:]]*=[[:space:]]*([-\.0-9a-zA-Z_]*).*$|\1|')"
  _ver="${_ver_major}.${_ver_minor}"
  # _ver="$(git describe --tags | sed -E -e 's|^[vV]||' -e 's|\-g[0-9a-f]*$||' | tr '-' '+')"
  _rev="$(git rev-list --count HEAD)"
  _date="$(git log -1 --date=format:"%Y%m%d" --format="%ad")"
  _hash="$(git rev-parse --short HEAD)"

  if [ -z "${_rev}" ]; then
    error "Git commit count could not be determined."
    return 1
  fi
  if [ -z "${_ver}" ]; then
    error "Version could not be determined."
    return 1
  else
    printf '%s' "${_ver}.r${_rev}.${_date}.${_hash}"
  fi
}

build() {
  cd "${srcdir}/${_pkgbase}"
  make
}

package_deadbeef-plugin-waveform-doc-git() {
  arch=("any")
  pkgdesc="${_pkgdesc} Common documentation files."
  depends=()
  provides=("${_pkgbase}-doc")
  conflicts=("${_pkgbase}-doc=${pkgver}")
  optdepends=(
    "${_pkgbase}-gtk2: The software (GTK2-variant) this documentation is for."
    "${_pkgbase}-gtk3: The software (GTK3-variant) this documentation is for."
  )

  cd "${srcdir}/${_pkgbase}"
  install -Dvm644 -t "${pkgdir}/usr/share/doc/${_pkgbase}"  git.log README.md
}

package_deadbeef-plugin-waveform-gtk2-git() {
  pkgdesc="${_pkgdesc} GTK2 variant."
  depends=(
    "${_common_depends[@]}"
    "${_gtk2_depends[@]}"
  )
  optdepends=("${_pkgbase}-doc: For (minimal) documentation files.")
  provides=("${_pkgbase}-gtk2=${pkgver}")
  conflicts=("${_pkgbase}-gtk2")

  cd "${srcdir}/${_pkgbase}"
  install -Dvm644 -t "${pkgdir}/usr/lib/deadbeef"  "gtk2/ddb_misc_waveform_GTK2.so"
}

package_deadbeef-plugin-waveform-gtk3-git() {
  pkgdesc=${_pkgdesc}" GTK3 variant."
  depends=(
    "${_common_depends[@]}"
    "${_gtk3_depends[@]}"
  )
  optdepends=("${_pkgbase}-doc: For (minimal) documentation files.")
  provides=("${_pkgbase}-gtk3=${pkgver}")
  conflicts=("${_pkgbase}-gtk3")


  cd "${srcdir}/${_pkgbase}"
  install -Dvm644 -t "${pkgdir}/usr/lib/deadbeef"  "gtk3/ddb_misc_waveform_GTK3.so"
}