:brittany_cutscene_first_turtle
  switch hidePlayer ON
  js window.turtleEvent = $gameMap.createAnimalByTypeAt('small-turtle', 6, 10, 6);
  + window.turtleEvent._through = true;
  + window.turtleEvent._priorityType = 0;

  $ create Villager('Nathalia', 8, 10, left);
  + center camera(8, 10);
  wait for camera
  js window.turtleEvent.requestBalloon(Balloons.HEART);
  wait 60
  Nathalia "Did you like it?"
  wait 20
  $ create villager('Brittany', 0, 10, right);
  + change speed('Brittany', 3)
  + move('Brittany', 4, 10, right)
  js window.turtleEvent.requestBalloon(Balloons.HEART);
  wait for Brittany

  Brittany "Good Morning, Nathalia! What are you doing?"
  Nathalia "Hey Brittany, I just gave a tuna to this turtle. It looks like she loved it."
  Brittany "Is that so? Turtles really love most types of fish."
  Nathalia "Can I give her more?"
  Brittany "I don't think she'll be able to eat another one right now, but you can give her another fish tomorrow."
  Brittany "If you pet and feed her often, she'll grow attached to you. If that happens, she'll let you carry her around."
  Nathalia "Really? That's so nice. But Pat-Pat probably wouldn't like that."

  $ change speed('Player', 3)
  js if $gamePlayer.y < 3
    js $gamePlayer.setPosition(4, 0);
    switch hidePlayer OFF
    $ move('Player', 4, 8, right)
    wait for Player
    $ move('Player', 6, 8, down)
  else
    js if $gamePlayer.y > 16
      js $gamePlayer.setPosition(4, 19);
      switch hidePlayer OFF
      $ move('Player', 4, 12, right)
      wait for Player
      $ move('Player', 6, 12, up)
    else
      js $gamePlayer.setPosition(0, 8);
      $ change speed('Player', 2.5)
      switch hidePlayer OFF
      $ move('Player', 6, 8, down)
    end
  end

  wait for Player
  $ turn('Nathalia', 'Player');
  + turn('Brittany', 'Player');

  wait 10
  Nathalia "<name>, good timing! Did you hear what we were talking? You definitely need to tame some turtles for your farm."
  $ turn('Brittany', 'Nathalia')

  js if ItemManager.isHoldingAnimal('small-turtle')
    include player_holding_turtle
  else
    Brittany "Hold on, Nathalia. <He> doesn't really need to tame them. Turtles are useless on a farm."
    $ turn('Nathalia', 'Brittany')
    Nathalia "But why wouldn't <he>? Turtles are so cool."
    Brittany "<He> should focus on more useful animals, like cows and chicken. Right, <name>?"
    $ turn('Brittany', 'Player')
    $ turn('Nathalia', 'Player')

    js if CreatureManager.hasAnyCreatureOfRace('small-turtle')
      ADD-CHOICE I already tamed a turtle.
    end
    Player ("Taming turtles, or focusing on useful animals...", "I would like a turtle too.", "I'm too busy to take care of a turtle.")

    if response is "I would like a turtle too."
      include player_would_like_a_turtle
    else
      if response is "I'm too busy to take care of a turtle."
        include player_wouldnt_like_a_turtle
      else
        if response is "I already tamed a turtle."
          include player_already_has_a_turtle
        end
      end
    end
  end

  retain cutscene until teleport
  $ restore speed('Player')
  # switch playedCutsceneFirstTurtle ON
  wait 30

:player_holding_turtle
  Brittany "It looks like <he> already did."
  $ turn('Brittany', 'Player')
  $ turn('Nathalia', 'Player')
  wait 20

  Nathalia "<heart>"
  js RelationshipManager.increaseFriendship('Nathalia', 500)
  js RelationshipManager.increaseFriendship('Brittany', 120)

  Nathalia "Oh, that's right! What a cute turtle <he> has!"
  include nathalia_player_youre_amazing
  $ assign villager event('Nathalia', 'nathalia_player_youre_amazing')
  $ assign villager event('Brittany', 'brittany_player_you_got_me_surprised')

:player_would_like_a_turtle
  Nathalia "<music:async>"
  Brittany "<...>"
  js RelationshipManager.increaseFriendship('Nathalia', 200)
  js RelationshipManager.increaseFriendship('Brittany', 50)

  Nathalia "See? I told you, Brittany!"
  include brittany_player_dont_forget_farm_animals
  $ assign villager event('Nathalia', 'nathalia_player_youre_amazing')
  $ assign villager event('Brittany', 'brittany_player_dont_forget_farm_animals')

:player_wouldnt_like_a_turtle
  Nathalia "<cobweb:async>"
  Brittany "<music>"
  js RelationshipManager.increaseFriendship('Brittany', 150)
  js RelationshipManager.decreaseFriendship('Nathalia', 300)

  include brittany_its_understandable
  include nathalia_but_the_turtles

  $ assign villager event('Nathalia', 'nathalia_but_the_turtles')
  $ assign villager event('Brittany', 'brittany_its_understandable')

:player_already_has_a_turtle
  Nathalia "<heart:async>"
  Brittany "<!>"
  js RelationshipManager.increaseFriendship('Nathalia', 300)
  js RelationshipManager.increaseFriendship('Brittany', 100)

  Nathalia "Really? You're amazing, <name>! I want to see it some day."
  $ assign villager event('Nathalia', 'nathalia_player_youre_amazing')
  $ assign villager event('Brittany', 'brittany_player_dont_forget_farm_animals')

:nathalia_player_youre_amazing
  $ turn('Nathalia', 'Player')
  Nathalia "<name>, you're amazing!"

:brittany_player_you_got_me_surprised
  $ turn('Brittany', 'Player')
  Brittany "You surprised me now. I didn't expect you to have a turtle with you."

:brittany_player_dont_forget_farm_animals
  $ turn('Brittany', 'Player')
  Brittany "Well <name>, as long as you don't forget to take care of the farm animals, there's no harm in having pets."

:nathalia_but_the_turtles
  $ turn('Nathalia', 'Player')
  Nathalia "But... the turtles..."

:brittany_its_understandable
  $ turn('Brittany', 'Player')
  Brittany "It's understandable. Taking care of a farm by yourself is very hard work."