# Bukkit - CommandHelper - Clone / Ban Evasion Detection
# Created by CyaNox (Admin of mc.qubetubers.com)
# Provided as is without warranty and under public domain.

proc(_msgmods, @text,
  foreach(all_players(), @pl,
    foreach(array('mods', 'supermods', 'admins'), @r,
      if(array_contains(pinfo(@pl, 9), @r),
        tmsg(@pl, @text)
      )
    )
  )
)

bind(player_join, array(array(priority, HIGHEST)), null, @eb,
  assign(@plt, get_value(concat(iplookup, @eb['player'])))
  if(equals(@plt, null), assign(@plt, 0))
  if(lt(@plt, floor(divide(time(), 10000))),
    store_value(concat(iplookup, @eb['player']), floor(divide(time(), 10000)))
  , die())
  assign(@pip, pinfo(@eb['player'], 3))
  assign(@pip, replace(@pip, ., _))
  assign(@pip, replace(@pip, -, _))
  assign(@ps, get_value(concat(iplookup, @pip)))
  if(equals(@ps, null), assign(@ps, array()))
  if(not(array_contains(@ps, @eb['player'])),
    array_push(@ps, @eb['player'])
    store_value(concat(iplookup, @pip), @ps)
  )
  if(gt(array_size(@ps), 1),
    assign(@t, '')
    foreach(@ps, @p,
      assign(@t, concat(@t, @p, ' '))
    )
    call_proc(_msgmods, concat(color(LIGHT_PURPLE), '[CLONES]', color(GRAY), ' Player ', color(RED), @eb['player'], color(GRAY), ' also known as ', color(RED), @t))
  )
)