XSLT stylesheet para gerar índice multinível para os arqsits

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="2.0">

    <xsl:template match="/">
        <html>
            <head>
                <title>Arqueossítios</title>
            </head>
            <body>
                <a name="indice"/>
                <h2>Índice</h2>
                <ul>
                    <xsl:apply-templates select="//CONCEL[not(normalize-space(.)=preceding::CONCEL/normalize-space(.))]" mode="indice">
                        <xsl:sort select="normalize-space(.)"/>
                    </xsl:apply-templates>
                </ul>
                <hr/>
                <h1>Arqueossítios do NW português</h1>
                <hr align="center" width="60%"/>
                <xsl:apply-templates/>
            </body>
        </html>

    </xsl:template>

    <!-- ..........Templates para geração do conteúdo.... -->

    <xsl:template match="ARQELEM">
        <h3>
            <a name="{generate-id()}">
                <xsl:value-of select="IDENTI"/>
            </a>
        </h3>
        <p><b>Localização:</b>
            <xsl:value-of select="FREGUE"/>,
            <xsl:value-of select="CONCEL"/>.
        </p>
        <p>
            <xsl:value-of select="DESARQ"/>
        </p>
        <address>[<a href="#indice">Voltar ao topo</a>]
            [<a href="#i{generate-id()}">Voltar atrás</a>]</address>
        <hr width="80%" align="center"/>
    </xsl:template>

    <!-- ..........Templates para geração do índice.... -->

    <xsl:template match="CONCEL" mode="indice">
        <xsl:variable name="c" select="normalize-space(.)"/>
        <li>
            <xsl:value-of select="."/>
            <ul>
                <xsl:apply-templates select="/ARQSITS/ARQELEM[normalize-space(CONCEL)=$c]" mode="indice">
                    <xsl:sort select="IDENTI"/>
                </xsl:apply-templates>
            </ul>
        </li>
    </xsl:template>

    <xsl:template match="ARQELEM" mode="indice">
        <li>
            <a href="#{generate-id()}"
                name="i{generate-id()}">
                <xsl:value-of select="IDENTI"/>
            </a>
        </li>
    </xsl:template>


</xsl:stylesheet>