plugin simpleObject helperSample
name:"HelperSample"
category:"HowTo"
classID:#(0x453e608, 0x40dda998)
(
    parameters main rollout:params
    (
        p1 type:#maxObject
        p2 type:#maxObject
        p3 type:#maxObject
		stairWidth type:#worldUnits ui:spnStairWidth default:5.0
    )
	rollout params "Parameters"
	(
		spinner spnStairWidth "Stair Width" range:[-100.0,100.0,5.0] type:#worldunits
		--
		on spnStairWidth changed theVal do
		(
			p2UnitVector = p2.node.transform[1]
			rotatedMatrix = rotateZMatrix 90
			rotatedVector = p2UnitVector * rotatedMatrix
			p3.node.pos = p2.node.pos + (rotatedVector * this.stairWidth)
		)
	)
    fn isValid= isValidObj p1 and isValidObj p2 and isValidObj p3
	fn rot=
	(
		p2Vec = [p1.node.pos.x, p1.node.pos.y, 0] - [p2.node.pos.x, p2.node.pos.y, 0]
		p2Angle = atan2 p2Vec.y p2Vec.x
		p2Matrix = rotate (matrix3 1) (eulerangles 0.0 0.0 p2Angle as quat)
		scale p2Matrix p2.node.scale
		translate p2Matrix p2.node.pos
		p2.node.transform = p2Matrix
		p3Vec = [p2.node.pos.x, p2.node.pos.y, 0] - [p3.node.pos.x, p3.node.pos.y, 0]
		p3Angle = atan2 p3Vec.y p3Vec.x
		p3Matrix = rotate (matrix3 1) (eulerangles 0.0 0.0 p3Angle as quat)
		scale p3Matrix p3.node.scale
		translate p3Matrix p3.node.pos
		p3.node.transform = p3Matrix
	)
    on load do when transform #(p1, p2, p3) changes id:#forceUpdate do notifyDependents this
    on buildMesh do if isValid() do
    (
		/*when p1 moves the build is not taking it's position into account...*/
		local owner = refs.dependentNodes this firstOnly:on
		lDir = [p2.node.pos.x, p2.node.pos.y, 0] - [p1.node.pos.x, p1.node.pos.y, 0]
		lUVec = normalize lDir
		wDir = [p3.node.pos.x, p3.node.pos.y, 0] - [p2.node.pos.x, p2.node.pos.y, 0]
		wUVec = normalize wDir
		totalStairLength = distance [p1.node.pos.x,p1.node.pos.y] [p2.node.pos.x,p2.node.pos.y]
		amountOfStairs = (totalStairLength / 1) as integer
		stepLength = 1
		totalStairDrop = p2.node.pos.z - p1.node.pos.z
		dropDist = totalStairDrop / amountOfStairs
		stepWidth = distance [p2.node.pos.x,p2.node.pos.y] [p3.node.pos.x,p3.node.pos.y]
		fn stairVec _pnt3=
		(
			local lDir = [p2.node.pos.x, p2.node.pos.y, 0] - [p1.node.pos.x, p1.node.pos.y, 0]
			local lUVec = normalize lDir
			local wDir = [p3.node.pos.x, p3.node.pos.y, 0] - [p2.node.pos.x, p2.node.pos.y, 0]
			local wUVec = normalize wDir
			local x = wUVec * _pnt3[1] --width
			local y = lUVec * _pnt3[2]--length
			local z = _pnt3[3] --drop
			return (x + y + [0,0,z])
		)
		vert_array =#()
		face_array =#()
		vert_count = 0
		vertPos = undefined
		for i = 1 to amountOfStairs do
		(
			if i == 1 then
			(
				--6 verts
				vertPos = [0,0,0]
				append vert_array vertPos
				append vert_array (vertPos + (stairVec [stepWidth,0,0]))
				append vert_array (vertPos + (stairVec [stepWidth,stepLength,0]))
				append vert_array (vertPos + (stairVec [0,stepLength,0]))
				append vert_array (vertPos + (stairVec [stepWidth,stepLength,dropDist]))
				append vert_array (vertPos + (stairVec [0,stepLength,dropDist]))
				--4 faces
				append face_array [vert_count+1, vert_count+2, vert_count+3]
				append face_array [vert_count+1, vert_count+3, vert_count+4]
				append face_array [vert_count+4, vert_count+3, vert_count+5]
				append face_array [vert_count+4, vert_count+5, vert_count+6]
				vert_count += 6
			) else
			(
				--4 verts
				append vert_array (vertPos + (stairVec [stepWidth,stepLength,0]))
				append vert_array (vertPos + (stairVec [0,stepLength,0]))
				append vert_array (vertPos + (stairVec [stepWidth,stepLength,dropDist]))
				append vert_array (vertPos + (stairVec [0,stepLength,dropDist]))
				--4 faces
				append face_array [vert_count,vert_count-1,vert_count+1]
				append face_array [vert_count,vert_count+1,vert_count+2]
				append face_array [vert_count+2,vert_count+3,vert_count+4]
				append face_array [vert_count+2,vert_count+1,vert_count+3]
				vert_count += 4
			)
			vertPos = vert_array[vert_array.count]
		)
		setMesh mesh verts:vert_array faces:face_array smGroup:0
		for i = 1 to (getNumFaces mesh) do
		(
			setFaceSmoothGroup mesh i 0
		)

    )--end buildMesh
    tool create numPoints:2
    (
        local p3Pos
        on mousePoint click do if click == 1 do
        (
			p3Pos = undefined
            nodeTM.translation = gridPoint
            local owner = refs.dependentNodes this firstOnly:on
			print (refs.dependentNodes this firstOnly:on)
            p1 = NodeTransformMonitor node:(Point prefix:"p1-" parent:owner showLinks:on size:10 cross:off box:on constantscreensize:on wirecolor:yellow)
            p2 = NodeTransformMonitor node:(Point prefix:"p2-" parent:p1.node showLinks:on size:10 cross:off box:on constantscreensize:on wirecolor:yellow)
			p3 = NodeTransformMonitor node:(Point prefix:"p3-" parent:p2.node showLinks:on size:10 cross:off box:on constantscreensize:on wirecolor:yellow)
			p1.node.pos = owner.position
            when transform #(p1, p2, p3) changes id:#forceUpdate do notifyDependents this
			when transform #(p2, p3) changes id:#stairsPointDirection do rot()
        )
        on mouseMove click do if click == 2 and lbutton do
        (
			p2.node.pos = worldPoint
			p2UnitVector = p2.node.transform[1]
			rotatedMatrix = rotateZMatrix 90
			rotatedVector = p2UnitVector * rotatedMatrix
			p3.node.pos = p2.node.pos + (rotatedVector * this.stairWidth)
		)
    )
)