Wsh Vbscript Download com alias for mIRC

;WshVbscriptDownload http://location.com/PageorFilename.ext LocationtoSave
;$WshVbscriptDownload(http://location.com/PageorFilename.ext,LocationtoSave)
alias WshVbscriptDownload {
  var %comname $+(WshVbscriptDownload,$ticks,$r(1,1000))
  .comopen %comname MSScriptControl.ScriptControl
  if ($com(%comname)) {
    var %Success $com(%comname,language,4,string,vbscript)
    inc %Success $Execute(%comname,Set MicrosoftXmlhttp = CreateObject("Microsoft.Xmlhttp"))
    inc %Success $Execute(%comname,$+(MicrosoftXmlhttp.Open "GET",$chr(44),$qt($1),$chr(44),False))
    inc %Success $Execute(%comname,MicrosoftXmlhttp.Send)
    inc %Success $Execute(%comname,set AdodbStream = CreateObject("Adodb.Stream"))
    inc %Success $Execute(%comname,AdodbStream.type = 1)
    inc %Success $Execute(%comname,AdodbStream.open)
    inc %Success $Execute(%comname,AdodbStream.write MicrosoftXmlhttp.responseBody)
    echo -a Downloading $1 $bytes($evaluate(%comname,AdodbStream.Size)).suf
    inc %Success $Execute(%comname,AdodbStream.savetofile $+($qt($2),$chr(44),2))
    inc %Success $Execute(%comname,AdodbStream.close)
    if (%Success != 10) echo -st *error* WshVbscriptDownload Download Failed!
    else echo -a Download of $1 Complete
    .comclose %comname
  }
}
alias -l Execute return $com($1,executestatement,3,bstr,$2-)
alias -l Evaluate {
  noop $com($1,eval,3,bstr,$2-)
  return $com($1).result
}