1234

Proceso sin_titulo
	Definir numJ, numM, i, x Como Entero;
	Definir valorTemporal, aciertos Como Entero;
	Definir validador Como Logico;
	Dimension numJ(14);
	Dimension numM(14);
	validador = verdadero;
	aciertos = 0;
	valorTemporal = 0;
	i = 0;
	x = 0;

	// En esta parte se asigna el valor 0 a las 14 variables dentro de los 2 arreglos.
	Para i <-0 Hasta 13 con paso 1 hacer
		numM(i) = 0;
		numJ(i) = 0;
	FinPara
	// Aqui se asigan los 14 numeros de la maquina. y se verefica que no se repitan. en caso de repetirse, se vuelve a tirar un numero al azar.

	Para i <- 0 hasta 13 con paso 1 Hacer
		numM(i) = azar (25)+1;
		para x <- 0 Hasta 13 con paso 1 hacer
			Si i != x Entonces
				Si numM(i) == numM(x) Entonces
					validador = Falso;
				FinSi
			FinSi
		FinPara
		Si validador == falso Entonces
			i = i -1;
			validador = Verdadero;
		FinSi
	FinPara

	// En esta parte el usuario ingresa sus 14 numeros, en caso de ser un numero repetido, este le pedira que ingrese nuevamente...
	// yo lo deje con un selector automatico para ahorrar tiempo al momento de testiar...(linea 39).
	Para i <- 0 Hasta 13 con paso 1 Hacer
		Escribir "Ingrese un numero entre 1 y 25, no se puede repetir";
		numJ(i) = azar(25)+1;
		Esperar 200 milisegundo;
		Limpiar Pantalla;
		Si numJ(i) > 0 && numJ(i) < 26 Entonces
			para x <-0 Hasta 13 con paso 1 Hacer
				si i != x Entonces
					Si numJ(i) == numJ(x) Entonces
						validador = falso;
					FinSi
				FinSi
			FinPara
			Si validador ==  falso Entonces
				i = i -1;
				validador = Verdadero;
				Escribir "El numero seleccionado ya fue ingresado, Ingrese nuevamente";
			FinSi
		Sino
			Escribir "Debe ingresar un numero en el rango valido";
			i = i-1;
		FinSi
	FinPara

	// En esta parte se ordenan los numeros.
	Para i <- 0 Hasta 13 con paso 1 Hacer
		para x <- 0 Hasta 13 con paso 1 hacer
			Si x != 0 Entonces
				Si numM(x -1) > numM(x) Entonces
					valortemporal = numM(x);
					numM(x) = numM(x -1);
					numM(x -1) = valortemporal;
				FinSi
			FinSi
		FinPara
	FinPara

	Para i <- 0 Hasta 13 con paso 1 Hacer
		Para x <- 0 Hasta 13 con paso 1 hacer
			Si numJ(i) == numM(x) Entonces
				aciertos = aciertos +1;
			FinSi
		FinPara
	FinPara

	Escribir "============================================";
	Escribir "Los numeros sorteados fueron";
	Escribir "============================================";
	Para i <- 0 Hasta 13 Con paso 1 Hacer
		Escribir Sin Saltar "|", numM(i),"|";
	FinPara
	Escribir "";
	Escribir "============================";
	Escribir "Tus numeros seleccionados fueron";
	Escribir "============================";
	Para i <-0 Hasta 13 con paso 1 Hacer
		Escribir sin saltar "|", numJ(i),"|";
	FinPara
	Escribir "";
	Escribir "=======================================";
	Escribir "Hubieron ",aciertos," aciertos en tu apuesta";
FinProceso