Actor Warhead : Ammo
{
    Inventory.Amount 1
    Inventory.MaxAmount 3
    Inventory.Icon "BFS1A0"
    Inventory.PickupMessage "You have picked up a Nuclear Warhead!"
    Inventory.PickupSound "misc/p_pkup"
    Ammo.BackpackAmount 0
    Ammo.BackpackMaxAmount 3
    Ammo.DropAmount 0
    +INVENTORY.IGNORESKILL
    +INVENTORY.BIGPOWERUP
    States
    {
    Spawn:
        DEBF A -1
        stop
    }
}

Actor SSAENuke : Weapon replaces BFG9000
{
    Inventory.PickupSound "misc/p_pkup"
    Inventory.PickupMessage "You have picked up a Nuclear Launcher!"
    Weapon.AmmoGive 1
    Weapon.AmmoType "Warhead"
    Weapon.AmmoUse 1
    Weapon.Kickback 0
    Weapon.SlotNumber 8
    Weapon.SlotPriority 0
    Weapon.SelectionOrder 9999
    +WEAPON.BFG
    +WEAPON.CHEATNOTWEAPON
    +WEAPON.NO_AUTO_SWITCH
    +WEAPON.NOAUTOAIM
    +WEAPON.NOAUTOFIRE
    +INVENTORY.BIGPOWERUP
    Tag "Nuke Launcher"
    States
    {
    Ready:
        DBFG A 1 A_WeaponReady
        loop
    Deselect:
        DBFG AAA 0 A_Lower
		DBFG A 1 A_Lower
        loop
    Select:
        DBFG AAA 0
		DBFG A 1 A_Raise
        loop
    Fire:
        DBFG B 2 A_PlaySound("Weapons/Nuke/Charge",4)
		DBFC ABCDE 2 Bright
		DBFC F 2 Bright A_GunFlash
		DBFC GHIJ 2 Bright
		DBFF A 0 Bright A_PlaySound("Weapons/Nuke/Fire",1)
        DBFF A 2 Bright A_FireCustomMissile("NukeBall",0,1,0,0,0,0)
		DBFF B 2 Bright
		DBFG CDA 2 Bright
        goto Ready
	Flash:
		TNT1 A 5 bright A_Light1
		TNT1 A 3 bright A_Light2
		TNT1 A 2 bright A_Light(3)
		TNT1 A 2 bright A_Light(4)
		TNT1 A 2 bright A_Light(3)
		TNT1 A 2 bright A_Light2
		TNT1 A 3 bright A_Light1
		Goto LightDone
    Spawn:
        BFUG A -1
        stop
    }
}

Actor NukeBall
{
	var int user_NukeTimer;

    Height 8
    Radius 13
    Damage (Random(user_NukeTimer * 3,user_NukeTimer * 5))
	DamageType "PlayerNuke"
    Speed 25
    Projectile
    Renderstyle add
	Alpha 0.75
    Obituary "%o saw the light."
	+RIPPER
    +FORCERADIUSDMG
	+NODAMAGETHRUST
    States
    {
    Spawn:
		BFS1 A 0 bright A_SetUserVar("user_NukeTimer",0)

		BFS1 A 0 bright A_SetUserVar("user_NukeTimer", user_NukeTimer + 1)
        BFS1 A 0 bright A_Explode(sqrt(user_NukeTimer * 160), sqrt(user_NukeTimer * 320),0,0,0)
		BFS1 A 4 bright A_ScaleVelocity(0.80)
		BFS1 A 0 bright A_JumpIf(user_NukeTimer == 18, "Death")

		BFS1 B 0 bright A_SetUserVar("user_NukeTimer", user_NukeTimer + 1)
        BFS1 B 0 bright A_Explode(sqrt(user_NukeTimer * 160), sqrt(user_NukeTimer * 320),0,0,0)
		BFS1 B 4 bright A_ScaleVelocity(0.80)
		BFS1 B 0 bright A_JumpIf(user_NukeTimer == 18, "Death")
		Goto Spawn+1
    Death:
		BFE1 A 0 bright A_ChangeVelocity(0,0,0,CVF_REPLACE)
        BFE1 A 0 bright ACS_NamedExecuteAlways("Nuke_Flash",0)

		BFE1 A 0 bright A_SetUserVar("user_NukeTimer", user_NukeTimer + 18)
        BFE1 A 3 bright A_Explode(sqrt(user_NukeTimer * 240), sqrt(user_NukeTimer * 480),0,0,0)

        BFE1 A 0 bright A_SetUserVar("user_NukeTimer", user_NukeTimer + 32)
        BFE1 A 3 bright A_Explode(sqrt(user_NukeTimer * 320), sqrt(user_NukeTimer * 640),0,0,0)
		BFS1 B 0 bright A_JumpIf(user_NukeTimer >= 128, 1)
		Goto Death+3

        BFE1 B 0 bright A_SetUserVar("user_NukeTimer", user_NukeTimer + 32)
        BFE1 B 3 bright A_Explode(sqrt(user_NukeTimer * 320), sqrt(user_NukeTimer * 640),0,0,0)
		BFS1 B 0 bright A_JumpIf(user_NukeTimer >= 224, 1)
		Goto Death+6

        BFE1 C 0 bright A_SetUserVar("user_NukeTimer", user_NukeTimer + 48)
        BFE1 C 3 bright A_Explode(sqrt(user_NukeTimer * 320), sqrt(user_NukeTimer * 640),0,0,0)
        BFE1 C 0 bright A_SetUserVar("user_NukeTimer", user_NukeTimer + 64)
        BFE1 C 2 bright A_Explode(sqrt(user_NukeTimer * 320), sqrt(user_NukeTimer * 640),0,0,0)
        BFE1 C 0 bright A_SetUserVar("user_NukeTimer", user_NukeTimer * 4096)
		BFE1 C 0 bright ACS_NamedExecuteAlways("Nuke_BoomFade",0)
        BFE1 C 2 bright A_Explode(sqrt(user_NukeTimer * 320), 16384, 0, 0, 8192)

		BFE1 DEF 8 bright
		stop
    }
}