libreoffice-extension-writer2latex PKGBUILD

pkgname=libreoffice-extension-writer2latex
_javaname=writer2latex
_exts=( writer2latex writer2xhtml writer4latex )
pkgver=1.2.1
pkgrel=8
pkgdesc="A java program and collection of LibreOffice extensions for converting to and working with LaTeX in LibreOffice"
arch=('any')
url="http://writer2latex.sourceforge.net"
license=('LGPL')
groups=('libreoffice-extensions')
depends=('libreoffice-common' 'java-runtime-headless')
makedepends=('libreoffice-writer')
conflicts=('libreoffice-extension-writer2latex-svn')

_nodotver=${pkgver//.}
_srcname=${_javaname}${_nodotver}
# "$_srcname"::git+"https://github.com/kolewu/writer2latex.git#tag=$pkgver"
source=("http://downloads.sourceforge.net/project/writer2latex/writer2latex/Writer2LaTeX%20${pkgver%.*}/${_srcname}.zip"
        'writer2latex.sh')
md5sums=('643906496a5ec519cd4ee044305675bc'
         'f2d20081ef6d5c905d54385697856642')

#prepare() {
#  cd "$srcdir/$_srcname"
#  patch < "$srcdir/build.xml.patch"
#}

build() {
  cd "$srcdir/$_srcname/doc"
  libreoffice --headless --convert-to pdf user-manual.odt
}

package() {
  cd "$srcdir/$_srcname"

  #Install the extensions
  for _ext in ${_exts[@]}; do
    install -dm755  "$pkgdir/usr/lib/libreoffice/share/extensions/$_ext"
    bsdtar -xf $_ext.oxt -C "$pkgdir/usr/lib/libreoffice/share/extensions/$_ext"
  done

  #Install the java converter
  install -Dm644 $_javaname.jar "$pkgdir/usr/share/java/$_javaname/$_javaname.jar"

  #Install shell script to execute java program
  install -Dm755 "$srcdir/$_javaname.sh" "$pkgdir/usr/bin/$_javaname"

  #Install documentation
  install -Dm644 Readme.txt "$pkgdir/usr/share/doc/$pkgname/Readme.txt"
  install -Dm644 changelog.txt "$pkgdir/usr/share/doc/$pkgname/changelog.txt"
  install -Dm644 History.txt "$pkgdir/usr/share/doc/$pkgname/History.txt"
  install -Dm644 doc/* "$pkgdir/usr/share/doc/$pkgname/"
}