freetube

pkgname=freetube
_pkgname=FreeTube
_pkgver=0.15.0-beta
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc='An open source desktop YouTube player built with privacy in mind.'
arch=('x86_64' 'aarch64' 'armv7h')
url="https://freetubeapp.io"
license=('AGPL3')
depends=('electron13')
makedepends=('npm' 'yarn')
source=("$_pkgname-$_pkgver.tar.gz::https://github.com/FreeTubeApp/FreeTube/archive/v$_pkgver.tar.gz"
        'package-only-necessary.diff'
        "$pkgname.desktop"
        "$pkgname.sh")
sha256sums=('7e5f12444f881cc708b271aa4abd5ab9064c0577a297e7e0d4a02936b95f249b'
            '40bc70f6e2996ba6d2e77e385a618737b7f4c68c9c0bc52bbb2de93dbb01de2f'
            '1b518ac2f42db51294316b15313e997c7f0ff6245cf1eb74830fe7caeea4e70b'
            'e4dab57eefc975469edf981984c76be17b574a51438e86f0df159ca6e2d8d637')

prepare() {
  cd "$_pkgname-$_pkgver"
  patch _scripts/build.js < ../package-only-necessary.diff
}

build() {
  cd "$_pkgname-$_pkgver"
  yarn config set cache-folder "$srcdir/yarn-cache"
  yarn install
  yarn run build
}

package() {
  cd "$_pkgname-$_pkgver"
  install -Dm644 build/linux-unpacked/resources/app.asar -t "$pkgdir/usr/lib/$pkgname"
  install -Dm644 _icons/icon.svg "$pkgdir/usr/share/pixmaps/$pkgname.svg"
  install -Dm755 "$srcdir/$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
  install -Dm644 "$srcdir/$pkgname.desktop" -t "$pkgdir/usr/share/applications"
}