Update Check

menu status,menubar {
  Update-c&heck... :checkver
}
alias sdt {
  if ($did($did).state) { set % $+ $1 1 }
  else { unset % $+ $1 }
}
alias checkver { noop $dialog(checkver,checkver,-4) }
alias new.version {
  did -a checkver 13 mIRC 7.76 has been released! (January 7th 2024)
  did -a checkver 13
  did -a checkver 13 This is a small update that adds features and addresses a number of issues reported by users since
  did -a checkver 13 the last release. It includes improvements, changes and fixes, including:
  did -a checkver 13
  did -a checkver 13 · Updated to Visual Studio 2017 to compile mIRC.
  did -a checkver 13 · Updated OpenSSL library to v3.0.12.
  did -a checkver 13 · Updated CA root certificates cacert.pem file.
  did -a checkver 13 · Fixed switchbar vertical scrollbar buttons not being visible on Windows 11.
  did -a checkver 13 · Added support for larger GUI icons for high resolution monitors.
  did -a checkver 13 · Fixed notify list MONITOR event parsing to handle events without hostnames.
  did -a checkver 13 · Fixed numeric 324 bug when parsing date range.
  did -a checkver 13 · Enabled Control Flow Guard runtime security checks.
  did -a checkver 13 · Fixed /toolbar -p bug that was not freeing memory correctly.
  did -a checkver 13 · Fixed typing notifications bug in parted/kicked channel windows.
  did -a checkver 13 · Added tab completion suffix option to Keys dialog.
}
alias new.beta {
  did -a checkver 13 1.Item 27, changes:
  did -a checkver 13
  did -a checkver 13 Updated the dialog resource parser to handle several more
  did -a checkver 13 contexts when loading/checking/comparing resources. Also now
  did -a checkver 13 takes account of changes that Resource Hacker makes to controls,
  did -a checkver 13 which was preventing mIRC from validating/using them.
  did -a checkver 13 $chr(32)
  did -a checkver 13 Experimented with resizing dialogs/controls in order to handle
  did -a checkver 13 longer translated text. Many of the dialogs and controls are tightly
  did -a checkver 13 sized/fitted. This will require changes to almost all dialogs and
  did -a checkver 13 will take a lot of work.
  did -a checkver 13 $chr(32)
  did -a checkver 13 Signed up with with Crowdin for translations and experimented with
  did -a checkver 13 editing/importing/exporting resources.
}
alias StartVersion {
  did -r $dname 13
  did -a $dname 11 Checking for updates...
  did -h $dname 4,8
  did -b $dname 6
  if (%check.beta) { var %URI = https://forums.mirc.com/ubbthreads.php/topics/225704 }
  else { var %URI = https://www.mirc.com/get.html }
  noop $urlget(%URI,gbi,&CheckVer,processWmIRC)
}
alias ProcessWmIRC {
  if ($dialog(checkver)) {
    var %beta = /The latest beta can be downloaded <a href="https\x3A\x2F\x2Fwww\x2Emirc\x2Ecom\x2Fdownloads\x2Fbeta\x2F([^"]+)"[^>]+>here</a>/i
    var %norm = /The latest version of mIRC is <strong>mIRC ([^<]+)</strong>/i
    var %id = $1 , %BV = $urlget(%id).target, %m
    if ($urlget(%id).state = ok) {
      if ($bfind(%BV,1,%norm,Norm).regex) {
        var %m = $mid($regml(Norm,1),2)
        if (%m != $version) {
          did -e checkver 6
          did -v checkver 4,8
          did -a checkver 11 %m
          new.version
          set %url.get $nofile($urlget(%id).url) $+ get.php
          set %url.news $nofile($urlget(%id).url) $+ news.html
        }
        else {
          did -ra checkver 11 mIRC is up to date.
          did -e checkver 6
        }
      }
      elseif ($bfind(%BV,1,%beta,Beta).regex) {
        var %m = $mid($wd($regml(Beta,1),1,46),9)
        if (%m != $beta) {
          did -e checkver 6
          did -v checkver 4,8
          did -a checkver 11 $+($version,.,%m)
          new.beta
          set %url.get $+(https://www.mirc.com/downloads/beta/,$regml(Beta,1))
          set %url.news $urlget(%id).url
        }
        elseif (%check.beta) { var %URI = https://www.mirc.com/get.html | noop $urlget(%URI,gbi,&CheckVer,processWmIRC) }
      }
    }
    else {
      did -a checkver 11 There was a problem contacting the mIRC website.
      did -e checkver 6
    }
  }
}
dialog checkver {
  title "mIRC Update"
  size -1 -1 515 397
  text "Installed version:", 9, 12 13 90 14, multi return
  text "Newest version:", 10, 12 35 90 14, multi return
  text "", 11, 120 35 300 14, multi return
  text "Changes from new version:", 12, 12 57 150 14, multi return
  list 13, 12 75 490 250, autovs size
  link "What's new in this version?", 4, 370 55 185 14, hide
  text "", 1, 120 13 80 14, multi return
  check "C&heck for new beta versions", 5, 12 372 157 14
  button "Check for &updates", 6, 10 334 107 23
  button "&OK", 7, 427 366 76 23, cancel
  button "&Download now", 8, 396 334 107 23, center hide ok
}
on *:dialog:checkver:*:*:{
  if ($devent == init) {
    did -a $dname 1 $iif($beta,$+($version,.,$beta),$version)
    did -f $dname 9
    if (%check.beta) { did -c $dname 5 }
  }
  elseif ($devent == sclick) {
    if ($did == 4) { url -an %url.news }
    elseif ($did == 5) { sdt check.beta }
    elseif ($did == 6) { StartVersion }
    elseif ($did == 8) { url -an %url.get }
  }
  elseif ($devent == close) { unset %url.get %url.news }
}