@Echo off
:: Backup-Script für Firebird 2.0 - 2.5 Server
:: Copyright 2021 MP-BOS GmbH
:: Kontakt: <[email protected]>

:: README - Bitte lesen
::
:: Dieses Script erstellt ein Vollbackup der MP-FEUER Datenbankdatei.
:: Hierzu sind die unten stehenden Konfigurationswerte anzupassen.


:: # # # # # KONFIGURATION # # # # #

:: Pfad zu GBAK.EXE
set GBAK_EXE=C:\Program Files (x86)\Firebird\Firebird_2_5\bin\gbak.exe

:: Name des Servers, auf dem der Firebird-Server läuft.
:: In den meisten Fällen ist dies 'localhost'
set SERVER_HOST=localhost

:: Pfad zur Datenbankdatei (aus Sicht des Servers)
:: Hier darf kein UNC/Fregabepfad angegeben werden!
:: Lokaler Pfad der Datenbank
set DATENBANK=C:\MP-SOFT-4-U\MP-FEUER Netzdaten\V2020P\database\DATA54P.FDB

:: Pfad zum Backup-Verzeichnis.
:: Hier werden die Backups und Logdateien abgelegt.
set BACKUP_DIR=C:\MP-SOFT-4-U\MP-FEUER Netzdaten\Sicherung

:: Name des Backups
set BACKUP_NAME=MPFEUER_DB_BAK

:: Firebird Benutzername
set USER=SYSDBA

:: Firebird Benutzer Passwort
set PASSWORD=masterkey

:: # # # # # KONFIGURATION ENDE # # # # # #

:: Check WMIC
WMIC.EXE Alias /? >NUL 2>&1 || GOTO wmic_error

:: Timestamp Variablen setzen
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
     set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
     set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%"
set "timestamp=%HH%%Min%%Sec%"
set "fullstamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%"

:: Ausgabedateien
set _BACKUP_PATH=%BACKUP_DIR%\%BACKUP_NAME%_%fullstamp%.bak
set _LOG_FILE=%BACKUP_DIR%\%BACKUP_NAME%_%fullstamp%_log.txt
set _DB_URI=%SERVER_HOST%:%DATENBANK%

:: Run...
echo.
echo Starte Sicherung:
echo  * Datenbank: %_DB_URI%
echo  * Host: %SERVER_HOST%
echo  * Backup: %_BACKUP_PATH%
echo  * Logdatei: %_LOG_FILE%
echo.

:: Starte GBAK.EXE
"%GBAK_EXE%" -v -verify -y "%_LOG_FILE%" -b "%_DB_URI%" "%_BACKUP_PATH%" -user "%USER%" -password "%PASSWORD%"

if errorlevel 1 goto backup_fail

echo.
echo Backup wurde erfolgreich erstellt.
echo Bitte prüfen Sie die Logdatei, ob alle Daten korrekt gesichert wurden.
echo.
timeout /T 3 > nul
GOTO:EOF

:backup_fail
echo.
echo !!! Die Sicherung konnte nicht erstellt werden. !!!
echo Bitte prüfen Sie die Logdatei (%_LOG_FILE%)
echo.
timeout /T 3 > nul
GOTO:EOF

:wmci_error
echo.
echo Das aktuelle Datum konnte nicht ermittelt werden (wmci.exe).
echo Dieses Script benötigt mind. Windows Vista!
echo.
timeout /T 3 > nul