move_to_block_center

$${

//Code developed by lomexicano#2779 (discord contact);
//Works only in Minecraft 1.11+ ;

set(#error_margin,5); ///error margin. Possible range: 1 to 30. Default: 5;
set(sneak); //change to "unset(sneak)" it if you don't want to sneak in the process - i recommend you to increase the error_margin to, at least, 15;


if((#error_margin < 1)|(#error_margin > 30));
    set(#error_margin,10);
endif;
#error_margin = #error_margin * 10;
set(#final_decimal,500);
inc(#final_decimal,"%#error_margin%");
set(#initial_decimal,500);
dec(#initial_decimal,"%#error_margin%");

set(#pos_final_x1,"%XPOS%"); if(%XPOS% < 0); inc(#pos_final_x1,1); endif; set(#pos_final_x1,"%#pos_final_x1%%#initial_decimal%");
set(#pos_final_x2,"%XPOS%"); if(%XPOS% < 0); inc(#pos_final_x2,1); endif; set(#pos_final_x2,"%#pos_final_x2%%#final_decimal%");
set(#pos_final_z1,"%ZPOS%"); if(%ZPOS% < 0); inc(#pos_final_z1,1); endif; set(#pos_final_z1,"%#pos_final_z1%%#initial_decimal%");
set(#pos_final_z2,"%ZPOS%"); if(%ZPOS% < 0); inc(#pos_final_z2,1); endif; set(#pos_final_z2,"%#pos_final_z2%%#final_decimal%");

match(%XPOSF%,"^(\-?\d+)\.(\d+)$",{#pos_now_x1,#pos_now_x2});
set(#pos_now_x,"%#pos_now_x1%%#pos_now_x2%");
match(%ZPOSF%,"^(\-?\d+)\.(\d+)$",{#pos_now_z1,#pos_now_z2});
set(#pos_now_z,"%#pos_now_z1%%#pos_now_z2%");

if((((%#pos_now_x% < %#pos_final_x1%)&&(%#pos_now_x% > %#pos_final_x2%))|((%#pos_now_x% > %#pos_final_x1%)&&(%#pos_now_x% < %#pos_final_x2%)))&&(((%#pos_now_z% < %#pos_final_z1%)&&(%#pos_now_z% > %#pos_final_z2%))|((%#pos_now_z% > %#pos_final_z1%)&&(%#pos_now_z% < %#pos_final_z2%))));
    log("good enough");
else;
    calcyawto(%XPOS%,%ZPOS%,#yaw); inc(#yaw,180);
    look(%#yaw%,90);
endif;

unsafe(0);
    do();
        match(%XPOSF%,"^(\-?\d+)\.(\d+)$",{#pos_now_x1,#pos_now_x2});
        set(#pos_now_x,"%#pos_now_x1%%#pos_now_x2%");
        match(%ZPOSF%,"^(\-?\d+)\.(\d+)$",{#pos_now_z1,#pos_now_z2});
        set(#pos_now_z,"%#pos_now_z1%%#pos_now_z2%");
        if((((%#pos_now_x% < %#pos_final_x1%)&&(%#pos_now_x% > %#pos_final_x2%))|((%#pos_now_x% > %#pos_final_x1%)&&(%#pos_now_x% < %#pos_final_x2%)))&&(((%#pos_now_z% < %#pos_final_z1%)&&(%#pos_now_z% > %#pos_final_z2%))|((%#pos_now_z% > %#pos_final_z1%)&&(%#pos_now_z% < %#pos_final_z2%))));
            keyup(forward);
            keyup(sneak);
            break;
        else;
            if(sneak);
                keydown(sneak);
            endif;
            calcyawto(%XPOS%,%ZPOS%,#yaw); inc(#yaw,180);
            look(%#yaw%,90);
            keydown(forward);
            wait(1ms);
            keyup(forward);
            wait(1ms);
        endif;
    loop;
endunsafe;

log(off);

}$$