Billy3 clear test users

GO
BEGIN TRANSACTION [ClearTestUsersTransaction]

BEGIN TRY
SELECT
  u.RId  UserId,
  p.RId  PostId,
  sa.Id  SurveyAnswerId,
  pn.RId PostNotificationId,
  r.RId  ReplyId,
  cl.Id  CreditsLedgerId,
  ra.RId ReplyActionId,
  ts.RId TimeSlotId,
  at.RId AuditTrailId
INTO #toRemove
FROM Users u
  LEFT JOIN Posts p ON u.RId = p.UserId
  LEFT JOIN SurveyAnswers sa ON p.RId = sa.PostId
  LEFT JOIN PostsNotifications pn ON pn.PostId = p.RId
  LEFT JOIN Replies r ON r.PostId = p.RId
  LEFT JOIN CreditsLedger cl ON cl.ReplyId = r.RId
  LEFT JOIN ReplyActions ra ON ra.ReplyId = r.RId
  LEFT JOIN TimeSlots ts ON ts.PostId = p.RId
  LEFT JOIN AuditTrail at ON at.UserId = u.RId
WHERE (u.ZipCode = '00737' OR u.ZipCode = '00923') AND Password IS NULL

DELETE FROM SurveyAnswers
WHERE Id IN (SELECT SurveyAnswerId
             FROM #toRemove)

DELETE FROM PostsNotifications
WHERE RId IN (SELECT PostNotificationId
              FROM #toRemove)

DELETE FROM CreditsLedger
WHERE Id IN (SELECT CreditsLedgerId
             FROM #toRemove)

DELETE FROM ReplyActions
WHERE RId IN (SELECT ReplyActionId
              FROM #toRemove)

DELETE FROM TimeSlots
WHERE RId IN (SELECT TimeSlotId
              FROM #toRemove)

DELETE FROM Replies
WHERE RId IN (SELECT ReplyId
              FROM #toRemove)

DELETE FROM Posts
WHERE RId IN (SELECT PostId
              FROM #toRemove)

DELETE FROM AuditTrail
WHERE RId IN (SELECT AuditTrailId
              FROM #toRemove)

DELETE FROM Users
WHERE RId IN (SELECT UserId
              FROM #toRemove)

DROP TABLE #toRemove
COMMIT TRANSACTION [ClearTestUsersTransaction]

END TRY
BEGIN CATCH
ROLLBACK TRANSACTION [ClearTestUsersTransaction]
SELECT
  ERROR_NUMBER()    AS ErrorNumber,
  ERROR_SEVERITY()  AS ErrorSeverity,
  ERROR_STATE()     AS ErrorState,
  ERROR_PROCEDURE() AS ErrorProcedure,
  ERROR_LINE()      AS ErrorLine,
  ERROR_MESSAGE()   AS ErrorMessage;
END CATCH

GO