AC3-DTS-WAV TO AAC BATCH

@ECHO OFF

:: SWISS FILE KNIFE to echo with colors
IF EXIST "%windir%\sfk.exe" (
  set SFK=sfk
  set GCLR=[Green]
  set RCLR=[Red]
  set ENDCLR=[def]
)

:: set eac3to="D:\Apps\EAC3to\eac3to.exe"
:: set neroAacEnc="D:\Apps\EAC3to\neroAacEnc.exe"

IF EXIST "%~1\" (
ECHO. & %SFK% echo "%RCLR%Select files not folders!%ENDCLR%"
GOTO EOF
)

:LOOP
IF [%1]==[] GOTO EOF
CD /D "%~dp1"

:: Filter remove from source file name
SET SOURCE=%~nx1
SET FLT1=%~n1
SET FLT2=%FLT1:-DTS=%
SET FLT3=%FLT2:-AC3=%
SET TARGET=%FLT3:-PCM=%

:: check audio type
IF [%~x1]==[.dts] GOTO AC3-DTS
IF [%~x1]==[.ac3] GOTO AC3-DTS
IF [%~x1]==[.wav] GOTO WAV
SHIFT
GOTO LOOP

:AC3-DTS
ECHO. & %SFK% echo "%GCLR%Processing  %TARGET%-PCM.wav%ENDCLR%" & ECHO.
eac3to "%SOURCE%" "%TARGET%-PCM.wav" -normalize -log="%TARGET%-PCM.log"
ECHO. & %SFK% echo "%GCLR%Processing  %TARGET%-M4A.m4a%ENDCLR%" & ECHO.
neroAacEnc -br 384000 -2pass -ignorelength -if "%TARGET%-PCM.wav" -of "%TARGET%-M4A.m4a"
SHIFT
GOTO LOOP

:WAV
ECHO. & %SFK% echo "%GCLR%Processing  %TARGET%-M4A.m4a%ENDCLR%" & ECHO.
neroAacEnc -br 384000 -2pass -ignorelength -if "%SOURCE%" -of "%TARGET%-M4A.m4a"
SHIFT
GOTO LOOP

:EOF